.zsh/zshrc/30_aliases

   1 # zshrc/30_aliases
   2 #
   3 # Defines command shortcuts
   4 #
   5 # Copyright © 1994–2008 martin f. krafft <madduck@madduck.net>
   6 # Released under the terms of the Artistic Licence 2.0
   7 #
   8 # Source repository: http://git.madduck.net/v/etc/zsh.git
   9 #
  10
  11 alias mv='nocorrect mv'
  12 alias cp='nocorrect cp'
  13 alias ln='nocorrect ln'
  14 alias mkdir='nocorrect mkdir'
  15 alias rm='nocorrect rm'
  16
  17 alias find='noglob find'
  18 alias w3m='noglob w3m -no-mouse'
  19 alias links='noglob links'
  20 alias wb='noglob www-browser'
  21 alias wget='noglob wget'
  22 alias curl='noglob curl'
  23
  24 _LS_OPTS='-bCF --color=auto'
  25 ls --group-directories-first >/dev/null 2>&1 \
  26   && _LS_OPTS="$_LS_OPTS --group-directories-first"
  27 # I prefer POSIX collation for ls
  28 alias ls="LC_COLLATE=POSIX ls $_LS_OPTS"
  29 unset _LS_OPTS
  30
  31 alias ll='ls -l'
  32 alias la='ls -a'
  33 alias lla='ls -la'
  34 # List only directories and symbolic links that point to directories
  35 alias lsd='ls -ld *(-/DN)'
  36
  37 alias lsbig="ls -flh *(.OL[1,10])"
  38 alias lssmall="ls -Srl *(.oL[1,10])"
  39 alias lsnew="ls -rl *(D.om[1,10])"
  40 alias lsold="ls -rtlh *(D.om[1,10])"
  41
  42 alias egrep='egrep --color=auto -d skip'
  43 alias fgrep='fgrep --color=auto -d skip'
  44 alias grep='grep --color=auto -d skip'
  45
  46 alias mmv='noglob zmv -W'
  47 alias zcp='zmv -C'
  48 alias zln='zmv -L'
  49 alias zgmv='zmv -p git-mv'
  50
  51 alias cal='cal -3'
  52 alias ftp=lftp
  53
  54 alias mbug='bts show --mbox'
  55 alias bug='BROWSER=www-browser bts show'
  56
  57 # handy documentation lookup on Debian
  58 # from http://www.michael-prokop.at/computer/config/.zshrc
  59 doc() { cd /usr/share/doc/$1 && ls }
  60 _doc() { _files -W /usr/share/doc -/ }
  61 compdef _doc doc
  62
  63 alias giti='git init && git add . && git commit -minitial\ checkin'
  64
  65 _d() { dict $* }
  66 d() { _d $* | sensible-pager }
  67 the() { d -d moby-thesaurus $* }
  68 typeset -A _LANGUAGES
  69 _LANGUAGES[en]=eng
  70 _LANGUAGES[de]=deu
  71 _LANGUAGES[es]=spa
  72 _LANGUAGES[fr]=fra
  73 _LANGUAGES[it]=ita
  74 _LANGUAGES[lt]=lat
  75 for l0 in ${(k)_LANGUAGES}; do
  76   for l1 in ${(k)_LANGUAGES}; do
  77     eval "_${l0}-${l1}() { _d -d fd-${_LANGUAGES[$l0]}-${_LANGUAGES[$l1]} \$* }"
  78     eval "${l0}-${l1}() { d -d fd-${_LANGUAGES[$l0]}-${_LANGUAGES[$l1]} \$* }"
  79   done
  80 done
  81 unset '_LANGUAGES[en]'
  82 for l in ${(k)_LANGUAGES}; do
  83   eval "${l}() { (_${l}-en \$*; _en-${l} \$*) | more }"
  84 done
  85 unset _LANGUAGES
  86
  87 # vim:ft=zsh