Make zsh not complete on an endless cycle of repos

[code/vcsh.git] / _vcsh

diff --git a/_vcsh b/_vcsh
index fce8794cb9fd7c6906eacd08d247bb4f2c642a0c..59cdcfe49dff30fa1b9ef6bbf773b600429c734c 100644 (file)
--- a/_vcsh
+++ b/_vcsh
@@ -1,12 +1,122 @@
 #compdef vcsh
 
-#              use\:"use/enter repo"
-_arguments \
-       ':subcommand:((
-               help\:"display help"
-               list\:"list all repos"
-               run\:"run command on repo"
-               init\:"init & clone from repo"
-               clone\:"clone from repo"
-               exit\:"exit repo"
-       ))'
+function __vcsh_repositories () {
+       local expl
+       local -a repos
+       repos=( ${(f)"$(command vcsh list)"} )
+       _describe -t repos 'repositories' repos
+}
+
+function __vcsh_not_implemented_yet () {
+       _message "Subcommand completion '${1#*-}': not implemented yet"
+}
+
+function _vcsh-clone () {
+       __vcsh_not_implemented_yet "$0" #TODO
+}
+
+function _vcsh-delete () {
+       (( CURRENT == 2 )) && __vcsh_repositories
+}
+
+function _vcsh-enter () {
+       (( CURRENT == 2 )) && __vcsh_repositories
+}
+
+function _vcsh-help () {
+       _nothing
+}
+
+function _vcsh-init () {
+       _nothing
+}
+
+function _vcsh-list () {
+       _nothing
+}
+
+function _vcsh-list-tracked () {
+       _nothing
+}
+
+function _vcsh-list-tracked-by () {
+       (( CURRENT == 2 )) && __vcsh_repositories
+}
+
+function _vcsh-rename () {
+       (( CURRENT == 2 )) && __vcsh_repositories
+       #TODO tell the user to add a new name
+}
+
+function _vcsh-run () {
+       (( CURRENT == 2 )) && __vcsh_repositories
+       #TODO normal commands
+}
+
+function _vcsh-setup () {
+       (( CURRENT == 2 )) && __vcsh_repositories
+}
+
+function _vcsh-version () {
+       _nothing
+}
+
+function _vcsh-which () {
+       _files
+}
+
+function _vcsh-write-gitignore () {
+       (( CURRENT == 2 )) && __vcsh_repositories
+}
+
+function _vcsh () {
+       local curcontext="${curcontext}"
+       local state vcshcommand
+       local -a args subcommands
+
+       subcommands=(
+               "clone:clone an existing repository"
+               "delete:delete an existing repository"
+               "enter:enter repository; spawn new <\$SHELL>"
+               "help:display help"
+               "init:initialize an empty repository"
+               "list:list all local vcsh repositories"
+               "list-tracked:list all files tracked by vcsh"
+               "list-tracked-by:list files tracked by a repository"
+               "rename:rename a repository"
+               "run:run command with <\$GIT_DIR> and <\$GIT_WORK_TREE> set"
+               "setup:set up repository with recommended settings"
+               "version:print version information"
+               "which:find <substring> in name of any tracked file"
+               "write-gitignore:write .gitignore.d/<repo> via git ls-files"
+       )
+
+       args=(
+               '-c[source <file> prior to other configuration files]:config files:_path_files'
+               '-d[enable debug mode]'
+               '-v[enable verbose mode]'
+               '*:: :->subcommand_or_options_or_repo'
+       )
+
+       _arguments -C ${args} && return
+
+       if [[ ${state} == "subcommand_or_options_or_repo" ]]; then
+               if (( CURRENT == 1 )); then
+                       _describe -t subcommands 'vcsh sub-commands' subcommands
+                       __vcsh_repositories
+               else
+                       vcshcommand="${words[1]}"
+                       if ! (( ${+functions[_vcsh-$vcshcommand]} )); then
+                               # There is no handler function, so this is probably the name
+                               # of a repository. Act accordingly.
+                               _message "git sub-command"
+                               #TODO and now we need to complete on git subcommands
+                       else
+                               curcontext="${curcontext%:*:*}:vcsh-${vcshcommand}:"
+                               _call_function ret _vcsh-${vcshcommand}
+                       fi
+               fi
+       fi
+}
+
+_vcsh "$@"