X-Git-Url: https://git.madduck.net/etc/vim.git/blobdiff_plain/0ee596c5c5e11fc79598407eaf22f83d279f7e9e..5a4872f466ebd76ddd532bdf2798554421c53df4:/.vim/bundle/ale/ale_linters/java/pmd.vim?ds=sidebyside

diff --git a/.vim/bundle/ale/ale_linters/java/pmd.vim b/.vim/bundle/ale/ale_linters/java/pmd.vim
new file mode 100644
index 00000000..a1f4c93c
--- /dev/null
+++ b/.vim/bundle/ale/ale_linters/java/pmd.vim
@@ -0,0 +1,36 @@
+" Author: Johannes Wienke <languitar@semipol.de>
+" Description: PMD for Java files
+
+function! ale_linters#java#pmd#Handle(buffer, lines) abort
+    let l:pattern = '"\(\d\+\)",".*","\(.\+\)","\(\d\+\)","\(\d\+\)","\(.\+\)","\(.\+\)","\(.\+\)"$'
+    let l:output = []
+
+    for l:match in ale#util#GetMatches(a:lines, l:pattern)
+        call add(l:output, {
+        \   'type': 'W',
+        \   'lnum': l:match[4] + 0,
+        \   'text': l:match[5],
+        \   'code': l:match[6] . ' - ' . l:match[7],
+        \})
+    endfor
+
+    return l:output
+endfunction
+
+function! ale_linters#java#pmd#GetCommand(buffer) abort
+    return 'pmd '
+    \ . ale#Var(a:buffer, 'java_pmd_options')
+    \ . ' -f csv'
+    \ . ' -d %t'
+endfunction
+
+if !exists('g:ale_java_pmd_options')
+    let g:ale_java_pmd_options = '-R category/java/bestpractices.xml'
+endif
+
+call ale#linter#Define('java', {
+\   'name': 'pmd',
+\   'executable': 'pmd',
+\   'command': function('ale_linters#java#pmd#GetCommand'),
+\   'callback': 'ale_linters#java#pmd#Handle',
+\})