.zsh/zshrc/10-xterm_title

   1 #
   2 # Fancy setting of the xterm title
   3 #
   4 # Copyright © 1994–2017 martin f. krafft <madduck@madduck.net>
   5 # Released under the terms of the Artistic Licence 2.0
   6 #
   7 # Source repository: http://git.madduck.net/v/etc/zsh.git
   8 #
   9 # Based on http://www.zshwiki.org/cgi-bin/wiki.pl?ZshHardStatus
  10 #
  11
  12 autoload -U add-zsh-hook
  13
  14 __set_xterm_title() {
  15   emulate -L zsh
  16   local typ
  17   case $TERM in
  18     (tmux|tmux-*) typ=tmux;;
  19     (screen|screen-*) if [ -n "$TMUX" ]; then typ=tmux else typ=screen fi;;
  20     (*) typ=xterm
  21   esac
  22
  23   case "$typ" in
  24     (xterm) print -nR $'\033]0;'$*$'\a';;
  25     (screen)
  26       print -nR $'\033k'$1$'\033'\\
  27       print -nR $'\033]0;'$2$'\a'
  28       ;;
  29     (tmux) print -nR $'\033]2;'$*$'\a';;
  30   esac
  31 }
  32
  33 __get_session_flags() {
  34   emulate -L zsh
  35   [ -n "$SSH_CONNECTION" ] || return
  36   local flags
  37   [ -n "$DISPLAY" ] && flags+=x
  38   [ -n "$SSH_AUTH_SOCK" ] && flags+=a
  39   [[ $SSH_CLIENT = *:* ]] && flags+=6
  40   [ -n "$flags" ] && echo "[${flags}]"
  41 }
  42
  43 __get_standard_prompt() {
  44   emulate -L zsh
  45   print -n "[${${(%):-%l}#pts/}]"
  46   [[ -z $SSH_CLIENT ]] || print -nP "%m"
  47   print -P "%#%25\<..\<%~ $(__get_session_flags)"
  48 }
  49
  50 _set_plain_xterm_title() {
  51   emulate -L zsh
  52   __set_xterm_title "$(__get_standard_prompt)"
  53 }
  54 add-zsh-hook precmd _set_plain_xterm_title
  55
  56 _set_cmd_xterm_title () {
  57   emulate -L zsh
  58   local -a cmd; cmd=(${(z)1})             # Re-parse the command line
  59
  60   # Construct a command that will output the desired job number.
  61   case $cmd[1] in
  62     fg) if (( $#cmd == 1 )); then
  63           # No arguments, must find the current job
  64           cmd=(builtin jobs -l %+)
  65         else
  66           # Replace the command name, ignore extra args.
  67           cmd=(builtin jobs -l ${(Q)cmd[2]})
  68         fi;;
  69     %*) cmd=(builtin jobs -l ${(Q)cmd[1]});; # Same as "else" above
  70     *) # Not resuming a job,
  71       __set_xterm_title $cmd[1]:t${cmd[2]:+ }$cmd[2,-1] "| $(__get_standard_prompt)"
  72       return;;                        # so we're all done
  73   esac
  74
  75   local -A jt; jt=(${(kv)jobtexts})       # Copy jobtexts for subshell
  76
  77   # Run the command, read its output, and look up the jobtext.
  78   # Could parse $rest here, but $jobtexts (via $jt) is easier.
  79   $cmd 2>/dev/null >>(read num rest; cmd=(${(z)${(e):-\$jt$num}};)
  80   __set_xterm_title $leader$cmd[1]:t${cmd[2]:+ }$cmd[2,-1] "| $(__get_standard_prompt)"
  81 )
  82 }
  83 add-zsh-hook preexec _set_cmd_xterm_title
  84
  85 # vim:ft=zsh