.zsh/zshrc/30_aliases

   1 # zshrc/30_aliases
   2 #
   3 # Defines command shortcuts
   4 #
   5 # Copyright © 1994–2008 martin f. krafft <madduck@madduck.net>
   6 # Released under the terms of the Artistic Licence 2.0
   7 #
   8 # Source repository: http://git.madduck.net/v/etc/zsh.git
   9 #
  10
  11 alias mv='nocorrect mv'
  12 alias cp='nocorrect cp'
  13 alias ln='nocorrect ln'
  14 alias mkdir='nocorrect mkdir'
  15 alias rm='nocorrect rm'
  16
  17 alias find='noglob find'
  18 alias w3m='noglob w3m -no-mouse'
  19 alias links='noglob links'
  20 alias wb='noglob www-browser'
  21 alias curl='noglob curl'
  22 alias apt-cache='noglob apt-cache'
  23 alias locate='noglob locate'
  24
  25 local _USER_AGENT="Mozilla/5.0 (X11; U; Linux i686; en-US; rv:1.8.1.14) Gecko/20080404 Iceweasel/2.0.0.14 (Debian-2.0.0.14-2)"
  26 alias wget="noglob wget --user-agent='$USER_AGENT'"
  27
  28 typeset -a _ls_opts; _ls_opts=(-bC --color=auto)
  29 command ls --group-directories-first >/dev/null 2>&1 \
  30   && _ls_opts+=--group-directories-first
  31 # I prefer POSIX collation for ls
  32 alias ls="LC_COLLATE=POSIX ls $_ls_opts"
  33
  34 alias ll='ls -l'
  35 alias l=ll
  36 alias la='ls -a'
  37 alias lla='ls -la'
  38 # List only directories and symbolic links that point to directories
  39 alias lsd='ls -ld *(-/DN)'
  40
  41 alias lsbig="ls -flh *(.OL[1,10])"
  42 alias lssmall="ls -Srl *(.oL[1,10])"
  43 alias lsnew="ls -rl *(D.om[1,10])"
  44 alias lsold="ls -rtlh *(D.om[1,10])"
  45
  46 cd () { builtin cd $* && ll }
  47 #_cd_l() { ll }
  48 #chpwd_functions+=_cd_l
  49
  50 alias egrep='egrep --color=auto -d skip'
  51 alias fgrep='fgrep --color=auto -d skip'
  52 alias grep='grep --color=auto -d skip'
  53
  54 alias mmv='noglob zmv -W'
  55 alias zcp='zmv -C'
  56 alias zln='zmv -L'
  57 alias zgmv='zmv -p git-mv'
  58
  59 alias cal='cal -3'
  60 alias ftp=lftp
  61
  62 alias mbug='bts show --mbox'
  63 alias bug='BROWSER=www-browser bts show'
  64
  65 # handy documentation lookup on Debian
  66 # from http://www.michael-prokop.at/computer/config/.zshrc
  67 doc() { cd /usr/share/doc/$1 && ls }
  68 _doc() { _files -W /usr/share/doc -/ }
  69 compdef _doc doc
  70
  71 alias giti='git init && git add . && git commit -minitial\ checkin'
  72
  73 if whence tailf >/dev/null; then
  74   alias t=tailf
  75 else
  76   alias t='tail -f'
  77 fi
  78 alias tsl='t /var/log/syslog'
  79 alias tml='t /var/log/mail.log'
  80 alias tal='t /var/log/auth.log'
  81 alias tdl='t /var/log/daemon.log'
  82 alias tkl='t /var/log/kern.log'
  83
  84 alias px='ps afux'
  85 alias mps='ps -ao user,pcpu,start,command'
  86
  87 alias bofh='fortune bofh-excuses'
  88
  89 autoload -U baseconv
  90 alias b2d='baseconv 2 10'
  91 alias d2b='baseconv 10 2'
  92 alias d2h='baseconv 10 16'
  93 alias h2d='baseconv 16 10'
  94 alias d2o='baseconv 10 8'
  95 alias o2d='baseconv 8 10'
  96
  97 alias sendmail=/usr/sbin/sendmail
  98
  99 _d() { dict $* }
 100 d() { _d $* | sensible-pager }
 101 the() { d -d moby-thesaurus $* }
 102 typeset -A _LANGUAGES
 103 _LANGUAGES[en]=eng
 104 _LANGUAGES[de]=deu
 105 _LANGUAGES[es]=spa
 106 _LANGUAGES[fr]=fra
 107 _LANGUAGES[it]=ita
 108 _LANGUAGES[lt]=lat
 109 for l0 in ${(k)_LANGUAGES}; do
 110   for l1 in ${(k)_LANGUAGES}; do
 111     eval "_${l0}-${l1}() { _d -d fd-${_LANGUAGES[$l0]}-${_LANGUAGES[$l1]} \$* }"
 112     eval "${l0}-${l1}() { d -d fd-${_LANGUAGES[$l0]}-${_LANGUAGES[$l1]} \$* }"
 113   done
 114 done
 115 unset '_LANGUAGES[en]'
 116 for l in ${(k)_LANGUAGES}; do
 117   eval "${l}() { (_${l}-en \$*; _en-${l} \$*) | more }"
 118 done
 119 unset _LANGUAGES
 120
 121 alias dpkg-buildpackage="dpkg-buildpackage -k$DEBKEYID"
 122
 123 uc() { unicode --max=0 --colour=off "$@" | sensible-pager }
 124
 125 # vim:ft=zsh