indent/markdown.vim

   1 if exists("b:did_indent") | finish | endif
   2 let b:did_indent = 1
   3
   4 setlocal indentexpr=GetMarkdownIndent()
   5 setlocal nolisp
   6 setlocal autoindent
   7
   8 " Automatically insert bullets
   9 setlocal formatoptions+=r
  10 " Do not automatically insert bullets when auto-wrapping with text-width
  11 setlocal formatoptions-=c
  12 " Accept various markers as bullets
  13 setlocal comments=b:*,b:+,b:-
  14
  15 " Automatically continue blockquote on line break
  16 setlocal comments+=b:>
  17
  18 " Only define the function once
  19 if exists("*GetMarkdownIndent") | finish | endif
  20
  21 function! s:is_mkdCode(lnum)
  22     let name = synIDattr(synID(a:lnum, 1, 0), 'name')
  23     return (name =~ '^mkd\%(Code$\|Snippet\)' || name != '' && name !~ '^\%(mkd\|html\)')
  24 endfunction
  25
  26 function! s:is_li_start(line)
  27     return a:line !~ '^ *\([*-]\)\%( *\1\)\{2}\%( \|\1\)*$' &&
  28       \    a:line =~ '^\s*[*+-] \+'
  29 endfunction
  30
  31 function! s:is_blank_line(line)
  32     return a:line =~ '^$'
  33 endfunction
  34
  35 function! s:prevnonblank(lnum)
  36     let i = a:lnum
  37     while i > 1 && s:is_blank_line(getline(i))
  38         let i -= 1
  39     endwhile
  40     return i
  41 endfunction
  42
  43 function GetMarkdownIndent()
  44     let list_ind = 4
  45     " Find a non-blank line above the current line.
  46     let lnum = prevnonblank(v:lnum - 1)
  47     " At the start of the file use zero indent.
  48     if lnum == 0 | return 0 | endif
  49     let ind = indent(lnum)
  50     let line = getline(lnum)    " Last line
  51     let cline = getline(v:lnum) " Current line
  52     if s:is_li_start(cline)
  53         " Current line is the first line of a list item, do not change indent
  54         return indent(v:lnum)
  55     elseif s:is_li_start(line)
  56         if s:is_mkdCode(lnum)
  57             return ind
  58         else
  59             " Last line is the first line of a list item, increase indent
  60             return ind + list_ind
  61         end
  62     else
  63         return ind
  64     endif
  65 endfunction