.zsh/zshrc/80_xtermtitle

   1 # zterm-title
   2 #
   3 # Fancy setting of the xterm title
   4 #
   5 # Copyright © 1994–2008 martin f. krafft <madduck@madduck.net>
   6 # Released under the terms of the Artistic Licence 2.0
   7 #
   8 # Source repository: http://git.madduck.net/v/etc/zsh.git
   9 #
  10 # Based on http://www.zshwiki.org/cgi-bin/wiki.pl?ZshHardStatus
  11 #
  12
  13 __set_xterm_title() {
  14   case $TERM in
  15     screen)
  16       print -nR $'\033k'$1$'\033'\\
  17       print -nR $'\033]0;'$2$'\a'
  18       ;;
  19     xterm|rxvt*)
  20       print -nR $'\033]0;'$*$'\a'
  21       ;;
  22   esac
  23 }
  24
  25 __get_session_flags() {
  26   [ -n "$SSH_CONNECTION" ] || return
  27   local flags; flags=
  28   [ -n "$DISPLAY" ] && flags="${flags}x"
  29   [ -n "$SSH_AUTH_SOCK" ] && flags="${flags}a"
  30   [ -n "$flags" ] && echo "[${flags}]"
  31 }
  32
  33 __get_standard_prompt() {
  34   print -P "%m%#%25\<..\<%~ $(__get_session_flags)"
  35 }
  36
  37 _set_plain_xterm_title() {
  38   __set_xterm_title "$(__get_standard_prompt)"
  39 }
  40 precmd_functions+=_set_plain_xterm_title
  41
  42 _set_cmd_xterm_title () {
  43     local -a cmd; cmd=(${(z)1})             # Re-parse the command line
  44
  45     # Construct a command that will output the desired job number.
  46     case $cmd[1] in
  47         fg) if (( $#cmd == 1 )); then
  48                 # No arguments, must find the current job
  49                 cmd=(builtin jobs -l %+)
  50             else
  51                 # Replace the command name, ignore extra args.
  52                 cmd=(builtin jobs -l ${(Q)cmd[2]})
  53             fi;;
  54         %*) cmd=(builtin jobs -l ${(Q)cmd[1]});; # Same as "else" above
  55         *) # Not resuming a job,
  56             __set_xterm_title $cmd[1]:t${cmd[2]:+ }$cmd[2,-1] "| $(__get_standard_prompt)"
  57             return;;                        # so we're all done
  58     esac
  59
  60     local -A jt; jt=(${(kv)jobtexts})       # Copy jobtexts for subshell
  61
  62     # Run the command, read its output, and look up the jobtext.
  63     # Could parse $rest here, but $jobtexts (via $jt) is easier.
  64     $cmd >>(
  65               read num rest
  66               cmd=(${(z)${(e):-\$jt$num}})
  67               __set_xterm_title $leader$cmd[1]:t${cmd[2]:+ }$cmd[2,-1] "| $(__get_standard_prompt)"
  68            )
  69 }
  70 preexec_functions+=_set_cmd_xterm_title
  71
  72 # vim:ft=zsh