_vcsh

   1 #compdef vcsh
   2
   3 function __vcsh_repositories () {
   4         local expl
   5         local -a repos
   6         repos=( ${(f)"$(command vcsh list)"} )
   7         _describe -t repos 'repositories' repos
   8 }
   9
  10 function __vcsh_not_implemented_yet () {
  11         _message "Subcommand completion '${1#*-}': not implemented yet"
  12 }
  13
  14 function _vcsh-clone () {
  15         __vcsh_not_implemented_yet "$0" #TODO
  16 }
  17
  18 function _vcsh-delete () {
  19         (( CURRENT == 2 )) && __vcsh_repositories
  20 }
  21
  22 function _vcsh-enter () {
  23         (( CURRENT == 2 )) && __vcsh_repositories
  24 }
  25
  26 function _vcsh-help () {
  27         _nothing
  28 }
  29
  30 function _vcsh-init () {
  31         _nothing
  32 }
  33
  34 function _vcsh-list () {
  35         _nothing
  36 }
  37
  38 function _vcsh-list-tracked () {
  39         _nothing
  40 }
  41
  42 function _vcsh-list-tracked-by () {
  43         (( CURRENT == 2 )) && __vcsh_repositories
  44 }
  45
  46 function _vcsh-rename () {
  47         (( CURRENT == 2 )) && __vcsh_repositories
  48         #TODO tell the user to add a new name
  49 }
  50
  51 function _vcsh-run () {
  52         (( CURRENT == 2 )) && __vcsh_repositories
  53         #TODO normal commands
  54 }
  55
  56 function _vcsh-setup () {
  57         (( CURRENT == 2 )) && __vcsh_repositories
  58 }
  59
  60 function _vcsh-version () {
  61         _nothing
  62 }
  63
  64 function _vcsh-which () {
  65         _files
  66 }
  67
  68 function _vcsh-write-gitignore () {
  69         (( CURRENT == 2 )) && __vcsh_repositories
  70 }
  71
  72 function _vcsh () {
  73         local curcontext="${curcontext}"
  74         local state vcshcommand
  75         local -a args subcommands
  76
  77         subcommands=(
  78                 "clone:clone an existing repository"
  79                 "delete:delete an existing repository"
  80                 "enter:enter repository; spawn new <\$SHELL>"
  81                 "help:display help"
  82                 "init:initialize an empty repository"
  83                 "list:list all local vcsh repositories"
  84                 "list-tracked:list all files tracked by vcsh"
  85                 "list-tracked-by:list files tracked by a repository"
  86                 "rename:rename a repository"
  87                 "run:run command with <\$GIT_DIR> and <\$GIT_WORK_TREE> set"
  88                 "setup:set up repository with recommended settings"
  89                 "version:print version information"
  90                 "which:find <substring> in name of any tracked file"
  91                 "write-gitignore:write .gitignore.d/<repo> via git ls-files"
  92         )
  93
  94         args=(
  95                 '-c[source <file> prior to other configuration files]:config files:_path_files'
  96                 '-d[enable debug mode]'
  97                 '-v[enable verbose mode]'
  98                 '*:: :->subcommand_or_options_or_repo'
  99         )
 100
 101         _arguments -C ${args} && return
 102
 103         if [[ ${state} == "subcommand_or_options_or_repo" ]]; then
 104                 if (( CURRENT == 1 )); then
 105                         _describe -t subcommands 'vcsh sub-commands' subcommands
 106                         __vcsh_repositories
 107                 else
 108                         vcshcommand="${words[1]}"
 109                         if ! (( ${+functions[_vcsh-$vcshcommand]} )); then
 110                                 # There is no handler function, so this is probably the name
 111                                 # of a repository. Act accordingly.
 112                                 _message "git sub-command"
 113                                 #TODO and now we need to complete on git subcommands
 114                         else
 115                                 curcontext="${curcontext%:*:*}:vcsh-${vcshcommand}:"
 116                                 _call_function ret _vcsh-${vcshcommand}
 117                         fi
 118                 fi
 119         fi
 120 }
 121
 122 _vcsh "$@"