.zsh/zshrc/30_aliases

   1 # zshrc/30_aliases
   2 #
   3 # Defines command shortcuts
   4 #
   5 # Copyright © 1994–2008 martin f. krafft <madduck@madduck.net>
   6 # Released under the terms of the Artistic Licence 2.0
   7 #
   8 # Source repository: git://git.madduck.net/etc/zsh.git
   9 #
  10
  11 function trace() { eval "set -x; $@" }
  12
  13 alias mv='nocorrect mv'
  14 alias cp='nocorrect cp'
  15 alias ln='nocorrect ln'
  16 alias mkdir='nocorrect mkdir'
  17 alias rm='nocorrect rm'
  18
  19 alias find='noglob find'
  20 alias w3m='noglob w3m -no-mouse'
  21 alias links='noglob links'
  22 alias wb='noglob www-browser'
  23 alias wget='noglob wget'
  24 alias curl='noglob curl'
  25 alias apt-cache='noglob apt-cache'
  26 alias locate='noglob locate'
  27
  28 local _USER_AGENT="Mozilla/5.0 (X11; U; Linux i686; en-US; rv:1.8.1.14) Gecko/20080404 Iceweasel/2.0.0.14 (Debian-2.0.0.14-2)"
  29 alias swget="noglob wget --user-agent='$USER_AGENT'"
  30
  31 typeset -a _ls_opts; _ls_opts=(-bC --color=auto)
  32 command ls --group-directories-first >/dev/null 2>&1 \
  33   && _ls_opts+=--group-directories-first
  34 # I prefer POSIX collation for ls
  35 alias ls="LC_COLLATE=POSIX ls $_ls_opts"
  36
  37 alias l='ls --time-style=+%Y%m%d.%H%M -gG'
  38 alias ll='ls -l'
  39 alias la='ls -a'
  40 alias lla='ls -la'
  41 alias lt='ls -lt'
  42 alias lrt='ls -lrt'
  43 alias lat='ls -lat'
  44 alias lart='ls -lart'
  45 # List only directories and symbolic links that point to directories
  46 alias lsd='ll -d *(-/DN)'
  47
  48 alias lscontext=l
  49 cd () { __CHPWD_RUN_FIRST=lscontext && builtin cd "$@" && unset __CHPWD_RUN_FIRST }
  50 #_cd_l() { ll }
  51 #chpwd_functions+=_cd_l
  52
  53 # #183394
  54 alias w='w|cat'
  55
  56 alias egrep='egrep --color=auto -d skip'
  57 alias fgrep='fgrep --color=auto -d skip'
  58 alias grep='grep --color=auto -d skip'
  59
  60 alias mmv='noglob zmv -W'
  61 alias zcp='zmv -C'
  62 alias zln='zmv -L'
  63 alias zgmv='zmv -p git-mv'
  64
  65 alias cal='cal -3'
  66 alias ftp=lftp
  67
  68 alias mbug='bts show --mbox'
  69 alias bug='BROWSER=www-browser bts show'
  70
  71 # handy documentation lookup on Debian
  72 # from http://www.michael-prokop.at/computer/config/.zshrc
  73 doc() { cd /usr/share/doc/$1 }
  74 compdef '_files -W /usr/share/doc -/' doc
  75
  76 alias giti='git init && git add . && git commit -minitial\ checkin && git tag orig'
  77
  78 if whence mtail >/dev/null; then
  79   alias t=mtail
  80 elif whence tailf >/dev/null; then
  81   alias t=tailf
  82 else
  83   alias t='tail -f'
  84 fi
  85 compdef _files t
  86
  87 function ltail() { t ~log/$1 }
  88 compdef '_files -W ~log' ltail
  89
  90 function lless() { sensible-pager ~log/$1 }
  91 compdef '_files -W ~log' lless
  92
  93 alias tsl='ltail syslog'
  94 alias lsl='lless ~log/syslog'
  95 alias tml='ltail mail.log'
  96 alias lml='lless ~log/mail.log'
  97 alias tal='ltail auth.log'
  98 alias lal='lless ~log/auth.log'
  99 alias tdl='ltail daemon.log'
 100 alias ldl='lless ~log/daemon.log'
 101 alias tkl='ltail kern.log'
 102 alias lkl='lless ~log/kern.log'
 103
 104 function lgrep() {
 105   local pattern="$1"; shift
 106   eval egrep "'$pattern'" "~log/${(j: ~log/:)@}"
 107 }
 108
 109 alias px='ps afux'
 110 alias mps='ps -ao user,pcpu,start,command'
 111
 112 alias bofh='fortune bofh-excuses'
 113
 114 autoload -U baseconv
 115 alias b2d='baseconv 2 10'
 116 alias d2b='baseconv 10 2'
 117 alias d2h='baseconv 10 16'
 118 alias h2d='baseconv 16 10'
 119 alias d2o='baseconv 10 8'
 120 alias o2d='baseconv 8 10'
 121
 122 alias sendmail=/usr/sbin/sendmail
 123
 124 _d() { dict $* }
 125 d() { _d $* | sensible-pager }
 126 the() { d -d moby-thesaurus $* }
 127 typeset -A _LANGUAGES
 128 _LANGUAGES[en]=eng
 129 _LANGUAGES[de]=deu
 130 _LANGUAGES[es]=spa
 131 _LANGUAGES[fr]=fra
 132 _LANGUAGES[it]=ita
 133 _LANGUAGES[lt]=lat
 134 for l0 in ${(k)_LANGUAGES}; do
 135   for l1 in ${(k)_LANGUAGES}; do
 136     eval "_${l0}-${l1}() { _d -d fd-${_LANGUAGES[$l0]}-${_LANGUAGES[$l1]} \$* }"
 137     eval "${l0}-${l1}() { d -d fd-${_LANGUAGES[$l0]}-${_LANGUAGES[$l1]} \$* }"
 138   done
 139 done
 140 unset '_LANGUAGES[en]'
 141 for l in ${(k)_LANGUAGES}; do
 142   eval "${l}() { (_${l}-en \$*; _en-${l} \$*) | more }"
 143 done
 144 unset _LANGUAGES
 145
 146 alias dpkg-buildpackage="dpkg-buildpackage -k$DEBKEYID -rfakeroot"
 147
 148 bugsub() { echo X-debbugs-autosubscribe: madduck | sendmail -f $DEBEMAIL ${1:?No bug number}-subscribe@bugs.debian.org }
 149 bugunsub() { sendmail -f $DEBEMAIL ${1:?No bug number}-unsubscribe@bugs.debian.org </dev/null }
 150 ptssub() { echo subscribe ${1:?E: no package name given.} | sendmail -f ${2:-$DEBEMAIL} pts@qa.debian.org }
 151 ptsunsub() { echo unsubscribe ${1:?E: no package name given.} | sendmail -f ${2:-$DEBEMAIL} pts@qa.debian.org }
 152 qasub() { echo subscribe ${1:?E: no package name given.} ${2:-unspecifed} | sendmail -f $DEBEMAIL ddpo@qa.debian.org }
 153 qaunsub() { echo unsubscribe ${1:?E: no package name given.} ${2:-unspecifed} | sendmail -f $DEBEMAIL ddpo@qa.debian.org }
 154
 155 uc() { unicode --max=0 --colour=off "$@" | sensible-pager }
 156
 157 alias ipr='ip r'
 158 alias ipa='ip a'
 159 alias ipl='ip l'
 160
 161 alias btd='btdownloadheadless'
 162
 163 alias mdtest='swaks -s localhost -t'
 164
 165 if whence devtodo >/dev/null; then
 166   _devtodo_on_chpwd() {
 167     local out; out="$(devtodo)"
 168     [[ -n $out ]] && print "todo:\n$out"
 169   }
 170   [[ -z ${(M)chpwd_functions:#_devtodo_on_chpwd} ]] && chpwd_functions+=_devtodo_on_chpwd
 171 fi
 172
 173 # vim:ft=zsh