.zsh/zshrc/30_aliases

   1 # zshrc/30_aliases
   2 #
   3 # Defines command shortcuts
   4 #
   5 # Copyright © 1994–2008 martin f. krafft <madduck@madduck.net>
   6 # Released under the terms of the Artistic Licence 2.0
   7 #
   8 # Source repository: http://git.madduck.net/v/etc/zsh.git
   9 #
  10
  11 alias mv='nocorrect mv'
  12 alias cp='nocorrect cp'
  13 alias ln='nocorrect ln'
  14 alias mkdir='nocorrect mkdir'
  15 alias rm='nocorrect rm'
  16
  17 alias find='noglob find'
  18 alias w3m='noglob w3m -no-mouse'
  19 alias links='noglob links'
  20 alias wb='noglob www-browser'
  21 alias wget='noglob wget'
  22 alias curl='noglob curl'
  23 alias apt-cache='noglob apt-cache'
  24 alias locate='noglob locate'
  25
  26 local _USER_AGENT="Mozilla/5.0 (X11; U; Linux i686; en-US; rv:1.8.1.14) Gecko/20080404 Iceweasel/2.0.0.14 (Debian-2.0.0.14-2)"
  27 alias swget="noglob wget --user-agent='$USER_AGENT'"
  28
  29 typeset -a _ls_opts; _ls_opts=(-bC --color=auto)
  30 command ls --group-directories-first >/dev/null 2>&1 \
  31   && _ls_opts+=--group-directories-first
  32 # I prefer POSIX collation for ls
  33 alias ls="LC_COLLATE=POSIX ls $_ls_opts"
  34
  35 alias ll='ls -l'
  36 alias l=ll
  37 alias la='ls -a'
  38 alias lla='ls -la'
  39 alias lrt='ls -lrt'
  40 alias lart='ls -lart'
  41 # List only directories and symbolic links that point to directories
  42 alias lsd='ls -ld *(-/DN)'
  43
  44 alias lsbig="ls -flh *(.OL[1,10])"
  45 alias lssmall="ls -Srl *(.oL[1,10])"
  46 alias lsnew="ls -rl *(D.om[1,10])"
  47 alias lsold="ls -rtlh *(D.om[1,10])"
  48
  49 cd () { builtin cd "$@" && lrt }
  50 #_cd_l() { ll }
  51 #chpwd_functions+=_cd_l
  52
  53 alias egrep='egrep --color=auto -d skip'
  54 alias fgrep='fgrep --color=auto -d skip'
  55 alias grep='grep --color=auto -d skip'
  56
  57 alias mmv='noglob zmv -W'
  58 alias zcp='zmv -C'
  59 alias zln='zmv -L'
  60 alias zgmv='zmv -p git-mv'
  61
  62 alias cal='cal -3'
  63 alias ftp=lftp
  64
  65 alias mbug='bts show --mbox'
  66 alias bug='BROWSER=www-browser bts show'
  67
  68 # handy documentation lookup on Debian
  69 # from http://www.michael-prokop.at/computer/config/.zshrc
  70 doc() { cd /usr/share/doc/$1 && ls }
  71 _doc() { _files -W /usr/share/doc -/ }
  72 compdef _doc doc
  73
  74 alias giti='git init && git add . && git commit -minitial\ checkin'
  75
  76 if whence tailf >/dev/null; then
  77   alias t=tailf
  78 else
  79   alias t='tail -f'
  80 fi
  81 alias tsl='t /var/log/syslog'
  82 alias tml='t /var/log/mail.log'
  83 alias tal='t /var/log/auth.log'
  84 alias tdl='t /var/log/daemon.log'
  85 alias tkl='t /var/log/kern.log'
  86
  87 alias px='ps afux'
  88 alias mps='ps -ao user,pcpu,start,command'
  89
  90 alias bofh='fortune bofh-excuses'
  91
  92 autoload -U baseconv
  93 alias b2d='baseconv 2 10'
  94 alias d2b='baseconv 10 2'
  95 alias d2h='baseconv 10 16'
  96 alias h2d='baseconv 16 10'
  97 alias d2o='baseconv 10 8'
  98 alias o2d='baseconv 8 10'
  99
 100 alias sendmail=/usr/sbin/sendmail
 101
 102 _d() { dict $* }
 103 d() { _d $* | sensible-pager }
 104 the() { d -d moby-thesaurus $* }
 105 typeset -A _LANGUAGES
 106 _LANGUAGES[en]=eng
 107 _LANGUAGES[de]=deu
 108 _LANGUAGES[es]=spa
 109 _LANGUAGES[fr]=fra
 110 _LANGUAGES[it]=ita
 111 _LANGUAGES[lt]=lat
 112 for l0 in ${(k)_LANGUAGES}; do
 113   for l1 in ${(k)_LANGUAGES}; do
 114     eval "_${l0}-${l1}() { _d -d fd-${_LANGUAGES[$l0]}-${_LANGUAGES[$l1]} \$* }"
 115     eval "${l0}-${l1}() { d -d fd-${_LANGUAGES[$l0]}-${_LANGUAGES[$l1]} \$* }"
 116   done
 117 done
 118 unset '_LANGUAGES[en]'
 119 for l in ${(k)_LANGUAGES}; do
 120   eval "${l}() { (_${l}-en \$*; _en-${l} \$*) | more }"
 121 done
 122 unset _LANGUAGES
 123
 124 alias dpkg-buildpackage="dpkg-buildpackage -k$DEBKEYID"
 125
 126 uc() { unicode --max=0 --colour=off "$@" | sensible-pager }
 127
 128 # vim:ft=zsh