_vcsh

   1 #compdef vcsh
   2
   3 function __vcsh_repositories () {
   4         local expl
   5         local -a repos
   6         repos=( ${(f)"$(command vcsh list)"} )
   7         _describe -t repos 'repositories' repos
   8 }
   9
  10 function __vcsh_not_implemented_yet () {
  11         _message "Subcommand completion '${1#*-}': not implemented yet"
  12 }
  13
  14 function _vcsh-clone () {
  15         __vcsh_not_implemented_yet "$0" #TODO
  16 }
  17
  18 function _vcsh-delete () {
  19         (( CURRENT == 2 )) && __vcsh_repositories
  20 }
  21
  22 function _vcsh-enter () {
  23         (( CURRENT == 2 )) && __vcsh_repositories
  24 }
  25
  26 function _vcsh-help () {
  27         _nothing
  28 }
  29
  30 function _vcsh-init () {
  31         _nothing
  32 }
  33
  34 function _vcsh-list () {
  35         _nothing
  36 }
  37
  38 function _vcsh-list-tracked () {
  39         _nothing
  40 }
  41
  42 function _vcsh-list-tracked-by () {
  43         (( CURRENT == 2 )) && __vcsh_repositories
  44 }
  45
  46 function _vcsh-pull () {
  47         _nothing
  48 }
  49
  50 function _vcsh-rename () {
  51         (( CURRENT == 2 )) && __vcsh_repositories
  52         (( CURRENT == 3 )) && _message "new repository name"
  53         (( CURRENT > 3 )) && _nothing
  54 }
  55
  56 function _vcsh-run () {
  57         (( CURRENT == 2 )) && __vcsh_repositories
  58         if (( CURRENT >= 3 )); then
  59                 words=( "${(@)words[3,-1]}" )
  60                 (( CURRENT -= 2 ))
  61                 _complete
  62         fi
  63 }
  64
  65 function _vcsh-upgrade () {
  66         (( CURRENT == 2 )) && __vcsh_repositories
  67 }
  68
  69 function _vcsh-version () {
  70         _nothing
  71 }
  72
  73 function _vcsh-which () {
  74         _files
  75 }
  76
  77 function _vcsh-write-gitignore () {
  78         (( CURRENT == 2 )) && __vcsh_repositories
  79 }
  80
  81 function _vcsh () {
  82         local curcontext="${curcontext}"
  83         local state vcshcommand
  84         local -a args subcommands
  85
  86         subcommands=(
  87                 "clone:clone an existing repository"
  88                 "delete:delete an existing repository"
  89                 "enter:enter repository; spawn new <\$SHELL>"
  90                 "help:display help"
  91                 "init:initialize an empty repository"
  92                 "list:list all local vcsh repositories"
  93                 "list-tracked:list all files tracked by vcsh"
  94                 "list-tracked-by:list files tracked by a repository"
  95                 "pull:pull from all vcsh remotes"
  96                 "rename:rename a repository"
  97                 "run:run command with <\$GIT_DIR> and <\$GIT_WORK_TREE> set"
  98                 "upgrade:upgrade repository to currently recommended settings"
  99                 "version:print version information"
 100                 "which:find <substring> in name of any tracked file"
 101                 "write-gitignore:write .gitignore.d/<repo> via git ls-files"
 102         )
 103
 104         args=(
 105                 '-c[source <file> prior to other configuration files]:config files:_path_files'
 106                 '-d[enable debug mode]'
 107                 '-v[enable verbose mode]'
 108                 '*:: :->subcommand_or_options_or_repo'
 109         )
 110
 111         _arguments -C ${args} && return
 112
 113         if [[ ${state} == "subcommand_or_options_or_repo" ]]; then
 114                 if (( CURRENT == 1 )); then
 115                         _describe -t subcommands 'vcsh sub-commands' subcommands
 116                         __vcsh_repositories
 117                 else
 118                         vcshcommand="${words[1]}"
 119                         if ! (( ${+functions[_vcsh-$vcshcommand]} )); then
 120                                 # There is no handler function, so this is probably the name
 121                                 # of a repository. Act accordingly.
 122                                 _dispatch git git
 123                         else
 124                                 curcontext="${curcontext%:*:*}:vcsh-${vcshcommand}:"
 125                                 _call_function ret _vcsh-${vcshcommand}
 126                         fi
 127                 fi
 128         fi
 129 }
 130
 131 _vcsh "$@"