.zsh/zshrc/10-xterm_title

   1 #
   2 # Fancy setting of the xterm title
   3 #
   4 # Copyright © 1994–2017 martin f. krafft <madduck@madduck.net>
   5 # Released under the terms of the Artistic Licence 2.0
   6 #
   7 # Source repository: http://git.madduck.net/v/etc/zsh.git
   8 #
   9 # Based on http://www.zshwiki.org/cgi-bin/wiki.pl?ZshHardStatus
  10 #
  11
  12 autoload -U add-zsh-hook
  13
  14 __set_xterm_title() {
  15   emulate -L zsh
  16   case $TERM in
  17     screen)
  18       print -nR $'\033k'$1$'\033'\\
  19       print -nR $'\033]0;'$2$'\a'
  20       ;;
  21     xterm|rxvt*)
  22       print -nR $'\033]0;'$*$'\a'
  23       ;;
  24   esac
  25 }
  26
  27 __get_session_flags() {
  28   emulate -L zsh
  29   [ -n "$SSH_CONNECTION" ] || return
  30   local flags
  31   [ -n "$DISPLAY" ] && flags+=x
  32   [ -n "$SSH_AUTH_SOCK" ] && flags+=a
  33   [[ $SSH_CLIENT = *:* ]] && flags+=6
  34   [ -n "$flags" ] && echo "[${flags}]"
  35 }
  36
  37 __get_standard_prompt() {
  38   emulate -L zsh
  39   [[ -z $SSH_CLIENT ]] || print -nP "%m"
  40   print -P "%#%25\<..\<%~ $(__get_session_flags)"
  41 }
  42
  43 _set_plain_xterm_title() {
  44   emulate -L zsh
  45   __set_xterm_title "$(__get_standard_prompt)"
  46 }
  47 add-zsh-hook precmd _set_plain_xterm_title
  48
  49 _set_cmd_xterm_title () {
  50   emulate -L zsh
  51   local -a cmd; cmd=(${(z)1})             # Re-parse the command line
  52
  53   # Construct a command that will output the desired job number.
  54   case $cmd[1] in
  55     fg) if (( $#cmd == 1 )); then
  56           # No arguments, must find the current job
  57           cmd=(builtin jobs -l %+)
  58         else
  59           # Replace the command name, ignore extra args.
  60           cmd=(builtin jobs -l ${(Q)cmd[2]})
  61         fi;;
  62     %*) cmd=(builtin jobs -l ${(Q)cmd[1]});; # Same as "else" above
  63     *) # Not resuming a job,
  64       __set_xterm_title $cmd[1]:t${cmd[2]:+ }$cmd[2,-1] "| $(__get_standard_prompt)"
  65       return;;                        # so we're all done
  66   esac
  67
  68   local -A jt; jt=(${(kv)jobtexts})       # Copy jobtexts for subshell
  69
  70   # Run the command, read its output, and look up the jobtext.
  71   # Could parse $rest here, but $jobtexts (via $jt) is easier.
  72   $cmd 2>/dev/null >>(read num rest; cmd=(${(z)${(e):-\$jt$num}};)
  73   __set_xterm_title $leader$cmd[1]:t${cmd[2]:+ }$cmd[2,-1] "| $(__get_standard_prompt)"
  74 )
  75 }
  76 add-zsh-hook preexec _set_cmd_xterm_title
  77
  78 # vim:ft=zsh