Overhaul of the entire config. Yay for big diffs.

[etc/zsh.git] / .zsh / zshrc / 30_aliases.disabled

diff --git a/.zsh/zshrc/30_aliases.disabled b/.zsh/zshrc/30_aliases.disabled
new file mode 100644 (file)
index 0000000..9b10390
--- /dev/null
+++ b/.zsh/zshrc/30_aliases.disabled
@@ -0,0 +1,155 @@
+# zshrc/30_aliases
+#
+# Defines command shortcuts
+#
+# Copyright © 1994–2017 martin f. krafft <madduck@madduck.net>
+# Released under the terms of the Artistic Licence 2.0
+#
+# Source repository: http://git.madduck.net/v/etc/zsh.git
+#
+
+alias giti='git init && git add . && git commit -minitial\ checkin && git tag orig'
+gbs() {
+  local branch; branch="$(git symbolic-ref -q HEAD)"; branch="${branch##*/}"
+  git config branch.${branch}.remote ${1:-origin}
+  git config branch.${branch}.merge refs/heads/${branch}
+  git config branch.${branch}.rebase true
+}
+
+if whence mtail >/dev/null; then
+  alias t=mtail
+elif whence tailf >/dev/null; then
+  alias t=tailf
+else
+  alias t='tail -f'
+fi
+compdef _files t
+
+function ltail() { t ~log/$1 }
+compdef '_files -W ~log' ltail
+
+function lless() { sensible-pager ~log/$1 }
+compdef '_files -W ~log' lless
+
+alias tsl='ltail syslog'
+alias lsl='lless syslog'
+alias tml='ltail mail.log'
+alias lml='lless mail.log'
+alias tal='ltail auth.log'
+alias lal='lless auth.log'
+alias tdl='ltail daemon.log'
+alias ldl='lless daemon.log'
+alias tkl='ltail kern.log'
+alias lkl='lless kern.log'
+
+function lgrep() {
+  local pattern="$1"; shift
+  eval egrep "'$pattern'" "~log/${(j: ~log/:)@}"
+}
+
+function psgrep() { ps aux | grep "[${1[1]}]${1[2,-1]}" }
+
+alias sendmail=/usr/sbin/sendmail
+
+_d() { dict $* }
+d() { _d $* | sensible-pager }
+the() { d -d moby-thesaurus $* }
+typeset -A _LANGUAGES
+_LANGUAGES[en]=eng
+_LANGUAGES[de]=deu
+_LANGUAGES[es]=spa
+_LANGUAGES[fr]=fra
+_LANGUAGES[it]=ita
+_LANGUAGES[tn]=lat
+for l0 in ${(k)_LANGUAGES}; do
+  for l1 in ${(k)_LANGUAGES}; do
+    eval "function _${l0}-${l1}() { _d -d fd-${_LANGUAGES[$l0]}-${_LANGUAGES[$l1]} \$* }"
+    eval "function ${l0}-${l1}() { d -d fd-${_LANGUAGES[$l0]}-${_LANGUAGES[$l1]} \$* }"
+  done
+done
+unset '_LANGUAGES[en]'
+for l in ${(k)_LANGUAGES}; do
+  eval "function ${l}() { (_${l}-en \$*; _en-${l} \$*) | more }"
+done
+unset _LANGUAGES
+
+bugsub() { echo X-debbugs-autosubscribe: madduck | sendmail -f $DEBEMAIL ${1:?No bug number}-subscribe@bugs.debian.org }
+bugunsub() { sendmail -f $DEBEMAIL ${1:?No bug number}-unsubscribe@bugs.debian.org </dev/null }
+ptssub() { echo subscribe ${1:?E: no package name given.} | sendmail -f ${2:-$DEBEMAIL} pts@qa.debian.org }
+ptsunsub() { echo unsubscribe ${1:?E: no package name given.} | sendmail -f ${2:-$DEBEMAIL} pts@qa.debian.org }
+qasub() { echo subscribe ${1:?E: no package name given.} ${2:-unspecifed} | sendmail -f $DEBEMAIL ddpo@qa.debian.org }
+qaunsub() { echo unsubscribe ${1:?E: no package name given.} ${2:-unspecifed} | sendmail -f $DEBEMAIL ddpo@qa.debian.org }
+listsub() { echo Subject: subscribe | sendmail -f ${1%@*}=${1#*@}@mass.madduck.net ${1%@*}-request@${1#*@} }
+listunsub() { echo Subject: unsubscribe | sendmail -f ${1%@*}=${1#*@}@mass.madduck.net ${1%@*}-request@${1#*@} }
+
+uc() { unicode --max=0 --colour=off "$@" | sensible-pager }
+
+alias ipr='ip r'
+alias ipa='ip a'
+alias ipl='ip l'
+
+alias btd='btdownloadheadless'
+
+function asc () { autossh -t "$@" 'screen -qxp= || screen -qdRR' }
+compdef asc=ssh
+
+alias mdtest='swaks -s localhost -t'
+
+if whence devtodo >/dev/null; then
+  _devtodo_on_chpwd() {
+    local out; out="$(devtodo)"
+    [[ -n $out ]] && print "todo:\n$out"
+  }
+  [[ -z ${(M)chpwd_functions:#_devtodo_on_chpwd} ]] && chpwd_functions+=_devtodo_on_chpwd
+fi
+
+pdfextract() {
+  local i=$1
+  local o=$2
+  shift 2
+  pdftk "$i" cat "${@:-1-end}" output "${o%.pdf}.pdf"
+  if [ -n "$1" ]; then
+    local tmpfile
+    tmpfile=$(tempfile -p pdftk -s .pdf)
+    cleanup() { rm -f $tmpfile; trap - EXIT; }
+    trap cleanup EXIT
+    pdftk "$i" cat "1-end~${(j:~:)@}" output $tmpfile
+    mv $tmpfile "$i"
+    cleanup
+  fi
+}
+compdef _files pdfextract
+
+gittestfile() {
+  local annex; annex=false
+  local file
+
+  case "$1" in
+    (-a) annex=true;;
+    (*)
+      if [ -n "$file" ]; then
+        echo >&2 "E: filename already given"
+        return 1
+      fi
+      file="$1";;
+  esac
+
+  if [ -z "$file" ]; then
+    file=$(TMPDIR=${PWD} tempfile -ptest. -s.txt)
+  fi
+
+  echo "Test file created $(date)" >| $file
+
+  case "$annex" in
+    true)
+      git annex add $file
+      git commit -m"Add test file $file to annex"
+      ;;
+    false)
+      git add $file
+      git commit -m"Add test file $file"
+      ;;
+  esac
+}
+
+# vim:ft=zsh