.zsh/zshrc/00-load_alias-d

   1 #
   2 # Turn files in $apath directories into aliases
   3 #
   4 # Copyright © 1994–2017 martin f. krafft <madduck@madduck.net>
   5 # Released under the terms of the Artistic Licence 2.0
   6 #
   7 # Source repository: http://git.madduck.net/v/etc/zsh.git
   8 #
   9
  10 function make_alias {
  11   emulate -L zsh
  12   setopt extendedglob
  13   local fn="${1:t}" s
  14   for l in ${(f)"$(<$1)"}; do
  15     case "$s/$l" in
  16       (*/\#*) continue;;
  17       (/*) eval "alias $fn='${l//\$0/$fn}'"; s=s;;
  18       (s/(#b)(*)) eval "$match[1]";;
  19     esac
  20   done
  21 }
  22
  23 for ad in $apath; do
  24   if [ ! -d "$ad" ]; then
  25     zerror "no such directory: $ad"
  26     continue
  27   fi
  28
  29 #  zdebug "sourcing alias directory ${ad#$ZDOTDIR/}"
  30   for f in "$ad"/*(N.,@); do
  31     case "$f" in
  32       *~|*.bak|*.old|*.sw?|*.zwc|*.disabled) continue;;
  33     esac
  34     make_alias "$f"
  35   done
  36 done
  37
  38 # vim:ft=zsh