X-Git-Url: https://git.madduck.net/etc/vim.git/blobdiff_plain/5ff124014066ba7882617c283e7750d449caafb4..899ef40d3c84192e3c6c0b512a40d9e42a8bb3dd:/ftplugin/markdown.vim?ds=inline

diff --git a/ftplugin/markdown.vim b/ftplugin/markdown.vim
index 9b98767..c2fff46 100644
--- a/ftplugin/markdown.vim
+++ b/ftplugin/markdown.vim
@@ -302,18 +302,77 @@ function! s:Toc(...)
         let l:window_type = 'vertical'
     endif
 
-    try
-        silent lvimgrep /\(^\S.*\(\n[=-]\+\n\)\@=\|^#\+\)/ %
-    catch /E480/
+
+    let l:bufnr = bufnr('%')
+    let l:cursor_line = line('.')
+    let l:cursor_header = 0
+    let l:fenced_block = 0
+    let l:front_matter = 0
+    let l:header_list = []
+    let l:header_max_len = 0
+    let l:vim_markdown_toc_autofit = get(g:, "vim_markdown_toc_autofit", 0)
+    let l:vim_markdown_frontmatter = get(g:, "vim_markdown_frontmatter", 0)
+    for i in range(1, line('$'))
+        let l:lineraw = getline(i)
+        let l:l1 = getline(i+1)
+        let l:line = substitute(l:lineraw, "#", "\\\#", "g")
+        if l:line =~ '````*' || l:line =~ '\~\~\~\~*'
+            if l:fenced_block == 0
+                let l:fenced_block = 1
+            elseif l:fenced_block == 1
+                let l:fenced_block = 0
+            endif
+        elseif l:vim_markdown_frontmatter == 1
+            if l:front_matter == 1
+                if l:line == '---'
+                    let l:front_matter = 0
+                endif
+            elseif i == 1
+                if l:line == '---'
+                    let l:front_matter = 1
+                endif
+            endif
+        endif
+        if l:line =~ '^#\+' || (l:l1 =~ '^=\+\s*$' || l:l1 =~ '^-\+\s*$') && l:line =~ '^\S'
+            let l:is_header = 1
+        else
+            let l:is_header = 0
+        endif
+        if l:is_header == 1 && l:fenced_block == 0 && l:front_matter == 0
+            " append line to location list
+            let l:item = {'lnum': i, 'text': l:line, 'valid': 1, 'bufnr': l:bufnr, 'col': 1}
+            let l:header_list = l:header_list + [l:item]
+            " set header number of the cursor position
+            if l:cursor_header == 0
+                if i == l:cursor_line
+                    let l:cursor_header = len(l:header_list)
+                elseif i > l:cursor_line
+                    let l:cursor_header = len(l:header_list) - 1
+                endif
+            endif
+            " keep track of the longest header size (heading level + title)
+            let l:total_len = stridx(l:line, ' ') + len(l:line)
+            if l:total_len > l:header_max_len
+                let l:header_max_len = l:total_len
+            endif
+        endif
+    endfor
+    call setloclist(0, l:header_list)
+    if len(l:header_list) == 0
         echom "Toc: No headers."
         return
-    endtry
+    endif
 
     if l:window_type ==# 'horizontal'
         lopen
     elseif l:window_type ==# 'vertical'
         vertical lopen
-        let &winwidth=(&columns/2)
+        " auto-fit toc window when possible to shrink it
+        if (&columns/2) > l:header_max_len && l:vim_markdown_toc_autofit == 1
+            execute 'vertical resize ' . (l:header_max_len + 1)
+        else
+            execute 'vertical resize ' . (&columns/2)
+        endif
     elseif l:window_type ==# 'tab'
         tab lopen
     else
@@ -330,7 +389,7 @@ function! s:Toc(...)
             let d.text = substitute(d.text, '\v[ ]*#*$', '', '')
         " setex headers
         else
-            let l:next_line = getbufline(bufname(d.bufnr), d.lnum+1)
+            let l:next_line = getbufline(d.bufnr, d.lnum+1)
             if match(l:next_line, "=") > -1
                 let l:level = 0
             elseif match(l:next_line, "-") > -1
@@ -341,7 +400,7 @@ function! s:Toc(...)
     endfor
     setlocal nomodified
     setlocal nomodifiable
-    normal! gg
+    execute 'normal! ' . l:cursor_header . 'G'
 endfunction
 
 " Convert Setex headers in range `line1 .. line2` to Atx.
@@ -381,8 +440,9 @@ function! s:HeaderDecrease(line1, line2, ...)
         endif
     endfor
     let l:numSubstitutions = s:SetexToAtx(a:line1, a:line2)
+    let l:flags = (&gdefault ? '' : 'g')
     for l:level in range(replaceLevels[0], replaceLevels[1], -l:levelDelta)
-        execute 'silent! ' . a:line1 . ',' . (a:line2 - l:numSubstitutions) . 'substitute/' . s:levelRegexpDict[l:level] . '/' . repeat('#', l:level + l:levelDelta) . '/g'
+        execute 'silent! ' . a:line1 . ',' . (a:line2 - l:numSubstitutions) . 'substitute/' . s:levelRegexpDict[l:level] . '/' . repeat('#', l:level + l:levelDelta) . '/' . l:flags
     endfor
 endfunction
 
@@ -396,11 +456,17 @@ function! s:TableFormat()
     " Search instead of `normal! j` because of the table at beginning of file edge case.
     call search('|')
     normal! j
-    " Remove everything that is not a pipe othewise well formated tables would grow
-    " because of addition of 2 spaces on the separator line by Tabularize /|.
-    s/[^|]//g
+    " Remove everything that is not a pipe, colon or hyphen next to a colon othewise
+    " well formated tables would grow because of addition of 2 spaces on the separator
+    " line by Tabularize /|.
+    let l:flags = (&gdefault ? '' : 'g')
+    execute 's/\(:\@<!-:\@!\|[^|:-]\)//e' . l:flags
+    execute 's/--/-/e' . l:flags
     Tabularize /|
-    s/ /-/g
+    " Move colons for alignment to left or right side of the cell.
+    execute 's/:\( \+\)|/\1:|/e' . l:flags
+    execute 's/|\( \+\):/|:\1/e' . l:flags
+    execute 's/ /-/' . l:flags
     call setpos('.', l:pos)
 endfunction
 
@@ -551,3 +617,111 @@ command! -buffer Toc call s:Toc()
 command! -buffer Toch call s:Toc('horizontal')
 command! -buffer Tocv call s:Toc('vertical')
 command! -buffer Toct call s:Toc('tab')
+
+" Heavily based on vim-notes - http://peterodding.com/code/vim/notes/
+if exists('g:vim_markdown_fenced_languages')
+    let s:filetype_dict = {}
+    for s:filetype in g:vim_markdown_fenced_languages
+        let key = matchstr(s:filetype, "[^=]*")
+        let val = matchstr(s:filetype, "[^=]*$")
+        let s:filetype_dict[key] = val
+    endfor
+else
+    let s:filetype_dict = {
+        \ 'c++': 'cpp',
+        \ 'viml': 'vim',
+        \ 'bash': 'sh',
+        \ 'ini': 'dosini'
+    \ }
+endif
+
+function! s:MarkdownHighlightSources(force)
+    " Syntax highlight source code embedded in notes.
+    " Look for code blocks in the current file
+    let filetypes = {}
+    for line in getline(1, '$')
+        let ft = matchstr(line, '```\s*\zs[0-9A-Za-z_+-]*')
+        if !empty(ft) && ft !~ '^\d*$' | let filetypes[ft] = 1 | endif
+    endfor
+    if !exists('b:mkd_known_filetypes')
+        let b:mkd_known_filetypes = {}
+    endif
+    if !exists('b:mkd_included_filetypes')
+        " set syntax file name included
+        let b:mkd_included_filetypes = {}
+    endif
+    if !a:force && (b:mkd_known_filetypes == filetypes || empty(filetypes))
+        return
+    endif
+
+    " Now we're ready to actually highlight the code blocks.
+    let startgroup = 'mkdCodeStart'
+    let endgroup = 'mkdCodeEnd'
+    for ft in keys(filetypes)
+        if a:force || !has_key(b:mkd_known_filetypes, ft)
+            if has_key(s:filetype_dict, ft)
+                let filetype = s:filetype_dict[ft]
+            else
+                let filetype = ft
+            endif
+            let group = 'mkdSnippet' . toupper(substitute(filetype, "[+-]", "_", "g"))
+            if !has_key(b:mkd_included_filetypes, filetype)
+                let include = s:SyntaxInclude(filetype)
+                let b:mkd_included_filetypes[filetype] = 1
+            else
+                let include = '@' . toupper(filetype)
+            endif
+            let command = 'syntax region %s matchgroup=%s start="^\s*```\s*%s$" matchgroup=%s end="\s*```$" keepend contains=%s%s'
+            execute printf(command, group, startgroup, ft, endgroup, include, has('conceal') && get(g:, 'vim_markdown_conceal', 1) ? ' concealends' : '')
+            execute printf('syntax cluster mkdNonListItem add=%s', group)
+
+            let b:mkd_known_filetypes[ft] = 1
+        endif
+    endfor
+endfunction
+
+function! s:SyntaxInclude(filetype)
+    " Include the syntax highlighting of another {filetype}.
+    let grouplistname = '@' . toupper(a:filetype)
+    " Unset the name of the current syntax while including the other syntax
+    " because some syntax scripts do nothing when "b:current_syntax" is set
+    if exists('b:current_syntax')
+        let syntax_save = b:current_syntax
+        unlet b:current_syntax
+    endif
+    try
+        execute 'syntax include' grouplistname 'syntax/' . a:filetype . '.vim'
+        execute 'syntax include' grouplistname 'after/syntax/' . a:filetype . '.vim'
+    catch /E484/
+        " Ignore missing scripts
+    endtry
+    " Restore the name of the current syntax
+    if exists('syntax_save')
+        let b:current_syntax = syntax_save
+    elseif exists('b:current_syntax')
+        unlet b:current_syntax
+    endif
+    return grouplistname
+endfunction
+
+
+function! s:MarkdownRefreshSyntax(force)
+    if &filetype == 'markdown' && line('$') > 1
+        call s:MarkdownHighlightSources(a:force)
+    endif
+endfunction
+
+function! s:MarkdownClearSyntaxVariables()
+    if &filetype == 'markdown'
+        unlet! b:mkd_included_filetypes
+    endif
+endfunction
+
+augroup Mkd
+    autocmd!
+    au BufWinEnter * call s:MarkdownRefreshSyntax(1)
+    au BufUnload * call s:MarkdownClearSyntaxVariables()
+    au BufWritePost * call s:MarkdownRefreshSyntax(0)
+    au InsertEnter,InsertLeave * call s:MarkdownRefreshSyntax(0)
+    au CursorHold,CursorHoldI * call s:MarkdownRefreshSyntax(0)
+augroup END