.zsh/zshrc/85_vcs_prompt

   1 # zshrc/85_git_prompt
   2 #
   3 # Make git information available to the prompt
   4 #
   5 # Copyright © 1994–2008 martin f. krafft <madduck@madduck.net>
   6 # Released under the terms of the Artistic Licence 2.0
   7 #
   8 # Source repository: http://git.madduck.net/v/etc/zsh.git
   9 #
  10 # Shamelessly based on http://glandium.org/blog/?p=170
  11 #
  12
  13 __git_get_repo_root()
  14 {
  15   local relroot
  16   relroot="$(git rev-parse --show-cdup 2>/dev/null)" || return 1
  17   if [ -n "$relroot" ]; then
  18     readlink -f "$relroot"
  19   else
  20     echo $PWD
  21   fi
  22 }
  23
  24 __git_get_branch()
  25 {
  26   local ref
  27   ref=$(git symbolic-ref -q HEAD 2>/dev/null \
  28      || git-name-rev --name-only HEAD 2>/dev/null)
  29   echo "${ref#refs/heads/}"
  30 }
  31
  32 __get_root_offsets()
  33 {
  34   local pwda reporoot loc
  35   pwda=(${(s:/:)PWD})
  36   reporoot=(${(s:/:)1})
  37   echo $((1 - $#reporoot)) $(($#pwda - $#reporoot))
  38 }
  39
  40 __get_prompt_path_components()
  41 {
  42   local reporoot
  43   reporoot="$1"
  44
  45   set -- $(__get_root_offsets "$reporoot")
  46   if [ "$2" -le 0 ]; then
  47     echo %~
  48   else
  49     echo "%${1}~" "%${2}~"
  50   fi
  51 }
  52
  53 __vcs_get_repo_type()
  54 {
  55   while true; do
  56     [ -d .git ] && echo git && break
  57     [ -d .bzr ] && echo bzr && break
  58     [ -d .hg ] && echo hg && break
  59     [ -d .svn ] && echo svn && break
  60     [ -d CVS ] && echo cvs && break
  61     [ "$PWD" = / ] && echo NONE && return 1
  62     cd ..
  63   done
  64 }
  65
  66 __vcs_set_prompt_variables()
  67 {
  68   local pre branch post
  69   local MAXLEN=25
  70
  71   case "${1:-$(__vcs_get_repo_type)}" in
  72     git)
  73       local reporoot="$(__git_get_repo_root)"
  74       set -- $(__get_prompt_path_components "$reporoot")
  75       branch="$(__git_get_branch)"
  76       post="${(%)2}"
  77       local prelen="$((MAXLEN - $#post - $#branch))"
  78       [ $prelen -lt 10 ] && prelen=10
  79       pre="%${prelen}<..<${1}%<<"
  80       pre="${(%)pre}"
  81       ;;
  82     *)
  83       local p="%${MAXLEN}<..<%~%<<"
  84       #TODO find a better way so we don't have to nuke $psvar, but since the
  85       #     %(nv.true.false) check for prompts checks element count, not
  86       #     content, that's all we get for now
  87       psvar=("${(%)p}")
  88       return
  89   esac
  90
  91   psvar[1]="$pre"
  92   psvar[2]="$branch"
  93   psvar[3]="$post"
  94 }
  95
  96 if ! is_root; then
  97   # too dangerous to be run as root
  98
  99   _update_vcs_prompt_vars_if_vcs_ran() {
 100     local vcs="$(__vcs_get_repo_type)"
 101     case "$(history $(($HISTCMD - 1)))" in
 102       # $vcs appeared in last command, so be sure to update
 103       *${vcs}*) __vcs_set_prompt_variables
 104     esac
 105   }
 106   precmd_functions+=_update_vcs_prompt_vars_if_vcs_ran
 107
 108   _update_vcs_prompt_vars() {
 109     __vcs_set_prompt_variables
 110   }
 111   chpwd_functions+=_update_vcs_prompt_vars
 112
 113   # call it once
 114   _update_vcs_prompt_vars
 115 fi
 116
 117 # vim:ft=zsh