X-Git-Url: https://git.madduck.net/etc/vim.git/blobdiff_plain/0ee596c5c5e11fc79598407eaf22f83d279f7e9e..5a4872f466ebd76ddd532bdf2798554421c53df4:/.vim/bundle/ale/ale_linters/sh/language_server.vim

diff --git a/.vim/bundle/ale/ale_linters/sh/language_server.vim b/.vim/bundle/ale/ale_linters/sh/language_server.vim
new file mode 100644
index 00000000..c6781584
--- /dev/null
+++ b/.vim/bundle/ale/ale_linters/sh/language_server.vim
@@ -0,0 +1,32 @@
+" Author: Christian Höltje (https://docwhat.org/)
+" Description: BASH Language server integration for ALE
+scriptencoding utf-8
+
+call ale#Set('sh_language_server_executable', 'bash-language-server')
+call ale#Set('sh_language_server_use_global', get(g:, 'ale_use_global_executables', 0))
+
+function! ale_linters#sh#language_server#GetExecutable(buffer) abort
+    return ale#path#FindExecutable(a:buffer, 'sh_language_server', [
+    \   'node_modules/.bin/bash-language-server',
+    \])
+endfunction
+
+function! ale_linters#sh#language_server#GetCommand(buffer) abort
+    let l:exe = ale#Escape(ale_linters#sh#language_server#GetExecutable(a:buffer))
+
+    return l:exe . ' start'
+endfunction
+
+function! ale_linters#sh#language_server#GetProjectRoot(buffer) abort
+    let l:git_path = ale#path#FindNearestDirectory(a:buffer, '.git')
+
+    return !empty(l:git_path) ? fnamemodify(l:git_path, ':h:h') : ''
+endfunction
+
+call ale#linter#Define('sh', {
+\   'name': 'language_server',
+\   'lsp': 'stdio',
+\   'executable': function('ale_linters#sh#language_server#GetExecutable'),
+\   'command': function('ale_linters#sh#language_server#GetCommand'),
+\   'project_root': function('ale_linters#sh#language_server#GetProjectRoot'),
+\})