_vcsh

   1 #compdef vcsh
   2
   3 function __vcsh_repositories () {
   4         local expl
   5         local -a repos
   6         repos=( ${(f)"$(command vcsh list)"} )
   7         _describe -t repos 'repositories' repos
   8 }
   9
  10 function __vcsh_not_implemented_yet () {
  11         _message "Subcommand completion '${1#*-}': not implemented yet"
  12 }
  13
  14 function _vcsh-clone () {
  15         __vcsh_not_implemented_yet "$0" #TODO
  16 }
  17
  18 function _vcsh-delete () {
  19         (( CURRENT == 2 )) && __vcsh_repositories
  20 }
  21
  22 function _vcsh-enter () {
  23         (( CURRENT == 2 )) && __vcsh_repositories
  24 }
  25
  26 function _vcsh-help () {
  27         _nothing
  28 }
  29
  30 function _vcsh-init () {
  31         _nothing
  32 }
  33
  34 function _vcsh-list () {
  35         _nothing
  36 }
  37
  38 function _vcsh-list-tracked () {
  39         _nothing
  40 }
  41
  42 function _vcsh-list-tracked-by () {
  43         (( CURRENT == 2 )) && __vcsh_repositories
  44 }
  45
  46 function _vcsh-pull () {
  47         _nothing
  48 }
  49
  50 function _vcsh-push () {
  51         _nothing
  52 }
  53
  54 function _vcsh-rename () {
  55         (( CURRENT == 2 )) && __vcsh_repositories
  56         (( CURRENT == 3 )) && _message "new repository name"
  57         (( CURRENT > 3 )) && _nothing
  58 }
  59
  60 function _vcsh-run () {
  61         (( CURRENT == 2 )) && __vcsh_repositories
  62         if (( CURRENT >= 3 )); then
  63                 words=( "${(@)words[3,-1]}" )
  64                 (( CURRENT -= 2 ))
  65                 _complete
  66         fi
  67 }
  68
  69 function _vcsh-upgrade () {
  70         (( CURRENT == 2 )) && __vcsh_repositories
  71 }
  72
  73 function _vcsh-version () {
  74         _nothing
  75 }
  76
  77 function _vcsh-which () {
  78         _files
  79 }
  80
  81 function _vcsh-write-gitignore () {
  82         (( CURRENT == 2 )) && __vcsh_repositories
  83 }
  84
  85 function _vcsh () {
  86         local curcontext="${curcontext}"
  87         local state vcshcommand
  88         local -a args subcommands
  89
  90         subcommands=(
  91                 "clone:clone an existing repository"
  92                 "commit:commit in all repositories"
  93                 "delete:delete an existing repository"
  94                 "enter:enter repository; spawn new <\$SHELL>"
  95                 "help:display help"
  96                 "init:initialize an empty repository"
  97                 "list:list all local vcsh repositories"
  98                 "list-tracked:list all files tracked by vcsh"
  99                 "list-tracked-by:list files tracked by a repository"
 100                 "pull:pull from all vcsh remotes"
 101                 "push:push to vcsh remotes"
 102                 "rename:rename a repository"
 103                 "run:run command with <\$GIT_DIR> and <\$GIT_WORK_TREE> set"
 104                 "status:show statuses of all/one vcsh repositories"
 105                 "upgrade:upgrade repository to currently recommended settings"
 106                 "version:print version information"
 107                 "which:find <substring> in name of any tracked file"
 108                 "write-gitignore:write .gitignore.d/<repo> via git ls-files"
 109         )
 110
 111         args=(
 112                 '-c[source <file> prior to other configuration files]:config files:_path_files'
 113                 '-d[enable debug mode]'
 114                 '-v[enable verbose mode]'
 115                 '*:: :->subcommand_or_options_or_repo'
 116         )
 117
 118         _arguments -C ${args} && return
 119
 120         if [[ ${state} == "subcommand_or_options_or_repo" ]]; then
 121                 if (( CURRENT == 1 )); then
 122                         _describe -t subcommands 'vcsh sub-commands' subcommands
 123                         __vcsh_repositories
 124                 else
 125                         vcshcommand="${words[1]}"
 126                         if ! (( ${+functions[_vcsh-$vcshcommand]} )); then
 127                                 # There is no handler function, so this is probably the name
 128                                 # of a repository. Act accordingly.
 129                                 _dispatch git git
 130                         else
 131                                 curcontext="${curcontext%:*:*}:vcsh-${vcshcommand}:"
 132                                 _call_function ret _vcsh-${vcshcommand}
 133                         fi
 134                 fi
 135         fi
 136 }
 137
 138 _vcsh "$@"