madduck's git repository

Every one of the projects in this repository is available at the canonical URL git://git.madduck.net/madduck/pub/<projectpath> — see each project's metadata for the exact URL.

All patches and comments are welcome. Please squash your changes to logical commits before using git-format-patch and git-send-email to patches@git.madduck.net. If you'd read over the Git project's submission guidelines and adhered to them, I'd be especially grateful.

SSH access, as well as push access can be individually arranged.

If you use my repositories frequently, consider adding the following snippet to ~/.gitconfig and using the third clone URL listed for each project:

[url "git://git.madduck.net/madduck/"]
  insteadOf = madduck:

d872af2cb4813f23aaebb5b4a3dde31e09babc6d
[etc/ssh.git] / .zsh / zshrc / parts.d / 50-ssh
1 # zshrc/parts.d/50-ssh
2 #
3 # ssh configuration for zsh
4 #
5 # Copyright © 2008 martin f. krafft <madduck@madduck.net>
6 # Released under the terms of the Artistic Licence 2.0
7 #
8 # Source repository: git://git.madduck.net/etc/ssh.git
9 #
10
11 # populate hosts completion with SSH's known_hosts
12 if [ -r $HOME/.ssh/known_hosts ]; then
13   local _myhosts
14   _myhosts=(${${${${(f)"$(cat $HOME/.ssh/known_hosts)"}:#[0-9]*}%%\ *}%%,*})
15   zstyle ':completion:*' hosts $_myhosts
16   unset _myhosts
17 fi
18
19 _ssh_proxy() {
20   local cmd sshopts cmdopts
21   cmd="$1"; shift
22   sshopts="${*%%--*}"; sshopts="${sshopts%% }"
23   [[ -n "$sshopts" ]] || { ssh; return $? }
24   cmdopts="${*#$sshopts}"; cmdopts="${cmdopts#*-- }"
25   eval ssh $sshopts -t $cmd $cmdopts
26 }
27
28 # need functions instead of aliases for completion
29 rrsh() { _ssh_proxy "sudo -i" "$@" }
30 compdef rrsh=ssh
31
32 ttsh() { _ssh_proxy "tmux last" "$@" }
33 compdef ttsh=ssh
34
35 rtsh() { _ssh_proxy "tmux new sudo -i" "$@" }
36 compdef rtsh=ssh
37
38 declare _SSH_SOCKDIR="${VARDIR}/ssh"
39 kssh() {
40   if [[ -z "$1" ]]; then
41     rm -vf -- ${_SSH_SOCKDIR}/*(=as-60Y1omN)
42   else
43     rm "$@"
44   fi
45 }
46 compdef -e "compset -P ${_SSH_SOCKDIR}/ || PREFIX=${_SSH_SOCKDIR}/; _files -W ${_SSH_SOCKDIR}" kssh
47
48 sshcd() {
49   local args host dir arg
50
51   for arg in "$@"; do
52     case "$arg" in
53       (*:*) host=${arg%%:*}; dir="${arg#*:}";;
54       (*) args="${args:+$args }$arg";;
55     esac
56   done
57
58   if [[ -z $dir ]]; then
59     ssh "$@"
60
61   else
62
63     ssh -t $args $host "cd '$dir' && exec \$SHELL --login"
64   fi
65 }
66
67 # vim:ft=zsh