X-Git-Url: https://git.madduck.net/etc/vim.git/blobdiff_plain/0ee596c5c5e11fc79598407eaf22f83d279f7e9e..5a4872f466ebd76ddd532bdf2798554421c53df4:/.vim/bundle/ale/ale_linters/php/php.vim?ds=inline

diff --git a/.vim/bundle/ale/ale_linters/php/php.vim b/.vim/bundle/ale/ale_linters/php/php.vim
new file mode 100644
index 00000000..51a109b9
--- /dev/null
+++ b/.vim/bundle/ale/ale_linters/php/php.vim
@@ -0,0 +1,39 @@
+" Author: Spencer Wood <https://github.com/scwood>, Adriaan Zonnenberg <amz@adriaan.xyz>
+" Description: This file adds support for checking PHP with php-cli
+
+call ale#Set('php_php_executable', 'php')
+
+function! ale_linters#php#php#Handle(buffer, lines) abort
+    " Matches patterns like the following:
+    "
+    " PHP 7.1<= - Parse error:  syntax error, unexpected ';', expecting ']' in - on line 15
+    " PHP 7.2>= - Parse error:  syntax error, unexpected ';', expecting ']' in Standard input code on line 15
+    let l:pattern = '\v^%(Fatal|Parse) error:\s+(.+unexpected ''(.+)%(expecting.+)@<!''.*|.+) in %(-|Standard input code) on line (\d+)'
+    let l:output = []
+
+    for l:match in ale#util#GetMatches(a:lines, l:pattern)
+        let l:col = empty(l:match[2]) ? 0 : stridx(getline(l:match[3]), l:match[2]) + 1
+
+        let l:obj = {
+        \   'lnum': l:match[3] + 0,
+        \   'col': l:col,
+        \   'text': l:match[1],
+        \}
+
+        if l:col != 0
+            let l:obj.end_col = l:col + strlen(l:match[2]) - 1
+        endif
+
+        call add(l:output, l:obj)
+    endfor
+
+    return l:output
+endfunction
+
+call ale#linter#Define('php', {
+\   'name': 'php',
+\   'executable': {b -> ale#Var(b, 'php_php_executable')},
+\   'output_stream': 'stdout',
+\   'command': '%e -l -d error_reporting=E_ALL -d display_errors=1 -d log_errors=0 --',
+\   'callback': 'ale_linters#php#php#Handle',
+\})