ftplugin/python_flake8.vim

   1 "
   2 " Python filetype plugin for running flake8
   3 " Language:     Python (ft=python)
   4 " Maintainer:   Vincent Driessen <vincent@datafox.nl>
   5 " Version:      Vim 7 (may work with lower Vim versions, but not tested)
   6 " URL:          http://github.com/nvie/vim-flake8
   7 "
   8 " Only do this when not done yet for this buffer
   9 if exists("b:loaded_flake8_ftplugin")
  10     finish
  11 endif
  12 let b:loaded_flake8_ftplugin=1
  13
  14 if exists("g:flake8_cmd")
  15     let s:flake8_cmd=g:flake8_cmd
  16 else
  17     let s:flake8_cmd="flake8"
  18 endif
  19
  20 let s:flake8_ignores=""
  21 if exists("g:flake8_ignore")
  22     let s:flake8_ignores=" --ignore=".g:flake8_ignore
  23 endif
  24
  25 if !exists("*Flake8()")
  26     function Flake8()
  27         if !executable(s:flake8_cmd)
  28             echoerr "File " . s:flake8_cmd . " not found. Please install it first."
  29             return
  30         endif
  31
  32         set lazyredraw   " delay redrawing
  33         cclose           " close any existing cwindows
  34
  35         " store old grep settings (to restore later)
  36         let l:old_gfm=&grepformat
  37         let l:old_gp=&grepprg
  38
  39         " write any changes before continuing
  40         if &readonly == 0
  41             update
  42         endif
  43
  44         " perform the grep itself
  45         let &grepformat="%f:%l:%c: %m\,%f:%l: %m"
  46         let &grepprg=s:flake8_cmd.s:flake8_ignores
  47         silent! grep! %
  48
  49         " restore grep settings
  50         let &grepformat=l:old_gfm
  51         let &grepprg=l:old_gp
  52
  53         " open cwindow
  54         let has_results=getqflist() != []
  55         if has_results
  56             execute 'belowright copen'
  57             setlocal wrap
  58             nnoremap <buffer> <silent> c :cclose<CR>
  59             nnoremap <buffer> <silent> q :cclose<CR>
  60         endif
  61
  62         set nolazyredraw
  63         redraw!
  64
  65         if has_results == 0
  66             " Show OK status
  67             hi Green ctermfg=green
  68             echohl Green
  69             echon "Flake8 check OK"
  70             echohl
  71         endif
  72     endfunction
  73 endif
  74
  75 " Add mappings, unless the user didn't want this.
  76 " The default mapping is registered under to <F7> by default, unless the user
  77 " remapped it already (or a mapping exists already for <F7>)
  78 if !exists("no_plugin_maps") && !exists("no_flake8_maps")
  79     if !hasmapto('Flake8(')
  80         noremap <buffer> <F7> :call Flake8()<CR>
  81     endif
  82 endif