ftplugin/python_flake8.vim

   1 "
   2 " Python filetype plugin for running flake8
   3 " Language:     Python (ft=python)
   4 " Maintainer:   Vincent Driessen <vincent@3rdcloud.com>
   5 " Version:      Vim 7 (may work with lower Vim versions, but not tested)
   6 " URL:          http://github.com/nvie/vim-flake8
   7 "
   8 " Only do this when not done yet for this buffer
   9 if exists("b:loaded_flake8_ftplugin")
  10     finish
  11 endif
  12 let b:loaded_flake8_ftplugin=1
  13
  14 if exists("g:flake8_cmd")
  15     let s:flake8_cmd=g:flake8_cmd
  16 else
  17     let s:flake8_cmd="flake8"
  18 endif
  19
  20 let s:flake8_ignores=""
  21 if exists("g:flake8_ignore")
  22     let s:flake8_ignores=" --ignore=".g:flake8_ignore
  23 endif
  24
  25 let s:flake8_max_line_length=""
  26 if exists("g:flake8_max_line_length")
  27     let s:flake8_max_line_length=" --max-line-length=".g:flake8_max_line_length
  28 endif
  29
  30 if !exists("*Flake8()")
  31     function Flake8()
  32         if !executable(s:flake8_cmd)
  33             echoerr "File " . s:flake8_cmd . " not found. Please install it first."
  34             return
  35         endif
  36
  37         set lazyredraw   " delay redrawing
  38         cclose           " close any existing cwindows
  39
  40         " store old grep settings (to restore later)
  41         let l:old_gfm=&grepformat
  42         let l:old_gp=&grepprg
  43
  44         " write any changes before continuing
  45         if &readonly == 0
  46             update
  47         endif
  48
  49         " perform the grep itself
  50         let &grepformat="%f:%l:%c: %m\,%f:%l: %m"
  51         let &grepprg=s:flake8_cmd.s:flake8_ignores.s:flake8_max_line_length
  52         silent! grep! %
  53
  54         " restore grep settings
  55         let &grepformat=l:old_gfm
  56         let &grepprg=l:old_gp
  57
  58         " open cwindow
  59         let has_results=getqflist() != []
  60         if has_results
  61             execute 'belowright copen'
  62             setlocal wrap
  63             nnoremap <buffer> <silent> c :cclose<CR>
  64             nnoremap <buffer> <silent> q :cclose<CR>
  65         endif
  66
  67         set nolazyredraw
  68         redraw!
  69
  70         if has_results == 0
  71             " Show OK status
  72             hi Green ctermfg=green
  73             echohl Green
  74             echon "Flake8 check OK"
  75             echohl
  76         endif
  77     endfunction
  78 endif
  79
  80 " Add mappings, unless the user didn't want this.
  81 " The default mapping is registered under to <F7> by default, unless the user
  82 " remapped it already (or a mapping exists already for <F7>)
  83 if !exists("no_plugin_maps") && !exists("no_flake8_maps")
  84     if !hasmapto('Flake8(')
  85         noremap <buffer> <F7> :call Flake8()<CR>
  86     endif
  87 endif