syntax/markdown.vim

   1 " Vim syntax file
   2 " Language:     Markdown
   3 " Maintainer:   Ben Williams <benw@plasticboy.com>
   4 " URL:          http://plasticboy.com/markdown-vim-mode/
   5 " Remark:       Uses HTML syntax file
   6 " TODO:         Handle stuff contained within stuff (e.g. headings within blockquotes)
   7
   8
   9 " Read the HTML syntax to start with
  10 if version < 600
  11   so <sfile>:p:h/html.vim
  12 else
  13   runtime! syntax/html.vim
  14
  15   if exists('b:current_syntax')
  16     unlet b:current_syntax
  17   endif
  18 endif
  19
  20 if version < 600
  21   syntax clear
  22 elseif exists("b:current_syntax")
  23   finish
  24 endif
  25
  26 " don't use standard HiLink, it will not work with included syntax files
  27 if version < 508
  28   command! -nargs=+ HtmlHiLink hi link <args>
  29 else
  30   command! -nargs=+ HtmlHiLink hi def link <args>
  31 endif
  32
  33 syn spell toplevel
  34 syn case ignore
  35 syn sync linebreaks=1
  36
  37 let s:conceal = ''
  38 let s:concealends = ''
  39 if has('conceal')
  40   let s:conceal = ' conceal'
  41   let s:concealends = ' concealends'
  42 endif
  43
  44 "additions to HTML groups
  45 if get(g:, "vim_markdown_emphasis_multiline", 1)
  46     syn region htmlItalic start="\%(^\|\s\)\zs\*\ze[^\\\*\t ]" end="[^\\\*\t ]\zs\*\ze\_W" keepend
  47     syn region htmlItalic start="\%(^\|\s\)\zs_\ze[^\\_\t ]" end="[^\\_\t ]\zs_\ze\_W" keepend
  48     syn region htmlBold start="\*\*\ze\S" end="\S\zs\*\*" keepend
  49     syn region htmlBold start="__\ze\S" end="\S\zs__" keepend
  50     syn region htmlBoldItalic start="\*\*\*\ze\S" end="\S\zs\*\*\*" keepend
  51     syn region htmlBoldItalic start="___\ze\S" end="\S\zs___" keepend
  52 else
  53     " single-line emphasis (emphasis only works with closing token on the same line)
  54     " the following character makes the match non-greedy:          vv
  55     syn region htmlItalic start="\%(^\|\s\)\zs\*\ze[^\\\*\t ]\([^\n\*]*[^\\\*\t ]\)\?\*" end="[^\\\*\t ]\zs\*\ze\_W" keepend
  56     syn region htmlItalic start="\%(^\|\s\)\zs_\ze[^\\_\t ]\([^\n_]*[^\\_\t ]\)\?_" end="[^\\_\t ]\zs_\ze\_W" keepend
  57     syn region htmlBold start="\*\*\ze\S\([^\n\*]*[^\\\*\t ]\)\?\*\*" end="\S\zs\*\*" keepend
  58     syn region htmlBold start="__\ze\S\([^\n_]*[^\\_\t ]\)\?__" end="\S\zs__" keepend
  59     syn region htmlBold start="\*\*\*\ze\S\([^\n\*]*[^\\\*\t ]\)\?\*\*\*" end="\S\zs\*\*\*" keepend
  60     syn region htmlBold start="___\ze\S\([^\n_]*[^\\_\t ]\)\?___" end="\S\zs___" keepend
  61 endif
  62
  63 " [link](URL) | [link][id] | [link][] | ![image](URL)
  64 syn region mkdFootnotes matchgroup=mkdDelimiter start="\[^"    end="\]"
  65 execute 'syn region mkdID matchgroup=mkdDelimiter    start="\["    end="\]" contained oneline' . s:conceal
  66 execute 'syn region mkdURL matchgroup=mkdDelimiter   start="("     end=")"  contained oneline' . s:conceal
  67 execute 'syn region mkdLink matchgroup=mkdDelimiter  start="\\\@<!!\?\[" end="\n\{-,1}[^]]\{-}\zs\]\ze[[(]" contains=@mkdNonListItem,@Spell nextgroup=mkdURL,mkdID skipwhite oneline' . s:concealends
  68
  69 " Autolink without angle brackets.
  70 " mkd  inline links:           protocol   optional  user:pass@       sub/domain                 .com, .co.uk, etc      optional port   path/querystring/hash fragment
  71 "                            ------------ _____________________ --------------------------- ________________________ ----------------- __
  72 syntax match   mkdInlineURL /https\?:\/\/\(\w\+\(:\w\+\)\?@\)\?\([A-Za-z][-_0-9A-Za-z]*\.\)\{1,}\(\w\{2,}\.\?\)\{1,}\(:[0-9]\{1,5}\)\?\S*/
  73
  74 " Autolink with parenthesis.
  75 syntax region  mkdInlineURL matchgroup=mkdDelimiter start="(\(https\?:\/\/\(\w\+\(:\w\+\)\?@\)\?\([A-Za-z][-_0-9A-Za-z]*\.\)\{1,}\(\w\{2,}\.\?\)\{1,}\(:[0-9]\{1,5}\)\?\S*)\)\@=" end=")"
  76
  77 " Autolink with angle brackets.
  78 syn region mkdInlineURL matchgroup=mkdDelimiter start="\\\@<!<\ze[a-z][a-z0-9,.-]\{1,22}:\/\/[^> ]*>" end=">"
  79
  80 " Link definitions: [id]: URL (Optional Title)
  81 syn region mkdLinkDef matchgroup=mkdDelimiter   start="^ \{,3}\zs\[" end="]:" oneline nextgroup=mkdLinkDefTarget skipwhite
  82 syn region mkdLinkDefTarget start="<\?\zs\S" excludenl end="\ze[>[:space:]\n]"   contained nextgroup=mkdLinkTitle,mkdLinkDef skipwhite skipnl oneline
  83 syn region mkdLinkTitle matchgroup=mkdDelimiter start=+"+     end=+"+  contained
  84 syn region mkdLinkTitle matchgroup=mkdDelimiter start=+'+     end=+'+  contained
  85 syn region mkdLinkTitle matchgroup=mkdDelimiter start=+(+     end=+)+  contained
  86
  87 "HTML headings
  88 syn region htmlH1       start="^\s*#"                   end="$" contains=@Spell
  89 syn region htmlH2       start="^\s*##"                  end="$" contains=@Spell
  90 syn region htmlH3       start="^\s*###"                 end="$" contains=@Spell
  91 syn region htmlH4       start="^\s*####"                end="$" contains=@Spell
  92 syn region htmlH5       start="^\s*#####"               end="$" contains=@Spell
  93 syn region htmlH6       start="^\s*######"              end="$" contains=@Spell
  94 syn match  htmlH1       /^.\+\n=\+$/ contains=@Spell
  95 syn match  htmlH2       /^.\+\n-\+$/ contains=@Spell
  96
  97 "define Markdown groups
  98 syn match  mkdLineBreak    /  \+$/
  99 syn region mkdBlockquote   start=/^\s*>/                   end=/$/ contains=mkdLineBreak,@Spell
 100 syn region mkdCode         start=/\(\([^\\]\|^\)\\\)\@<!`/ end=/\(\([^\\]\|^\)\\\)\@<!`/
 101 syn region mkdCode         start=/\s*``[^`]*/              end=/[^`]*``\s*/
 102 syn region mkdCode         start=/^\s*\z(`\{3,}\)[^`]*$/   end=/^\s*\z1`*\s*$/
 103 syn region mkdCode         start=/\s*\~\~[^\~]*/           end=/[^\~]*\~\~\s*/
 104 syn region mkdCode         start=/^\s*\z(\~\{3,}\)\s*[0-9A-Za-z_+-]*\s*$/         end=/^\s*\z1\~*\s*$/
 105 syn region mkdCode         start="<pre[^>]*\\\@<!>"        end="</pre>"
 106 syn region mkdCode         start="<code[^>]*\\\@<!>"       end="</code>"
 107 syn region mkdFootnote     start="\[^"                     end="\]"
 108 syn match  mkdCode         /^\s*\n\(\(\s\{8,}[^ ]\|\t\t\+[^\t]\).*\n\)\+/
 109 syn match  mkdCode         /\%^\(\(\s\{4,}[^ ]\|\t\+[^\t]\).*\n\)\+/
 110 syn match  mkdCode         /^\s*\n\(\(\s\{4,}[^ ]\|\t\+[^\t]\).*\n\)\+/ contained
 111 syn match  mkdListItem     /^\s*\%([-*+]\|\d\+\.\)\s\+/ contained
 112 syn region mkdListItemLine start="^\s*\%([-*+]\|\d\+\.\)\s\+" end="$" oneline contains=@mkdNonListItem,mkdListItem,@Spell
 113 syn region mkdNonListItemBlock start="\(\%^\(\s*\([-*+]\|\d\+\.\)\s\+\)\@!\|\n\(\_^\_$\|\s\{4,}[^ ]\|\t+[^\t]\)\@!\)" end="^\(\s*\([-*+]\|\d\+\.\)\s\+\)\@=" contains=@mkdNonListItem,@Spell
 114 syn match  mkdRule         /^\s*\*\s\{0,1}\*\s\{0,1}\*$/
 115 syn match  mkdRule         /^\s*-\s\{0,1}-\s\{0,1}-$/
 116 syn match  mkdRule         /^\s*_\s\{0,1}_\s\{0,1}_$/
 117 syn match  mkdRule         /^\s*-\{3,}$/
 118 syn match  mkdRule         /^\s*\*\{3,5}$/
 119
 120 " YAML frontmatter
 121 if get(g:, 'vim_markdown_frontmatter', 0)
 122   syn include @yamlTop syntax/yaml.vim
 123   syn region Comment matchgroup=mkdDelimiter start="\%^---$" end="^---$" contains=@yamlTop
 124   unlet! b:current_syntax
 125 endif
 126
 127 if get(g:, 'vim_markdown_toml_frontmatter', 0)
 128   try
 129     syn include @tomlTop syntax/toml.vim
 130     syn region Comment matchgroup=mkdDelimiter start="\%^+++$" end="^+++$" transparent contains=@tomlTop
 131     unlet! b:current_syntax
 132   catch /E484/
 133     syn region Comment matchgroup=mkdDelimiter start="\%^+++$" end="^+++$"
 134   endtry
 135 endif
 136
 137 if get(g:, 'vim_markdown_json_frontmatter', 0)
 138   try
 139     syn include @jsonTop syntax/json.vim
 140     syn region Comment matchgroup=mkdDelimiter start="\%^{$" end="^}$" contains=@jsonTop
 141     unlet! b:current_syntax
 142   catch /E484/
 143     syn region Comment matchgroup=mkdDelimiter start="\%^{$" end="^}$"
 144   endtry
 145 endif
 146
 147 if get(g:, 'vim_markdown_math', 0)
 148   syn include @tex syntax/tex.vim
 149   syn region mkdMath matchgroup=mkdDelimiter start="\\\@<!\$" end="\$" contains=@tex
 150   syn region mkdMath matchgroup=mkdDelimiter start="\\\@<!\$\$" end="\$\$" contains=@tex
 151 endif
 152
 153 syn cluster mkdNonListItem contains=@htmlTop,htmlItalic,htmlBold,htmlBoldItalic,mkdFootnotes,mkdInlineURL,mkdLink,mkdLinkDef,mkdLineBreak,mkdBlockquote,mkdCode,mkdRule,htmlH1,htmlH2,htmlH3,htmlH4,htmlH5,htmlH6,mkdMath
 154
 155 "highlighting for Markdown groups
 156 HtmlHiLink mkdString        String
 157 HtmlHiLink mkdCode          String
 158 HtmlHiLink mkdCodeStart     String
 159 HtmlHiLink mkdCodeEnd       String
 160 HtmlHiLink mkdFootnote      Comment
 161 HtmlHiLink mkdBlockquote    Comment
 162 HtmlHiLink mkdListItem      Identifier
 163 HtmlHiLink mkdRule          Identifier
 164 HtmlHiLink mkdLineBreak     Todo
 165 HtmlHiLink mkdFootnotes     htmlLink
 166 HtmlHiLink mkdLink          htmlLink
 167 HtmlHiLink mkdURL           htmlString
 168 HtmlHiLink mkdInlineURL     htmlLink
 169 HtmlHiLink mkdID            Identifier
 170 HtmlHiLink mkdLinkDef       mkdID
 171 HtmlHiLink mkdLinkDefTarget mkdURL
 172 HtmlHiLink mkdLinkTitle     htmlString
 173 HtmlHiLink mkdDelimiter     Delimiter
 174
 175 let b:current_syntax = "mkd"
 176
 177 delcommand HtmlHiLink
 178 " vim: ts=8