syntax/mkd.vim

   1 " Vim syntax file
   2 " Language:     Markdown
   3 " Maintainer:   Ben Williams <benw@plasticboy.com>
   4 " URL:          http://plasticboy.com/markdown-vim-mode/
   5 " Version:      9
   6 " Last Change:  2009 May 18
   7 " Remark:       Uses HTML syntax file
   8 " Remark:       I don't do anything with angle brackets (<>) because that would too easily
   9 "               easily conflict with HTML syntax
  10 " TODO:         Handle stuff contained within stuff (e.g. headings within blockquotes)
  11
  12
  13 " Read the HTML syntax to start with
  14 if version < 600
  15   so <sfile>:p:h/html.vim
  16 else
  17   runtime! syntax/html.vim
  18
  19   if exists('b:current_syntax')
  20     unlet b:current_syntax
  21   endif
  22 endif
  23
  24 if version < 600
  25   syntax clear
  26 elseif exists("b:current_syntax")
  27   finish
  28 endif
  29
  30 " don't use standard HiLink, it will not work with included syntax files
  31 if version < 508
  32   command! -nargs=+ HtmlHiLink hi link <args>
  33 else
  34   command! -nargs=+ HtmlHiLink hi def link <args>
  35 endif
  36
  37 syn spell toplevel
  38 syn case ignore
  39 syn sync linebreaks=1
  40
  41 "additions to HTML groups
  42 syn region htmlItalic start="\\\@<!\*\S\@=" end="\S\@<=\\\@<!\*" keepend oneline
  43 syn region htmlItalic start="\(^\|\s\)\@<=_\|\\\@<!_\([^_]\+\s\)\@=" end="\S\@<=_\|_\S\@=" keepend oneline
  44 syn region htmlBold start="\S\@<=\*\*\|\*\*\S\@=" end="\S\@<=\*\*\|\*\*\S\@=" keepend oneline
  45 syn region htmlBold start="\S\@<=__\|__\S\@=" end="\S\@<=__\|__\S\@=" keepend oneline
  46 syn region htmlBoldItalic start="\S\@<=\*\*\*\|\*\*\*\S\@=" end="\S\@<=\*\*\*\|\*\*\*\S\@=" keepend oneline
  47 syn region htmlBoldItalic start="\S\@<=___\|___\S\@=" end="\S\@<=___\|___\S\@=" keepend oneline
  48
  49 " [link](URL) | [link][id] | [link][]
  50 syn region mkdFootnotes matchgroup=mkdDelimiter start="\[^"    end="\]"
  51 syn region mkdID matchgroup=mkdDelimiter        start="\["    end="\]" contained oneline
  52 syn region mkdURL matchgroup=mkdDelimiter       start="("     end=")"  contained oneline
  53 syn region mkdLink matchgroup=mkdDelimiter      start="\\\@<!\[" end="\]\ze\s*[[(]" contains=@Spell nextgroup=mkdURL,mkdID skipwhite oneline
  54 " mkd  inline links:           protocol   optional  user:pass@       sub/domain                 .com, .co.uk, etc      optional port   path/querystring/hash fragment
  55 "                            ------------ _____________________ --------------------------- ________________________ ----------------- __
  56 syntax match   mkdInlineURL /https\?:\/\/\(\w\+\(:\w\+\)\?@\)\?\([A-Za-z][-_0-9A-Za-z]*\.\)\{1,}\(\w\{2,}\.\?\)\{1,}\(:[0-9]\{1,5}\)\?\S*/
  57
  58 " Link definitions: [id]: URL (Optional Title)
  59 " TODO handle automatic links without colliding with htmlTag (<URL>)
  60 syn region mkdLinkDef matchgroup=mkdDelimiter   start="^ \{,3}\zs\[" end="]:" oneline nextgroup=mkdLinkDefTarget skipwhite
  61 syn region mkdLinkDefTarget start="<\?\zs\S" excludenl end="\ze[>[:space:]\n]"   contained nextgroup=mkdLinkTitle,mkdLinkDef skipwhite skipnl oneline
  62 syn region mkdLinkTitle matchgroup=mkdDelimiter start=+"+     end=+"+  contained
  63 syn region mkdLinkTitle matchgroup=mkdDelimiter start=+'+     end=+'+  contained
  64 syn region mkdLinkTitle matchgroup=mkdDelimiter start=+(+     end=+)+  contained
  65
  66 "define Markdown groups
  67 syn match  mkdLineContinue ".$" contained
  68 syn match  mkdLineBreak    /  \+$/
  69 syn region mkdBlockquote   start=/^\s*>/                   end=/$/ contains=mkdLineBreak,mkdLineContinue,@Spell
  70 syn region mkdCode         start=/\(\([^\\]\|^\)\\\)\@<!`/ end=/\(\([^\\]\|^\)\\\)\@<!`/
  71 syn region mkdCode         start=/\s*``[^`]*/              end=/[^`]*``\s*/
  72 syn region mkdCode         start=/^```\s*[0-9A-Za-z_-]*\s*$/          end=/^```\s*$/
  73 syn region mkdCode         start="<pre[^>]*>"              end="</pre>"
  74 syn region mkdCode         start="<code[^>]*>"             end="</code>"
  75 syn region mkdFootnote     start="\[^"                     end="\]"
  76 syn match  mkdCode         /^\s*\n\(\(\s\{8,}[^ ]\|\t\t\+[^\t]\).*\n\)\+/
  77 syn match  mkdIndentCode   /^\s*\n\(\(\s\{4,}[^ ]\|\t\+[^\t]\).*\n\)\+/ contained
  78 syn match  mkdListItem     "^\s*[-*+]\s\+"
  79 syn match  mkdListItem     "^\s*\d\+\.\s\+"
  80 syn region mkdNonListItemBlock start="\n\(\_^\_$\|\s\{4,}[^ ]\|\t+[^\t]\)\@!" end="^\(\s*\([-*+]\|\d\+\.\)\s\+\)\@=" contains=@mkdNonListItem, @Spell
  81 syn match  mkdRule         /^\s*\*\s\{0,1}\*\s\{0,1}\*$/
  82 syn match  mkdRule         /^\s*-\s\{0,1}-\s\{0,1}-$/
  83 syn match  mkdRule         /^\s*_\s\{0,1}_\s\{0,1}_$/
  84 syn match  mkdRule         /^\s*-\{3,}$/
  85 syn match  mkdRule         /^\s*\*\{3,5}$/
  86
  87 "HTML headings
  88 syn region htmlH1       start="^\s*#"                   end="\($\|#\+\)" contains=@Spell
  89 syn region htmlH2       start="^\s*##"                  end="\($\|#\+\)" contains=@Spell
  90 syn region htmlH3       start="^\s*###"                 end="\($\|#\+\)" contains=@Spell
  91 syn region htmlH4       start="^\s*####"                end="\($\|#\+\)" contains=@Spell
  92 syn region htmlH5       start="^\s*#####"               end="\($\|#\+\)" contains=@Spell
  93 syn region htmlH6       start="^\s*######"              end="\($\|#\+\)" contains=@Spell
  94 syn match  htmlH1       /^.\+\n=\+$/ contains=@Spell
  95 syn match  htmlH2       /^.\+\n-\+$/ contains=@Spell
  96
  97 syn cluster mkdNonListItem contains=htmlItalic,htmlBold,htmlBoldItalic,mkdFootnotes,mkdID,mkdURL,mkdLink,mkdLinkDef,mkdLineBreak,mkdBlockquote,mkdCode,mkdIndentCode,mkdListItem,mkdRule,htmlH1,htmlH2,htmlH3,htmlH4,htmlH5,htmlH6
  98
  99 "highlighting for Markdown groups
 100 HtmlHiLink mkdString        String
 101 HtmlHiLink mkdCode          String
 102 HtmlHiLink mkdIndentCode    String
 103 HtmlHiLink mkdFootnote    Comment
 104 HtmlHiLink mkdBlockquote    Comment
 105 HtmlHiLink mkdLineContinue  Comment
 106 HtmlHiLink mkdListItem      Identifier
 107 HtmlHiLink mkdRule          Identifier
 108 HtmlHiLink mkdLineBreak     Todo
 109 HtmlHiLink mkdFootnotes     htmlLink
 110 HtmlHiLink mkdLink          htmlLink
 111 HtmlHiLink mkdURL           htmlString
 112 HtmlHiLink mkdInlineURL     htmlLink
 113 HtmlHiLink mkdID            Identifier
 114 HtmlHiLink mkdLinkDef       mkdID
 115 HtmlHiLink mkdLinkDefTarget mkdURL
 116 HtmlHiLink mkdLinkTitle     htmlString
 117
 118 HtmlHiLink mkdDelimiter     Delimiter
 119
 120 " Automatically insert bullets
 121 setlocal formatoptions+=r
 122 " Accept various markers as bullets
 123 setlocal comments=b:*,b:+,b:-
 124
 125 let b:current_syntax = "mkd"
 126
 127 delcommand HtmlHiLink
 128 " vim: ts=8