.zsh/zshrc/parts.d/50-ssh

   1 # zshrc/parts.d/50-ssh
   2 #
   3 # ssh configuration for zsh
   4 #
   5 # Copyright © 2008 martin f. krafft <madduck@madduck.net>
   6 # Released under the terms of the Artistic Licence 2.0
   7 #
   8 # Source repository: git://git.madduck.net/etc/ssh.git
   9 #
  10
  11 # populate hosts completion with SSH's known_hosts
  12 if [ -r $HOME/.ssh/known_hosts ]; then
  13   local _myhosts
  14   _myhosts=(${${${${(f)"$(cat $HOME/.ssh/known_hosts)"}:#[0-9]*}%%\ *}%%,*})
  15   zstyle ':completion:*' hosts $_myhosts
  16   unset _myhosts
  17 fi
  18
  19 _ssh_proxy() {
  20   local cmd sshopts cmdopts
  21   cmd="$1"; shift
  22   sshopts="${*%%--*}"; sshopts="${sshopts%% }"
  23   cmdopts="${*#$sshopts}"; cmdopts="${cmdopts#*-- }"
  24   eval ssh $sshopts -t $cmd $cmdopts
  25 }
  26
  27 # need functions instead of aliases for completion
  28 rrsh() { _ssh_proxy "su -" "$@" }
  29 compdef rrsh=ssh
  30
  31 ttsh() { _ssh_proxy "tmux last" "$@" }
  32 compdef ttsh=ssh
  33
  34 rtsh() { _ssh_proxy "tmux new su -" "$@" }
  35 compdef rtsh=ssh
  36
  37 local SOCKDIR=$VARDIR/ssh
  38 kssh() {
  39   local SOCKDIR=$SOCKDIR
  40   if [[ -z "$1" ]]; then
  41     rm -vf -- $SOCKDIR/ssh_control_*(=as-60Y1omN)
  42   else
  43     rm "$@"
  44   fi
  45 }
  46 compdef "_files -W $SOCKDIR" kssh
  47 unset SOCKDIR
  48
  49 # vim:ft=zsh