indent/markdown.vim

   1 if exists("b:did_indent") | finish | endif
   2 let b:did_indent = 1
   3
   4 setlocal indentexpr=GetMarkdownIndent()
   5 setlocal nolisp
   6 setlocal autoindent
   7
   8 " Automatically insert bullets
   9 setlocal formatoptions+=r
  10 " Do not automatically insert bullets when auto-wrapping with text-width
  11 setlocal formatoptions-=c
  12 " Accept various markers as bullets
  13 setlocal comments=b:*,b:+,b:-
  14
  15 " Automatically continue blockquote on line break
  16 setlocal comments+=b:>
  17
  18 " Only define the function once
  19 if exists("*GetMarkdownIndent") | finish | endif
  20
  21 function! s:IsMkdCode(lnum)
  22     let name = synIDattr(synID(a:lnum, 1, 0), 'name')
  23     return (name =~ '^mkd\%(Code$\|Snippet\)' || name != '' && name !~ '^\%(mkd\|html\)')
  24 endfunction
  25
  26 function! s:IsLiStart(line)
  27     return a:line !~ '^ *\([*-]\)\%( *\1\)\{2}\%( \|\1\)*$' &&
  28       \    a:line =~ '^\s*[*+-] \+'
  29 endfunction
  30
  31 function! s:IsBlankLine(line)
  32     return a:line =~ '^$'
  33 endfunction
  34
  35 function! s:PrevNonBlank(lnum)
  36     let i = a:lnum
  37     while i > 1 && s:IsBlankLine(getline(i))
  38         let i -= 1
  39     endwhile
  40     return i
  41 endfunction
  42
  43 function GetMarkdownIndent()
  44     if v:lnum > 2 && s:IsBlankLine(getline(v:lnum - 1)) && s:IsBlankLine(getline(v:lnum - 2))
  45         return 0
  46     endif
  47     let list_ind = 4
  48     " Find a non-blank line above the current line.
  49     let lnum = s:PrevNonBlank(v:lnum - 1)
  50     " At the start of the file use zero indent.
  51     if lnum == 0 | return 0 | endif
  52     let ind = indent(lnum)
  53     let line = getline(lnum)    " Last line
  54     let cline = getline(v:lnum) " Current line
  55     if s:IsLiStart(cline)
  56         " Current line is the first line of a list item, do not change indent
  57         return indent(v:lnum)
  58     elseif s:IsLiStart(line)
  59         if s:IsMkdCode(lnum)
  60             return ind
  61         else
  62             " Last line is the first line of a list item, increase indent
  63             return ind + list_ind
  64         end
  65     else
  66         return ind
  67     endif
  68 endfunction