.zsh/zshrc/30_aliases

   1 # zshrc/30_aliases
   2 #
   3 # Defines command shortcuts
   4 #
   5 # Copyright © 1994–2008 martin f. krafft <madduck@madduck.net>
   6 # Released under the terms of the Artistic Licence 2.0
   7 #
   8 # Source repository: http://git.madduck.net/v/etc/zsh.git
   9 #
  10
  11 alias mv='nocorrect mv'
  12 alias cp='nocorrect cp'
  13 alias ln='nocorrect ln'
  14 alias mkdir='nocorrect mkdir'
  15 alias rm='nocorrect rm'
  16
  17 alias find='noglob find'
  18 alias w3m='noglob w3m -no-mouse'
  19 alias links='noglob links'
  20 alias wb='noglob www-browser'
  21 alias wget='noglob wget'
  22 alias curl='noglob curl'
  23 alias apt-cache='noglob apt-cache'
  24 alias locate='noglob locate'
  25
  26 typeset -a _ls_opts; _ls_opts=(-bC --color=auto)
  27 command ls --group-directories-first >/dev/null 2>&1 \
  28   && _ls_opts+=--group-directories-first
  29 # I prefer POSIX collation for ls
  30 alias ls="LC_COLLATE=POSIX ls $_ls_opts"
  31
  32 alias ll='ls -l'
  33 alias l=ll
  34 alias la='ls -a'
  35 alias lla='ls -la'
  36 # List only directories and symbolic links that point to directories
  37 alias lsd='ls -ld *(-/DN)'
  38
  39 alias lsbig="ls -flh *(.OL[1,10])"
  40 alias lssmall="ls -Srl *(.oL[1,10])"
  41 alias lsnew="ls -rl *(D.om[1,10])"
  42 alias lsold="ls -rtlh *(D.om[1,10])"
  43
  44 cd () { builtin cd $* && ll }
  45 #_cd_l() { ll }
  46 #chpwd_functions+=_cd_l
  47
  48 alias egrep='egrep --color=auto -d skip'
  49 alias fgrep='fgrep --color=auto -d skip'
  50 alias grep='grep --color=auto -d skip'
  51
  52 alias mmv='noglob zmv -W'
  53 alias zcp='zmv -C'
  54 alias zln='zmv -L'
  55 alias zgmv='zmv -p git-mv'
  56
  57 alias cal='cal -3'
  58 alias ftp=lftp
  59
  60 alias mbug='bts show --mbox'
  61 alias bug='BROWSER=www-browser bts show'
  62
  63 # handy documentation lookup on Debian
  64 # from http://www.michael-prokop.at/computer/config/.zshrc
  65 doc() { cd /usr/share/doc/$1 && ls }
  66 _doc() { _files -W /usr/share/doc -/ }
  67 compdef _doc doc
  68
  69 alias giti='git init && git add . && git commit -minitial\ checkin'
  70
  71 if whence tailf >/dev/null; then
  72   alias t=tailf
  73 else
  74   alias t='tail -f'
  75 fi
  76 alias tsl='t /var/log/syslog'
  77 alias tml='t /var/log/mail.log'
  78 alias tal='t /var/log/auth.log'
  79 alias tdl='t /var/log/daemon.log'
  80 alias tkl='t /var/log/kern.log'
  81
  82 alias px='ps afux'
  83 alias mps='ps -ao user,pcpu,start,command'
  84
  85 alias bofh='fortune bofh-excuses'
  86
  87 autoload -U baseconv
  88 alias b2d='baseconv 2 10'
  89 alias d2b='baseconv 10 2'
  90 alias d2h='baseconv 10 16'
  91 alias h2d='baseconv 16 10'
  92 alias d2o='baseconv 10 8'
  93 alias o2d='baseconv 8 10'
  94
  95 alias sendmail=/usr/sbin/sendmail
  96
  97 _d() { dict $* }
  98 d() { _d $* | sensible-pager }
  99 the() { d -d moby-thesaurus $* }
 100 typeset -A _LANGUAGES
 101 _LANGUAGES[en]=eng
 102 _LANGUAGES[de]=deu
 103 _LANGUAGES[es]=spa
 104 _LANGUAGES[fr]=fra
 105 _LANGUAGES[it]=ita
 106 _LANGUAGES[lt]=lat
 107 for l0 in ${(k)_LANGUAGES}; do
 108   for l1 in ${(k)_LANGUAGES}; do
 109     eval "_${l0}-${l1}() { _d -d fd-${_LANGUAGES[$l0]}-${_LANGUAGES[$l1]} \$* }"
 110     eval "${l0}-${l1}() { d -d fd-${_LANGUAGES[$l0]}-${_LANGUAGES[$l1]} \$* }"
 111   done
 112 done
 113 unset '_LANGUAGES[en]'
 114 for l in ${(k)_LANGUAGES}; do
 115   eval "${l}() { (_${l}-en \$*; _en-${l} \$*) | more }"
 116 done
 117 unset _LANGUAGES
 118
 119 alias dpkg-buildpackage="dpkg-buildpackage -k$DEBKEYID"
 120
 121 uc() { unicode --max=0 --colour=off "$@" | sensible-pager }
 122
 123 # vim:ft=zsh