.zsh/zshrc/30_aliases

   1 # zshrc/30_aliases
   2 #
   3 # Defines command shortcuts
   4 #
   5 # Copyright © 1994–2008 martin f. krafft <madduck@madduck.net>
   6 # Released under the terms of the Artistic Licence 2.0
   7 #
   8 # Source repository: http://git.madduck.net/v/etc/zsh.git
   9 #
  10
  11 alias mv='nocorrect mv'
  12 alias cp='nocorrect cp'
  13 alias ln='nocorrect ln'
  14 alias mkdir='nocorrect mkdir'
  15 alias rm='nocorrect rm'
  16
  17 alias find='noglob find'
  18 alias w3m='noglob w3m -no-mouse'
  19 alias links='noglob links'
  20 alias wb='noglob www-browser'
  21 alias wget='noglob wget'
  22 alias curl='noglob curl'
  23 alias apt-cache='noglob apt-cache'
  24 alias locate='noglob locate'
  25
  26 _LS_OPTS='-bCF --color=auto'
  27 ls --group-directories-first >/dev/null 2>&1 \
  28   && _LS_OPTS="$_LS_OPTS --group-directories-first"
  29 # I prefer POSIX collation for ls
  30 alias ls="LC_COLLATE=POSIX ls $_LS_OPTS"
  31 unset _LS_OPTS
  32
  33 alias ll='ls -l'
  34 alias la='ls -a'
  35 alias lla='ls -la'
  36 # List only directories and symbolic links that point to directories
  37 alias lsd='ls -ld *(-/DN)'
  38
  39 alias lsbig="ls -flh *(.OL[1,10])"
  40 alias lssmall="ls -Srl *(.oL[1,10])"
  41 alias lsnew="ls -rl *(D.om[1,10])"
  42 alias lsold="ls -rtlh *(D.om[1,10])"
  43
  44 alias egrep='egrep --color=auto -d skip'
  45 alias fgrep='fgrep --color=auto -d skip'
  46 alias grep='grep --color=auto -d skip'
  47
  48 alias mmv='noglob zmv -W'
  49 alias zcp='zmv -C'
  50 alias zln='zmv -L'
  51 alias zgmv='zmv -p git-mv'
  52
  53 alias cal='cal -3'
  54 alias ftp=lftp
  55
  56 alias mbug='bts show --mbox'
  57 alias bug='BROWSER=www-browser bts show'
  58
  59 # handy documentation lookup on Debian
  60 # from http://www.michael-prokop.at/computer/config/.zshrc
  61 doc() { cd /usr/share/doc/$1 && ls }
  62 _doc() { _files -W /usr/share/doc -/ }
  63 compdef _doc doc
  64
  65 alias giti='git init && git add . && git commit -minitial\ checkin'
  66
  67 alias t=tailf
  68 alias tsl='t /var/log/syslog'
  69 alias tml='t /var/log/mail.log'
  70 alias tal='t /var/log/auth.log'
  71 alias tdl='t /var/log/daemon.log'
  72 alias tkl='t /var/log/kern.log'
  73
  74 alias px='ps afux'
  75 alias mps='ps -ao user,pcpu,start,command'
  76
  77 alias bofh='fortune bofh-excuses'
  78
  79 autoload -U baseconv
  80 alias b2d='baseconv 2 10'
  81 alias d2b='baseconv 10 2'
  82 alias d2h='baseconv 10 16'
  83 alias h2d='baseconv 16 10'
  84 alias d2o='baseconv 10 8'
  85 alias o2d='baseconv 8 10'
  86
  87 alias sshnew='ssh -o "StrictHostKeyChecking no"'
  88 alias scpnew='ssh -o "StrictHostKeyChecking no"'
  89 alias sshtmp='sshnew -o "UserKnownHostsFile /dev/null"'
  90 alias scptmp='scptmp -o "UserKnownHostsFile /dev/null"'
  91
  92 _d() { dict $* }
  93 d() { _d $* | sensible-pager }
  94 the() { d -d moby-thesaurus $* }
  95 typeset -A _LANGUAGES
  96 _LANGUAGES[en]=eng
  97 _LANGUAGES[de]=deu
  98 _LANGUAGES[es]=spa
  99 _LANGUAGES[fr]=fra
 100 _LANGUAGES[it]=ita
 101 _LANGUAGES[lt]=lat
 102 for l0 in ${(k)_LANGUAGES}; do
 103   for l1 in ${(k)_LANGUAGES}; do
 104     eval "_${l0}-${l1}() { _d -d fd-${_LANGUAGES[$l0]}-${_LANGUAGES[$l1]} \$* }"
 105     eval "${l0}-${l1}() { d -d fd-${_LANGUAGES[$l0]}-${_LANGUAGES[$l1]} \$* }"
 106   done
 107 done
 108 unset '_LANGUAGES[en]'
 109 for l in ${(k)_LANGUAGES}; do
 110   eval "${l}() { (_${l}-en \$*; _en-${l} \$*) | more }"
 111 done
 112 unset _LANGUAGES
 113
 114 # vim:ft=zsh