.zsh/zshrc/30_aliases

   1 # zshrc/30_aliases
   2 #
   3 # Defines command shortcuts
   4 #
   5 # Copyright © 1994–2008 martin f. krafft <madduck@madduck.net>
   6 # Released under the terms of the Artistic Licence 2.0
   7 #
   8 # Source repository: git://git.madduck.net/etc/zsh.git
   9 #
  10
  11 function trace() { eval "set -x; $@" }
  12
  13 alias mv='nocorrect mv'
  14 alias cp='nocorrect cp'
  15 alias ln='nocorrect ln'
  16 alias mkdir='nocorrect mkdir'
  17 alias rm='nocorrect rm'
  18
  19 alias find='noglob find'
  20 alias w3m='noglob w3m -no-mouse'
  21 alias links='noglob links'
  22 alias wb='noglob www-browser'
  23 alias wget='noglob wget'
  24 alias curl='noglob curl'
  25 alias apt-cache='noglob apt-cache'
  26 alias locate='noglob locate'
  27
  28 local _USER_AGENT="Mozilla/5.0 (X11; U; Linux i686; en-US; rv:1.8.1.14) Gecko/20080404 Iceweasel/2.0.0.14 (Debian-2.0.0.14-2)"
  29 alias swget="noglob wget --user-agent='$USER_AGENT'"
  30
  31 typeset -a _ls_opts; _ls_opts=(-bC --color=auto)
  32 command ls --group-directories-first >/dev/null 2>&1 \
  33   && _ls_opts+=--group-directories-first
  34 # I prefer POSIX collation for ls
  35 alias ls="LC_COLLATE=POSIX ls $_ls_opts"
  36
  37 alias l='ls --time-style=+%Y%m%d.%H%M -gG'
  38 alias ll='ls -l'
  39 alias la='ls -a'
  40 alias lla='ls -la'
  41 alias lt='ls -lt'
  42 alias lrt='ls -lrt'
  43 alias lat='ls -lat'
  44 alias lart='ls -lart'
  45 # List only directories and symbolic links that point to directories
  46 alias lsd='ll -d *(-/DN)'
  47
  48 alias lscontext=ls
  49 cd () { __CHPWD_RUN_FIRST=lscontext && builtin cd "$@" && unset __CHPWD_RUN_FIRST }
  50 #_cd_l() { ll }
  51 #chpwd_functions+=_cd_l
  52
  53 # #183394
  54 alias w='w|cat'
  55
  56 alias -g ND='*(/om[1])' # newest directory
  57 alias -g NF='*(.om[1])' # newest file
  58
  59 alias egrep='egrep --color=auto -d skip'
  60 alias fgrep='fgrep --color=auto -d skip'
  61 alias grep='grep --color=auto -d skip'
  62
  63 alias mmv='noglob zmv -W'
  64 alias zcp='zmv -C'
  65 alias zln='zmv -L'
  66 alias zgmv='zmv -p git-mv'
  67
  68 alias cal='cal -3'
  69 alias ftp=lftp
  70
  71 alias mbug='bts show --mbox'
  72 alias bug='BROWSER=www-browser bts show'
  73
  74 # handy documentation lookup on Debian
  75 # from http://www.michael-prokop.at/computer/config/.zshrc
  76 doc() { cd /usr/share/doc/$1 }
  77 compdef '_files -W /usr/share/doc -/' doc
  78
  79 alias giti='git init && git add . && git commit -minitial\ checkin && git tag orig'
  80 gbs() {
  81   local branch; branch="$(git symbolic-ref -q HEAD)"; branch="${branch##*/}"
  82   git config branch.${branch}.remote ${1:-origin}
  83   git config branch.${branch}.merge refs/heads/${branch}
  84   git config branch.${branch}.rebase true
  85 }
  86
  87 if whence mtail >/dev/null; then
  88   alias t=mtail
  89 elif whence tailf >/dev/null; then
  90   alias t=tailf
  91 else
  92   alias t='tail -f'
  93 fi
  94 compdef _files t
  95
  96 function ltail() { t ~log/$1 }
  97 compdef '_files -W ~log' ltail
  98
  99 function lless() { sensible-pager ~log/$1 }
 100 compdef '_files -W ~log' lless
 101
 102 alias tsl='ltail syslog'
 103 alias lsl='lless syslog'
 104 alias tml='ltail mail.log'
 105 alias lml='lless mail.log'
 106 alias tal='ltail auth.log'
 107 alias lal='lless auth.log'
 108 alias tdl='ltail daemon.log'
 109 alias ldl='lless daemon.log'
 110 alias tkl='ltail kern.log'
 111 alias lkl='lless kern.log'
 112
 113 function lgrep() {
 114   local pattern="$1"; shift
 115   eval egrep "'$pattern'" "~log/${(j: ~log/:)@}"
 116 }
 117
 118 alias px='ps afux'
 119 alias mps='ps -ao user,pcpu,start,command'
 120
 121 function of() { lsof -np "$1" }
 122 compdef _pids of
 123
 124 function psgrep() { ps aux | grep "[${1[1]}]${1[2,-1]}" }
 125
 126 alias bofh='fortune bofh-excuses'
 127
 128 autoload -U baseconv
 129 alias b2d='baseconv 2 10'
 130 alias d2b='baseconv 10 2'
 131 alias d2h='baseconv 10 16'
 132 alias h2d='baseconv 16 10'
 133 alias d2o='baseconv 10 8'
 134 alias d2o='baseconv 10 8'
 135 alias h2b='baseconv 16 2'
 136 alias b2h='baseconv 2 16'
 137
 138 alias sendmail=/usr/sbin/sendmail
 139
 140 _d() { dict $* }
 141 d() { _d $* | sensible-pager }
 142 the() { d -d moby-thesaurus $* }
 143 typeset -A _LANGUAGES
 144 _LANGUAGES[en]=eng
 145 _LANGUAGES[de]=deu
 146 _LANGUAGES[es]=spa
 147 _LANGUAGES[fr]=fra
 148 _LANGUAGES[it]=ita
 149 _LANGUAGES[tn]=lat
 150 for l0 in ${(k)_LANGUAGES}; do
 151   for l1 in ${(k)_LANGUAGES}; do
 152     eval "function _${l0}-${l1}() { _d -d fd-${_LANGUAGES[$l0]}-${_LANGUAGES[$l1]} \$* }"
 153     eval "function ${l0}-${l1}() { d -d fd-${_LANGUAGES[$l0]}-${_LANGUAGES[$l1]} \$* }"
 154   done
 155 done
 156 unset '_LANGUAGES[en]'
 157 for l in ${(k)_LANGUAGES}; do
 158   eval "function ${l}() { (_${l}-en \$*; _en-${l} \$*) | more }"
 159 done
 160 unset _LANGUAGES
 161
 162 alias dpkg-buildpackage="dpkg-buildpackage -k$DEBKEYID -rfakeroot"
 163
 164 bugsub() { echo X-debbugs-autosubscribe: madduck | sendmail -f $DEBEMAIL ${1:?No bug number}-subscribe@bugs.debian.org }
 165 bugunsub() { sendmail -f $DEBEMAIL ${1:?No bug number}-unsubscribe@bugs.debian.org </dev/null }
 166 ptssub() { echo subscribe ${1:?E: no package name given.} | sendmail -f ${2:-$DEBEMAIL} pts@qa.debian.org }
 167 ptsunsub() { echo unsubscribe ${1:?E: no package name given.} | sendmail -f ${2:-$DEBEMAIL} pts@qa.debian.org }
 168 qasub() { echo subscribe ${1:?E: no package name given.} ${2:-unspecifed} | sendmail -f $DEBEMAIL ddpo@qa.debian.org }
 169 qaunsub() { echo unsubscribe ${1:?E: no package name given.} ${2:-unspecifed} | sendmail -f $DEBEMAIL ddpo@qa.debian.org }
 170
 171 uc() { unicode --max=0 --colour=off "$@" | sensible-pager }
 172
 173 alias ipr='ip r'
 174 alias ipa='ip a'
 175 alias ipl='ip l'
 176
 177 alias btd='btdownloadheadless'
 178
 179 alias mdtest='swaks -s localhost -t'
 180
 181 if whence devtodo >/dev/null; then
 182   _devtodo_on_chpwd() {
 183     local out; out="$(devtodo)"
 184     [[ -n $out ]] && print "todo:\n$out"
 185   }
 186   [[ -z ${(M)chpwd_functions:#_devtodo_on_chpwd} ]] && chpwd_functions+=_devtodo_on_chpwd
 187 fi
 188
 189 # vim:ft=zsh