.zsh/zshrc/30_aliases

   1 # zshrc/30_aliases
   2 #
   3 # Defines command shortcuts
   4 #
   5 # Copyright © 1994–2008 martin f. krafft <madduck@madduck.net>
   6 # Released under the terms of the Artistic Licence 2.0
   7 #
   8 # Source repository: http://git.madduck.net/v/etc/zsh.git
   9 #
  10
  11 alias mv='nocorrect mv'
  12 alias cp='nocorrect cp'
  13 alias ln='nocorrect ln'
  14 alias mkdir='nocorrect mkdir'
  15 alias rm='nocorrect rm'
  16
  17 alias find='noglob find'
  18 alias w3m='noglob w3m -no-mouse'
  19 alias links='noglob links'
  20 alias wb='noglob www-browser'
  21 alias wget='noglob wget'
  22 alias curl='noglob curl'
  23 alias apt-cache='noglob apt-cache'
  24 alias locate='noglob locate'
  25
  26 _LS_OPTS='-bCF --color=auto'
  27 ls --group-directories-first >/dev/null 2>&1 \
  28   && _LS_OPTS="$_LS_OPTS --group-directories-first"
  29 # I prefer POSIX collation for ls
  30 alias ls="LC_COLLATE=POSIX ls $_LS_OPTS"
  31 unset _LS_OPTS
  32
  33 alias ll='ls -l'
  34 alias l=ll
  35 alias la='ls -a'
  36 alias lla='ls -la'
  37 # List only directories and symbolic links that point to directories
  38 alias lsd='ls -ld *(-/DN)'
  39
  40 alias lsbig="ls -flh *(.OL[1,10])"
  41 alias lssmall="ls -Srl *(.oL[1,10])"
  42 alias lsnew="ls -rl *(D.om[1,10])"
  43 alias lsold="ls -rtlh *(D.om[1,10])"
  44
  45 alias egrep='egrep --color=auto -d skip'
  46 alias fgrep='fgrep --color=auto -d skip'
  47 alias grep='grep --color=auto -d skip'
  48
  49 alias mmv='noglob zmv -W'
  50 alias zcp='zmv -C'
  51 alias zln='zmv -L'
  52 alias zgmv='zmv -p git-mv'
  53
  54 alias cal='cal -3'
  55 alias ftp=lftp
  56
  57 alias mbug='bts show --mbox'
  58 alias bug='BROWSER=www-browser bts show'
  59
  60 # handy documentation lookup on Debian
  61 # from http://www.michael-prokop.at/computer/config/.zshrc
  62 doc() { cd /usr/share/doc/$1 && ls }
  63 _doc() { _files -W /usr/share/doc -/ }
  64 compdef _doc doc
  65
  66 alias giti='git init && git add . && git commit -minitial\ checkin'
  67
  68 if whence tailf >/dev/null; then
  69   alias t=tailf
  70 else
  71   alias t='tail -f'
  72 fi
  73 alias tsl='t /var/log/syslog'
  74 alias tml='t /var/log/mail.log'
  75 alias tal='t /var/log/auth.log'
  76 alias tdl='t /var/log/daemon.log'
  77 alias tkl='t /var/log/kern.log'
  78
  79 alias px='ps afux'
  80 alias mps='ps -ao user,pcpu,start,command'
  81
  82 alias bofh='fortune bofh-excuses'
  83
  84 autoload -U baseconv
  85 alias b2d='baseconv 2 10'
  86 alias d2b='baseconv 10 2'
  87 alias d2h='baseconv 10 16'
  88 alias h2d='baseconv 16 10'
  89 alias d2o='baseconv 10 8'
  90 alias o2d='baseconv 8 10'
  91
  92 alias sshnew='ssh -o "StrictHostKeyChecking no"'
  93 alias scpnew='scp -o "StrictHostKeyChecking no"'
  94 alias sshtmp='sshnew -o "UserKnownHostsFile /dev/null"'
  95 alias scptmp='scpnew -o "UserKnownHostsFile /dev/null"'
  96
  97 alias sendmail=/usr/sbin/sendmail
  98
  99 _d() { dict $* }
 100 d() { _d $* | sensible-pager }
 101 the() { d -d moby-thesaurus $* }
 102 typeset -A _LANGUAGES
 103 _LANGUAGES[en]=eng
 104 _LANGUAGES[de]=deu
 105 _LANGUAGES[es]=spa
 106 _LANGUAGES[fr]=fra
 107 _LANGUAGES[it]=ita
 108 _LANGUAGES[lt]=lat
 109 for l0 in ${(k)_LANGUAGES}; do
 110   for l1 in ${(k)_LANGUAGES}; do
 111     eval "_${l0}-${l1}() { _d -d fd-${_LANGUAGES[$l0]}-${_LANGUAGES[$l1]} \$* }"
 112     eval "${l0}-${l1}() { d -d fd-${_LANGUAGES[$l0]}-${_LANGUAGES[$l1]} \$* }"
 113   done
 114 done
 115 unset '_LANGUAGES[en]'
 116 for l in ${(k)_LANGUAGES}; do
 117   eval "${l}() { (_${l}-en \$*; _en-${l} \$*) | more }"
 118 done
 119 unset _LANGUAGES
 120
 121 # vim:ft=zsh