.zsh/zshrc/82-load_alias-d

   1 #
   2 # Turn files in $apath directories into aliases
   3 #
   4 # Copyright © 1994–2017 martin f. krafft <madduck@madduck.net>
   5 # Released under the terms of the Artistic Licence 2.0
   6 #
   7 # Source repository: http://git.madduck.net/v/etc/zsh.git
   8 #
   9
  10 function make_alias {
  11   emulate -L zsh
  12   setopt extendedglob
  13   local fn="${1:t}" s
  14   for l in ${(f)"$(<$1)"}; do
  15     0=$fn
  16     case "$s/$l" in
  17       (*/\#*) continue;;
  18       (/\(\)*) eval "function $fn$l"; s=s;;
  19       (/*) eval "alias $fn='${l//\$0/$fn}'"; s=s;;
  20       (s/(#b)(*)) eval "$match[1]";;
  21     esac
  22   done
  23 }
  24
  25 for ad in $apath; do
  26   if [ ! -d "$ad" ]; then
  27     zerror "no such directory: $ad"
  28     continue
  29   fi
  30
  31 #  zdebug "sourcing alias directory ${ad#$ZDOTDIR/}"
  32   for f in "$ad"/*(N.,@); do
  33     case "$f" in
  34       *~|*.bak|*.old|*.sw?|*.zwc|*.disabled) continue;;
  35     esac
  36     make_alias "$f"
  37   done
  38 done
  39
  40 # vim:ft=zsh