.zsh/zshrc/30_aliases

   1 # zshrc/30_aliases
   2 #
   3 # Defines command shortcuts
   4 #
   5 # Copyright © 1994–2008 martin f. krafft <madduck@madduck.net>
   6 # Released under the terms of the Artistic Licence 2.0
   7 #
   8 # Source repository: http://git.madduck.net/v/etc/zsh.git
   9 #
  10
  11 alias mv='nocorrect mv'
  12 alias cp='nocorrect cp'
  13 alias ln='nocorrect ln'
  14 alias mkdir='nocorrect mkdir'
  15 alias rm='nocorrect rm'
  16
  17 alias find='noglob find'
  18 alias w3m='noglob w3m -no-mouse'
  19 alias links='noglob links'
  20 alias wb='noglob www-browser'
  21 alias wget='noglob wget'
  22 alias curl='noglob curl'
  23 alias apt-cache='noglob apt-cache'
  24 alias locate='noglob locate'
  25
  26 _LS_OPTS='-bCF --color=auto'
  27 ls --group-directories-first >/dev/null 2>&1 \
  28   && _LS_OPTS="$_LS_OPTS --group-directories-first"
  29 # I prefer POSIX collation for ls
  30 alias ls="LC_COLLATE=POSIX ls $_LS_OPTS"
  31 unset _LS_OPTS
  32
  33 alias ll='ls -l'
  34 alias la='ls -a'
  35 alias lla='ls -la'
  36 # List only directories and symbolic links that point to directories
  37 alias lsd='ls -ld *(-/DN)'
  38
  39 alias lsbig="ls -flh *(.OL[1,10])"
  40 alias lssmall="ls -Srl *(.oL[1,10])"
  41 alias lsnew="ls -rl *(D.om[1,10])"
  42 alias lsold="ls -rtlh *(D.om[1,10])"
  43
  44 alias egrep='egrep --color=auto -d skip'
  45 alias fgrep='fgrep --color=auto -d skip'
  46 alias grep='grep --color=auto -d skip'
  47
  48 alias mmv='noglob zmv -W'
  49 alias zcp='zmv -C'
  50 alias zln='zmv -L'
  51 alias zgmv='zmv -p git-mv'
  52
  53 alias cal='cal -3'
  54 alias ftp=lftp
  55
  56 alias mbug='bts show --mbox'
  57 alias bug='BROWSER=www-browser bts show'
  58
  59 # handy documentation lookup on Debian
  60 # from http://www.michael-prokop.at/computer/config/.zshrc
  61 doc() { cd /usr/share/doc/$1 && ls }
  62 _doc() { _files -W /usr/share/doc -/ }
  63 compdef _doc doc
  64
  65 alias giti='git init && git add . && git commit -minitial\ checkin'
  66
  67 if whence tailf >/dev/null; then
  68   alias t=tailf
  69 else
  70   alias t='tail -f'
  71 fi
  72 alias tsl='t /var/log/syslog'
  73 alias tml='t /var/log/mail.log'
  74 alias tal='t /var/log/auth.log'
  75 alias tdl='t /var/log/daemon.log'
  76 alias tkl='t /var/log/kern.log'
  77
  78 alias px='ps afux'
  79 alias mps='ps -ao user,pcpu,start,command'
  80
  81 alias bofh='fortune bofh-excuses'
  82
  83 autoload -U baseconv
  84 alias b2d='baseconv 2 10'
  85 alias d2b='baseconv 10 2'
  86 alias d2h='baseconv 10 16'
  87 alias h2d='baseconv 16 10'
  88 alias d2o='baseconv 10 8'
  89 alias o2d='baseconv 8 10'
  90
  91 alias sshnew='ssh -o "StrictHostKeyChecking no"'
  92 alias scpnew='scp -o "StrictHostKeyChecking no"'
  93 alias sshtmp='sshnew -o "UserKnownHostsFile /dev/null"'
  94 alias scptmp='scpnew -o "UserKnownHostsFile /dev/null"'
  95
  96 alias sendmail=/usr/sbin/sendmail
  97
  98 _d() { dict $* }
  99 d() { _d $* | sensible-pager }
 100 the() { d -d moby-thesaurus $* }
 101 typeset -A _LANGUAGES
 102 _LANGUAGES[en]=eng
 103 _LANGUAGES[de]=deu
 104 _LANGUAGES[es]=spa
 105 _LANGUAGES[fr]=fra
 106 _LANGUAGES[it]=ita
 107 _LANGUAGES[lt]=lat
 108 for l0 in ${(k)_LANGUAGES}; do
 109   for l1 in ${(k)_LANGUAGES}; do
 110     eval "_${l0}-${l1}() { _d -d fd-${_LANGUAGES[$l0]}-${_LANGUAGES[$l1]} \$* }"
 111     eval "${l0}-${l1}() { d -d fd-${_LANGUAGES[$l0]}-${_LANGUAGES[$l1]} \$* }"
 112   done
 113 done
 114 unset '_LANGUAGES[en]'
 115 for l in ${(k)_LANGUAGES}; do
 116   eval "${l}() { (_${l}-en \$*; _en-${l} \$*) | more }"
 117 done
 118 unset _LANGUAGES
 119
 120 # vim:ft=zsh