# zshrc/30_aliases
#
# Defines command shortcuts
#
# Copyright © 1994–2008 martin f. krafft <madduck@madduck.net>
# Released under the terms of the Artistic Licence 2.0
#
# Source repository: http://git.madduck.net/v/etc/zsh.git
#

alias mv='nocorrect mv'
alias cp='nocorrect cp'
alias ln='nocorrect ln'
alias mkdir='nocorrect mkdir'
alias rm='nocorrect rm'

alias find='noglob find'
alias w3m='noglob w3m -no-mouse'
alias links='noglob links'
alias wb='noglob www-browser'
alias wget='noglob wget'
alias curl='noglob curl'
alias apt-cache='noglob apt-cache'
alias locate='noglob locate'

_LS_OPTS='-bCF --color=auto'
ls --group-directories-first >/dev/null 2>&1 \
  && _LS_OPTS="$_LS_OPTS --group-directories-first"
# I prefer POSIX collation for ls
alias ls="LC_COLLATE=POSIX ls $_LS_OPTS"
unset _LS_OPTS

alias ll='ls -l'
alias l=ll
alias la='ls -a'
alias lla='ls -la'
# List only directories and symbolic links that point to directories
alias lsd='ls -ld *(-/DN)'

alias lsbig="ls -flh *(.OL[1,10])"
alias lssmall="ls -Srl *(.oL[1,10])"
alias lsnew="ls -rl *(D.om[1,10])"
alias lsold="ls -rtlh *(D.om[1,10])"

alias egrep='egrep --color=auto -d skip'
alias fgrep='fgrep --color=auto -d skip'
alias grep='grep --color=auto -d skip'

alias mmv='noglob zmv -W'
alias zcp='zmv -C'
alias zln='zmv -L'
alias zgmv='zmv -p git-mv'

alias cal='cal -3'
alias ftp=lftp

alias mbug='bts show --mbox'
alias bug='BROWSER=www-browser bts show'

# handy documentation lookup on Debian
# from http://www.michael-prokop.at/computer/config/.zshrc
doc() { cd /usr/share/doc/$1 && ls }
_doc() { _files -W /usr/share/doc -/ }
compdef _doc doc

alias giti='git init && git add . && git commit -minitial\ checkin'

if whence tailf >/dev/null; then
  alias t=tailf
else
  alias t='tail -f'
fi
alias tsl='t /var/log/syslog'
alias tml='t /var/log/mail.log'
alias tal='t /var/log/auth.log'
alias tdl='t /var/log/daemon.log'
alias tkl='t /var/log/kern.log'

alias px='ps afux'
alias mps='ps -ao user,pcpu,start,command'

alias bofh='fortune bofh-excuses'

autoload -U baseconv
alias b2d='baseconv 2 10'
alias d2b='baseconv 10 2'
alias d2h='baseconv 10 16'
alias h2d='baseconv 16 10'
alias d2o='baseconv 10 8'
alias o2d='baseconv 8 10'

alias sshnew='ssh -o "StrictHostKeyChecking no"'
alias scpnew='scp -o "StrictHostKeyChecking no"'
alias sshtmp='sshnew -o "UserKnownHostsFile /dev/null"'
alias scptmp='scpnew -o "UserKnownHostsFile /dev/null"'

alias sendmail=/usr/sbin/sendmail

_d() { dict $* }
d() { _d $* | sensible-pager }
the() { d -d moby-thesaurus $* }
typeset -A _LANGUAGES
_LANGUAGES[en]=eng
_LANGUAGES[de]=deu
_LANGUAGES[es]=spa
_LANGUAGES[fr]=fra
_LANGUAGES[it]=ita
_LANGUAGES[lt]=lat
for l0 in ${(k)_LANGUAGES}; do
  for l1 in ${(k)_LANGUAGES}; do
    eval "_${l0}-${l1}() { _d -d fd-${_LANGUAGES[$l0]}-${_LANGUAGES[$l1]} \$* }"
    eval "${l0}-${l1}() { d -d fd-${_LANGUAGES[$l0]}-${_LANGUAGES[$l1]} \$* }"
  done
done
unset '_LANGUAGES[en]'
for l in ${(k)_LANGUAGES}; do
  eval "${l}() { (_${l}-en \$*; _en-${l} \$*) | more }"
done
unset _LANGUAGES

# vim:ft=zsh