.zsh/xterm-title

   1 # zterm-title
   2 #
   3 # Fancy setting of the xterm title
   4 #
   5 # Copyright © 1994–2008 martin f. krafft <madduck@madduck.net>
   6 # Released under the terms of the Artistic Licence 2.0
   7 #
   8 # Source repository: http://git.madduck.net/v/etc/zsh.git
   9 #
  10 # Based on http://www.zshwiki.org/cgi-bin/wiki.pl?ZshHardStatus
  11 #
  12
  13 __set_xterm_title() {
  14   case $TERM in
  15     screen)
  16       print -nR $'\033k'$1$'\033'\\
  17       print -nR $'\033]0;'$2$'\a'
  18       ;;
  19     xterm|rxvt*)
  20       print -nR $'\033]0;'$*$'\a'
  21       ;;
  22   esac
  23 }
  24
  25 __get_session_flags() {
  26   [ -n "$SSH_CONNECTION" ] || return
  27   local flags; flags=
  28   [ -n "$DISPLAY" ] && flags="${flags}x"
  29   [ -n "$SSH_AUTH_SOCK" ] && flags="${flags}a"
  30   [ -n "$flags" ] && echo "[${flags}]"
  31 }
  32
  33 __get_standard_prompt() {
  34   print -P "%m%# %25\<..\<%~ $(__get_session_flags)"
  35 }
  36
  37 set_plain_xterm_title() {
  38   __set_xterm_title "$(__get_standard_prompt)"
  39 }
  40
  41 set_cmd_xterm_title () {
  42     local -a cmd; cmd=(${(z)1})             # Re-parse the command line
  43
  44     # Construct a command that will output the desired job number.
  45     case $cmd[1] in
  46         fg) if (( $#cmd == 1 )); then
  47                 # No arguments, must find the current job
  48                 cmd=(builtin jobs -l %+)
  49             else
  50                 # Replace the command name, ignore extra args.
  51                 cmd=(builtin jobs -l ${(Q)cmd[2]})
  52             fi;;
  53         %*) cmd=(builtin jobs -l ${(Q)cmd[1]});; # Same as "else" above
  54         *) # Not resuming a job,
  55             __set_xterm_title $cmd[1]:t${cmd[2]:+ }$cmd[2,-1] "| $(__get_standard_prompt)"
  56             return;;                        # so we're all done
  57     esac
  58
  59     local -A jt; jt=(${(kv)jobtexts})       # Copy jobtexts for subshell
  60
  61     # Run the command, read its output, and look up the jobtext.
  62     # Could parse $rest here, but $jobtexts (via $jt) is easier.
  63     $cmd >>(
  64               read num rest
  65               cmd=(${(z)${(e):-\$jt$num}})
  66               __set_xterm_title $leader$cmd[1]:t${cmd[2]:+ }$cmd[2,-1] "| $(__get_standard_prompt)"
  67            )
  68 }
  69
  70 # vim:ft=zsh