X-Git-Url: https://git.madduck.net/etc/vim.git/blobdiff_plain/0ee596c5c5e11fc79598407eaf22f83d279f7e9e..5a4872f466ebd76ddd532bdf2798554421c53df4:/.vim/bundle/ale/ale_linters/pyrex/cython.vim?ds=sidebyside

diff --git a/.vim/bundle/ale/ale_linters/pyrex/cython.vim b/.vim/bundle/ale/ale_linters/pyrex/cython.vim
new file mode 100644
index 00000000..247c3060
--- /dev/null
+++ b/.vim/bundle/ale/ale_linters/pyrex/cython.vim
@@ -0,0 +1,36 @@
+" Author: w0rp <devw0rp@gmail.com>,
+" Nicolas Pauss <https://github.com/nicopauss>
+" Description: cython syntax checking for cython files.
+
+call ale#Set('pyrex_cython_executable', 'cython')
+call ale#Set('pyrex_cython_options', '--warning-extra')
+
+function! ale_linters#pyrex#cython#GetCommand(buffer) abort
+    return '%e --working %s:h --include-dir %s:h'
+    \   . ale#Pad(ale#Var(a:buffer, 'pyrex_cython_options'))
+    \   . ' --output-file ' . g:ale#util#nul_file . ' %t'
+endfunction
+
+function! ale_linters#pyrex#cython#Handle(buffer, lines) abort
+    let l:pattern = '\v^(\w+: )?[^:]+:(\d+):?(\d+)?:? ?(.+)$'
+    let l:output = []
+
+    for l:match in ale#util#GetMatches(a:lines, l:pattern)
+        call add(l:output, {
+        \   'lnum': l:match[2] + 0,
+        \   'col': l:match[3] + 0,
+        \   'text': l:match[4],
+        \   'type': l:match[1][0] is# 'w' ? 'W' : 'E',
+        \})
+    endfor
+
+    return l:output
+endfunction
+
+call ale#linter#Define('pyrex', {
+\   'name': 'cython',
+\   'output_stream': 'stderr',
+\   'executable': {b -> ale#Var(b, 'pyrex_cython_executable')},
+\   'command': function('ale_linters#pyrex#cython#GetCommand'),
+\   'callback': 'ale_linters#pyrex#cython#Handle',
+\})