X-Git-Url: https://git.madduck.net/etc/vim.git/blobdiff_plain/0ee596c5c5e11fc79598407eaf22f83d279f7e9e..5a4872f466ebd76ddd532bdf2798554421c53df4:/.vim/bundle/ale/ale_linters/html/angular.vim?ds=inline

diff --git a/.vim/bundle/ale/ale_linters/html/angular.vim b/.vim/bundle/ale/ale_linters/html/angular.vim
new file mode 100644
index 00000000..05caf59d
--- /dev/null
+++ b/.vim/bundle/ale/ale_linters/html/angular.vim
@@ -0,0 +1,56 @@
+" Author: w0rp <devw0rp@gmail.com>
+" Description: tsserver integration for ALE
+
+call ale#Set('html_angular_executable', 'ngserver')
+call ale#Set('html_angular_use_global', get(g:, 'ale_use_global_executables', 0))
+
+function! ale_linters#html#angular#GetProjectRoot(buffer) abort
+    return ale#path#Dirname(
+    \   ale#path#FindNearestDirectory(a:buffer, 'node_modules')
+    \)
+endfunction
+
+function! ale_linters#html#angular#GetExecutable(buffer) abort
+    return 'node'
+endfunction
+
+function! ale_linters#html#angular#GetCommand(buffer) abort
+    let l:language_service_dir = ale#path#Simplify(
+    \   ale#path#FindNearestDirectory(
+    \       a:buffer,
+    \       'node_modules/@angular/language-service'
+    \   )
+    \)
+
+    if empty(l:language_service_dir)
+        return ''
+    endif
+
+    let l:language_service_dir = fnamemodify(l:language_service_dir, ':h')
+    let l:typescript_dir = ale#path#Simplify(
+    \   fnamemodify(l:language_service_dir, ':h:h')
+    \   . '/typescript'
+    \)
+    let l:script = ale#path#FindExecutable(a:buffer, 'html_angular', [
+    \   'node_modules/@angular/language-server/bin/ngserver',
+    \   'node_modules/@angular/language-server/index.js',
+    \])
+
+    if !filereadable(l:script)
+        return ''
+    endif
+
+    return ale#Escape('node') . ' ' . ale#Escape(l:script)
+    \ . ' --ngProbeLocations ' . ale#Escape(l:language_service_dir)
+    \ . ' --tsProbeLocations ' . ale#Escape(l:typescript_dir)
+    \ . ' --stdio'
+endfunction
+
+call ale#linter#Define('html', {
+\   'name': 'angular',
+\   'aliases': ['angular-language-server', 'angularls'],
+\   'lsp': 'stdio',
+\   'executable': function('ale_linters#html#angular#GetExecutable'),
+\   'command': function('ale_linters#html#angular#GetCommand'),
+\   'project_root': function('ale_linters#html#angular#GetProjectRoot'),
+\})