X-Git-Url: https://git.madduck.net/etc/vim.git/blobdiff_plain/0ee596c5c5e11fc79598407eaf22f83d279f7e9e..5a4872f466ebd76ddd532bdf2798554421c53df4:/.vim/bundle/ale/ale_linters/dart/analysis_server.vim

diff --git a/.vim/bundle/ale/ale_linters/dart/analysis_server.vim b/.vim/bundle/ale/ale_linters/dart/analysis_server.vim
new file mode 100644
index 00000000..12a5d590
--- /dev/null
+++ b/.vim/bundle/ale/ale_linters/dart/analysis_server.vim
@@ -0,0 +1,37 @@
+" Author: Nelson Yeung <nelsyeung@gmail.com>
+" Description: Check Dart files with dart analysis server LSP
+
+call ale#Set('dart_analysis_server_enable_language_server', 1)
+call ale#Set('dart_analysis_server_executable', 'dart')
+
+function! ale_linters#dart#analysis_server#GetProjectRoot(buffer) abort
+    " Note: pub only looks for pubspec.yaml, there's no point in adding
+    " support for pubspec.yml
+    let l:pubspec = ale#path#FindNearestFile(a:buffer, 'pubspec.yaml')
+
+    return !empty(l:pubspec) ? fnamemodify(l:pubspec, ':h:h') : '.'
+endfunction
+
+function! ale_linters#dart#analysis_server#GetCommand(buffer) abort
+    let l:language_server = ale#Var(a:buffer, 'dart_analysis_server_enable_language_server')
+    let l:executable = ale#Var(a:buffer, 'dart_analysis_server_executable')
+    let l:dart = resolve(exepath(l:executable))
+    let l:output = '%e '
+    \   . fnamemodify(l:dart, ':h') . '/snapshots/analysis_server.dart.snapshot'
+    \   . ' --lsp'
+
+    " Enable new language-server command
+    if l:language_server == 1
+        let l:output = '%e language-server --protocol=lsp'
+    endif
+
+    return l:output
+endfunction
+
+call ale#linter#Define('dart', {
+\   'name': 'analysis_server',
+\   'lsp': 'stdio',
+\   'executable': {b -> ale#Var(b, 'dart_analysis_server_executable')},
+\   'command': function('ale_linters#dart#analysis_server#GetCommand'),
+\   'project_root': function('ale_linters#dart#analysis_server#GetProjectRoot'),
+\})