# zshrc/parts.d/50-ssh
#
# ssh configuration for zsh
#
# Copyright © 2008 martin f. krafft <madduck@madduck.net>
# Released under the terms of the Artistic Licence 2.0
#
# Source repository: git://git.madduck.net/etc/ssh.git
#

# populate hosts completion with SSH's known_hosts
if [ -r $HOME/.ssh/known_hosts ]; then
  local _myhosts
  _myhosts=(${${${${(f)"$(cat $HOME/.ssh/known_hosts)"}:#[0-9]*}%%\ *}%%,*})
  zstyle ':completion:*' hosts $_myhosts
  unset _myhosts
fi

_ssh_proxy() {
  local cmd sshopts cmdopts
  cmd="$1"; shift
  sshopts="${*%%--*}"; sshopts="${sshopts%% }"
  [[ -n "$sshopts" ]] || { ssh; return $? }
  cmdopts="${*#$sshopts}"; cmdopts="${cmdopts#*-- }"
  eval ssh $sshopts -t $cmd $cmdopts
}

# need functions instead of aliases for completion
rrsh() { _ssh_proxy "sudo -i" "$@" }
compdef rrsh=ssh

ttsh() { _ssh_proxy "tmux last" "$@" }
compdef ttsh=ssh

rtsh() { _ssh_proxy "tmux new sudo -i" "$@" }
compdef rtsh=ssh

declare _SSH_SOCKDIR="${VARDIR}/ssh"
kssh() {
  if [[ -z "$1" ]]; then
    rm -vf -- ${_SSH_SOCKDIR}/*(=as-60Y1omN)
  else
    rm "$@"
  fi
}
compdef -e "compset -P ${_SSH_SOCKDIR}/ || PREFIX=${_SSH_SOCKDIR}/; _files -W ${_SSH_SOCKDIR}" kssh

sshcd() {
  local args host dir arg

  for arg in "$@"; do
    case "$arg" in
      (*:*) host=${arg%%:*}; dir="${arg#*:}";;
      (*) args="${args:+$args }$arg";;
    esac
  done

  if [[ -z $dir ]]; then
    ssh "$@"

  else

    ssh -t $args $host "cd '$dir' && exec \$SHELL --login"
  fi
}

# vim:ft=zsh