_vcsh

   1 #compdef vcsh
   2
   3 function __vcsh_repositories () {
   4         local expl
   5         local -a repos
   6         repos=( ${(f)"$(command vcsh list)"} )
   7         _describe -t repos 'repositories' repos
   8 }
   9
  10 function __vcsh_not_implemented_yet () {
  11         _message "Subcommand completion '${1#*-}': not implemented yet"
  12 }
  13
  14 function _vcsh-clone () {
  15         __vcsh_not_implemented_yet "$0" #TODO
  16 }
  17
  18 function _vcsh-delete () {
  19         (( CURRENT == 2 )) && __vcsh_repositories
  20 }
  21
  22 function _vcsh-enter () {
  23         (( CURRENT == 2 )) && __vcsh_repositories
  24 }
  25
  26 function _vcsh-foreach () {
  27         _dispatch git git
  28 }
  29
  30 function _vcsh-help () {
  31         _nothing
  32 }
  33
  34 function _vcsh-init () {
  35         _nothing
  36 }
  37
  38 function _vcsh-list () {
  39         _nothing
  40 }
  41
  42 function _vcsh-list-tracked () {
  43         _nothing
  44 }
  45
  46 function _vcsh-list-tracked-by () {
  47         (( CURRENT == 2 )) && __vcsh_repositories
  48 }
  49
  50 function _vcsh-list-untracked () {
  51         _nothing
  52 }
  53
  54 function _vcsh-pull () {
  55         _nothing
  56 }
  57
  58 function _vcsh-push () {
  59         _nothing
  60 }
  61
  62 function _vcsh-rename () {
  63         (( CURRENT == 2 )) && __vcsh_repositories
  64         (( CURRENT == 3 )) && _message "new repository name"
  65         (( CURRENT > 3 )) && _nothing
  66 }
  67
  68 function _vcsh-run () {
  69         (( CURRENT == 2 )) && __vcsh_repositories
  70         if (( CURRENT >= 3 )); then
  71                 words=( "${(@)words[3,-1]}" )
  72                 (( CURRENT -= 2 ))
  73                 _complete
  74         fi
  75 }
  76
  77 function _vcsh-status () {
  78         (( CURRENT == 2 )) && __vcsh_repositories
  79 }
  80
  81 function _vcsh-upgrade () {
  82         (( CURRENT == 2 )) && __vcsh_repositories
  83 }
  84
  85 function _vcsh-version () {
  86         _nothing
  87 }
  88
  89 function _vcsh-which () {
  90         _files
  91 }
  92
  93 function _vcsh-write-gitignore () {
  94         (( CURRENT == 2 )) && __vcsh_repositories
  95 }
  96
  97 function _vcsh () {
  98         local curcontext="${curcontext}"
  99         local state vcshcommand
 100         local -a args subcommands
 101
 102         subcommands=(
 103                 "clone:clone an existing repository"
 104                 "commit:commit in all repositories"
 105                 "delete:delete an existing repository"
 106                 "enter:enter repository; spawn new <\$SHELL>"
 107                 "foreach:execute for all repos"
 108                 "help:display help"
 109                 "init:initialize an empty repository"
 110                 "list:list all local vcsh repositories"
 111                 "list-tracked:list all files tracked by vcsh"
 112                 "list-tracked-by:list files tracked by a repository"
 113                 "list-untracked:list all files not tracked by vcsh"
 114                 "pull:pull from all vcsh remotes"
 115                 "push:push to vcsh remotes"
 116                 "rename:rename a repository"
 117                 "run:run command with <\$GIT_DIR> and <\$GIT_WORK_TREE> set"
 118                 "status:show statuses of all/one vcsh repositories"
 119                 "upgrade:upgrade repository to currently recommended settings"
 120                 "version:print version information"
 121                 "which:find <substring> in name of any tracked file"
 122                 "write-gitignore:write .gitignore.d/<repo> via git ls-files"
 123         )
 124
 125         args=(
 126                 '-c[source <file> prior to other configuration files]:config files:_path_files'
 127                 '-d[enable debug mode]'
 128                 '-v[enable verbose mode]'
 129                 '*:: :->subcommand_or_options_or_repo'
 130         )
 131
 132         _arguments -C ${args} && return
 133
 134         if [[ ${state} == "subcommand_or_options_or_repo" ]]; then
 135                 if (( CURRENT == 1 )); then
 136                         _describe -t subcommands 'vcsh sub-commands' subcommands
 137                         __vcsh_repositories
 138                 else
 139                         vcshcommand="${words[1]}"
 140                         if ! (( ${+functions[_vcsh-$vcshcommand]} )); then
 141                                 # There is no handler function, so this is probably the name
 142                                 # of a repository. Act accordingly.
 143                                 _dispatch git git
 144                         else
 145                                 curcontext="${curcontext%:*:*}:vcsh-${vcshcommand}:"
 146                                 _call_function ret _vcsh-${vcshcommand}
 147                         fi
 148                 fi
 149         fi
 150 }
 151
 152 _vcsh "$@"