.zsh/xterm-title

   1 # zterm-title
   2 #
   3 # Fancy setting of the xterm title
   4 #
   5 # Copyright © 1994–2008 martin f. krafft <madduck@madduck.net>
   6 # Released under the terms of the Artistic Licence 2.0
   7 #
   8 # Source repository: http://git.madduck.net/v/etc/zsh.git
   9 #
  10 # Based on http://www.zshwiki.org/cgi-bin/wiki.pl?ZshHardStatus
  11 #
  12
  13 __set_xterm_title() {
  14   case $TERM in
  15     screen)
  16       print -nR $'\033k'$1$'\033'\\
  17       print -nR $'\033]0;'$2$'\a'
  18       ;;
  19     xterm|rxvt*)
  20       print -nR $'\033]0;'$*$'\a'
  21       ;;
  22   esac
  23 }
  24
  25 __get_session_flags() {
  26     local flags; flags=
  27     [ -n "$DISPLAY" ] && flags="${flags}x"
  28     [ -n "$SSH_AUTH_SOCK" ] && flags="${flags}a"
  29     [ -n "$flags" ] && echo "[${flags}]"
  30 }
  31
  32 __get_standard_prompt() {
  33   print -P "%m%# %25\<..\<%~ $(__get_session_flags)"
  34 }
  35
  36 set_plain_xterm_title() {
  37   __set_xterm_title "$(__get_standard_prompt)"
  38 }
  39
  40 set_cmd_xterm_title () {
  41     local -a cmd; cmd=(${(z)1})             # Re-parse the command line
  42
  43     # Construct a command that will output the desired job number.
  44     case $cmd[1] in
  45         fg) if (( $#cmd == 1 )); then
  46                 # No arguments, must find the current job
  47                 cmd=(builtin jobs -l %+)
  48             else
  49                 # Replace the command name, ignore extra args.
  50                 cmd=(builtin jobs -l ${(Q)cmd[2]})
  51             fi;;
  52         %*) cmd=(builtin jobs -l ${(Q)cmd[1]});; # Same as "else" above
  53         *) # Not resuming a job,
  54             __set_xterm_title $cmd[1]:t${cmd[2]:+ }$cmd[2,-1] "| $(__get_standard_prompt)"
  55             return;;                        # so we're all done
  56     esac
  57
  58     local -A jt; jt=(${(kv)jobtexts})       # Copy jobtexts for subshell
  59
  60     # Run the command, read its output, and look up the jobtext.
  61     # Could parse $rest here, but $jobtexts (via $jt) is easier.
  62     $cmd >>(
  63               read num rest
  64               cmd=(${(z)${(e):-\$jt$num}})
  65               __set_xterm_title $leader$cmd[1]:t${cmd[2]:+ }$cmd[2,-1] "| $(__get_standard_prompt)"
  66            )
  67 }
  68
  69 # vim:ft=zsh