X-Git-Url: https://git.madduck.net/etc/vim.git/blobdiff_plain/0ee596c5c5e11fc79598407eaf22f83d279f7e9e..5a4872f466ebd76ddd532bdf2798554421c53df4:/.vim/bundle/ale/ale_linters/dafny/dafny.vim?ds=sidebyside

diff --git a/.vim/bundle/ale/ale_linters/dafny/dafny.vim b/.vim/bundle/ale/ale_linters/dafny/dafny.vim
new file mode 100644
index 00000000..8a114d22
--- /dev/null
+++ b/.vim/bundle/ale/ale_linters/dafny/dafny.vim
@@ -0,0 +1,41 @@
+" Author: Taylor Blau <me@ttaylorr.com>
+call ale#Set('dafny_dafny_timelimit', 10)
+
+function! ale_linters#dafny#dafny#Handle(buffer, lines) abort
+    let l:pattern = '\v(.*)\((\d+),(\d+)\): (.*): (.*)'
+    let l:output = []
+
+    for l:match in ale#util#GetMatches(a:lines, l:pattern)
+        call add(l:output, {
+        \    'filename': l:match[1],
+        \    'col': l:match[3] + 0,
+        \    'lnum': l:match[2] + 0,
+        \    'text': l:match[5],
+        \    'type': l:match[4] =~# '^Error' ? 'E' : 'W'
+        \ })
+    endfor
+
+    for l:match in ale#util#GetMatches(a:lines, '\v(.*)\((\d+),(\d+)\): (Verification of .{-} timed out after \d+ seconds)')
+        call add(l:output, {
+        \     'filename': l:match[1],
+        \     'col': l:match[3] + 0,
+        \     'lnum': l:match[2] + 0,
+        \     'text': l:match[4],
+        \     'type': 'E',
+        \ })
+    endfor
+
+    return l:output
+endfunction
+
+function! ale_linters#dafny#dafny#GetCommand(buffer) abort
+    return printf('dafny %%s /compile:0 /timeLimit:%d', ale#Var(a:buffer, 'dafny_dafny_timelimit'))
+endfunction
+
+call ale#linter#Define('dafny', {
+\    'name': 'dafny',
+\    'executable': 'dafny',
+\    'command': function('ale_linters#dafny#dafny#GetCommand'),
+\    'callback': 'ale_linters#dafny#dafny#Handle',
+\    'lint_file': 1,
+\ })