.zsh/zshrc/30_aliases

   1 # zshrc/30_aliases
   2 #
   3 # Defines command shortcuts
   4 #
   5 # Copyright © 1994–2008 martin f. krafft <madduck@madduck.net>
   6 # Released under the terms of the Artistic Licence 2.0
   7 #
   8 # Source repository: http://git.madduck.net/v/etc/zsh.git
   9 #
  10
  11 alias mv='nocorrect mv'
  12 alias cp='nocorrect cp'
  13 alias ln='nocorrect ln'
  14 alias mkdir='nocorrect mkdir'
  15 alias rm='nocorrect rm'
  16
  17 alias find='noglob find'
  18 alias w3m='noglob w3m -no-mouse'
  19 alias links='noglob links'
  20 alias wb='noglob www-browser'
  21 alias wget='noglob wget'
  22 alias curl='noglob curl'
  23 alias apt-cache='noglob apt-cache'
  24 alias locate='noglob locate'
  25
  26 _LS_OPTS='-bCF --color=auto'
  27 ls --group-directories-first >/dev/null 2>&1 \
  28   && _LS_OPTS="$_LS_OPTS --group-directories-first"
  29 # I prefer POSIX collation for ls
  30 alias ls="LC_COLLATE=POSIX ls $_LS_OPTS"
  31 unset _LS_OPTS
  32
  33 alias ll='ls -l'
  34 alias l=ll
  35 alias la='ls -a'
  36 alias lla='ls -la'
  37 # List only directories and symbolic links that point to directories
  38 alias lsd='ls -ld *(-/DN)'
  39
  40 alias lsbig="ls -flh *(.OL[1,10])"
  41 alias lssmall="ls -Srl *(.oL[1,10])"
  42 alias lsnew="ls -rl *(D.om[1,10])"
  43 alias lsold="ls -rtlh *(D.om[1,10])"
  44
  45 cd () { builtin cd $* && ll }
  46 #_cd_l() { ll }
  47 #chpwd_functions+=_cd_l
  48
  49 alias egrep='egrep --color=auto -d skip'
  50 alias fgrep='fgrep --color=auto -d skip'
  51 alias grep='grep --color=auto -d skip'
  52
  53 alias mmv='noglob zmv -W'
  54 alias zcp='zmv -C'
  55 alias zln='zmv -L'
  56 alias zgmv='zmv -p git-mv'
  57
  58 alias cal='cal -3'
  59 alias ftp=lftp
  60
  61 alias mbug='bts show --mbox'
  62 alias bug='BROWSER=www-browser bts show'
  63
  64 # handy documentation lookup on Debian
  65 # from http://www.michael-prokop.at/computer/config/.zshrc
  66 doc() { cd /usr/share/doc/$1 && ls }
  67 _doc() { _files -W /usr/share/doc -/ }
  68 compdef _doc doc
  69
  70 alias giti='git init && git add . && git commit -minitial\ checkin'
  71
  72 if whence tailf >/dev/null; then
  73   alias t=tailf
  74 else
  75   alias t='tail -f'
  76 fi
  77 alias tsl='t /var/log/syslog'
  78 alias tml='t /var/log/mail.log'
  79 alias tal='t /var/log/auth.log'
  80 alias tdl='t /var/log/daemon.log'
  81 alias tkl='t /var/log/kern.log'
  82
  83 alias px='ps afux'
  84 alias mps='ps -ao user,pcpu,start,command'
  85
  86 alias bofh='fortune bofh-excuses'
  87
  88 autoload -U baseconv
  89 alias b2d='baseconv 2 10'
  90 alias d2b='baseconv 10 2'
  91 alias d2h='baseconv 10 16'
  92 alias h2d='baseconv 16 10'
  93 alias d2o='baseconv 10 8'
  94 alias o2d='baseconv 8 10'
  95
  96 alias sshnew='ssh -o "StrictHostKeyChecking no"'
  97 alias scpnew='scp -o "StrictHostKeyChecking no"'
  98 alias sshtmp='sshnew -o "UserKnownHostsFile /dev/null"'
  99 alias scptmp='scpnew -o "UserKnownHostsFile /dev/null"'
 100
 101 alias sendmail=/usr/sbin/sendmail
 102
 103 _d() { dict $* }
 104 d() { _d $* | sensible-pager }
 105 the() { d -d moby-thesaurus $* }
 106 typeset -A _LANGUAGES
 107 _LANGUAGES[en]=eng
 108 _LANGUAGES[de]=deu
 109 _LANGUAGES[es]=spa
 110 _LANGUAGES[fr]=fra
 111 _LANGUAGES[it]=ita
 112 _LANGUAGES[lt]=lat
 113 for l0 in ${(k)_LANGUAGES}; do
 114   for l1 in ${(k)_LANGUAGES}; do
 115     eval "_${l0}-${l1}() { _d -d fd-${_LANGUAGES[$l0]}-${_LANGUAGES[$l1]} \$* }"
 116     eval "${l0}-${l1}() { d -d fd-${_LANGUAGES[$l0]}-${_LANGUAGES[$l1]} \$* }"
 117   done
 118 done
 119 unset '_LANGUAGES[en]'
 120 for l in ${(k)_LANGUAGES}; do
 121   eval "${l}() { (_${l}-en \$*; _en-${l} \$*) | more }"
 122 done
 123 unset _LANGUAGES
 124
 125 # vim:ft=zsh