]> git.madduck.net Git - etc/vim.git/blob - syntax/markdown.vim

madduck's git repository

Every one of the projects in this repository is available at the canonical URL git://git.madduck.net/madduck/pub/<projectpath> — see each project's metadata for the exact URL.

All patches and comments are welcome. Please squash your changes to logical commits before using git-format-patch and git-send-email to patches@git.madduck.net. If you'd read over the Git project's submission guidelines and adhered to them, I'd be especially grateful.

SSH access, as well as push access can be individually arranged.

If you use my repositories frequently, consider adding the following snippet to ~/.gitconfig and using the third clone URL listed for each project:

[url "git://git.madduck.net/madduck/"]
  insteadOf = madduck:

Fix indent code block at beginning of file
[etc/vim.git] / syntax / markdown.vim
1 " Vim syntax file
2 " Language:     Markdown
3 " Maintainer:   Ben Williams <benw@plasticboy.com>
4 " URL:          http://plasticboy.com/markdown-vim-mode/
5 " Remark:       Uses HTML syntax file
6 " TODO:         Handle stuff contained within stuff (e.g. headings within blockquotes)
7
8
9 " Read the HTML syntax to start with
10 if version < 600
11   so <sfile>:p:h/html.vim
12 else
13   runtime! syntax/html.vim
14
15   if exists('b:current_syntax')
16     unlet b:current_syntax
17   endif
18 endif
19
20 if version < 600
21   syntax clear
22 elseif exists("b:current_syntax")
23   finish
24 endif
25
26 " don't use standard HiLink, it will not work with included syntax files
27 if version < 508
28   command! -nargs=+ HtmlHiLink hi link <args>
29 else
30   command! -nargs=+ HtmlHiLink hi def link <args>
31 endif
32
33 syn spell toplevel
34 syn case ignore
35 syn sync linebreaks=1
36
37 let s:conceal = ''
38 let s:concealends = ''
39 if has('conceal')
40   let s:conceal = ' conceal'
41   let s:concealends = ' concealends'
42 endif
43
44 "additions to HTML groups
45 syn region htmlItalic start="\\\@<!\*\ze[^\\\*\t ]" end="[^\\\*\t ]\zs\*" keepend oneline
46 syn region htmlItalic start="\\\@<!_\ze[^\\_\t ]" end="[^\\_\t ]\zs_" keepend oneline
47 syn region htmlBold start="\*\*\ze\S" end="\S\zs\*\*" keepend oneline
48 syn region htmlBold start="__\ze\S" end="\S\zs__" keepend oneline
49 syn region htmlBoldItalic start="\*\*\*\ze\S" end="\S\zs\*\*\*" keepend oneline
50 syn region htmlBoldItalic start="___\ze\S" end="\S\zs___" keepend oneline
51
52 " [link](URL) | [link][id] | [link][] | ![image](URL)
53 syn region mkdFootnotes matchgroup=mkdDelimiter start="\[^"    end="\]"
54 execute 'syn region mkdID matchgroup=mkdDelimiter    start="\["    end="\]" contained oneline' . s:conceal
55 execute 'syn region mkdURL matchgroup=mkdDelimiter   start="("     end=")"  contained oneline' . s:conceal
56 execute 'syn region mkdLink matchgroup=mkdDelimiter  start="\\\@<!!\?\[" end="\]\ze[[(]" contains=@mkdNonListItem,@Spell nextgroup=mkdURL,mkdID skipwhite oneline' . s:concealends
57
58 " Autolink without angle brackets.
59 " mkd  inline links:           protocol   optional  user:pass@       sub/domain                 .com, .co.uk, etc      optional port   path/querystring/hash fragment
60 "                            ------------ _____________________ --------------------------- ________________________ ----------------- __
61 syntax match   mkdInlineURL /https\?:\/\/\(\w\+\(:\w\+\)\?@\)\?\([A-Za-z][-_0-9A-Za-z]*\.\)\{1,}\(\w\{2,}\.\?\)\{1,}\(:[0-9]\{1,5}\)\?\S*/
62
63 " Autolink with parenthesis.
64 syntax region  mkdInlineURL matchgroup=mkdDelimiter start="(\(https\?:\/\/\(\w\+\(:\w\+\)\?@\)\?\([A-Za-z][-_0-9A-Za-z]*\.\)\{1,}\(\w\{2,}\.\?\)\{1,}\(:[0-9]\{1,5}\)\?\S*)\)\@=" end=")"
65
66 " Autolink with angle brackets.
67 syn region mkdInlineURL matchgroup=mkdDelimiter start="\\\@<!<\ze[a-z][a-z0-9,.-]\{1,22}:\/\/[^> ]*>" end=">"
68
69 " Link definitions: [id]: URL (Optional Title)
70 syn region mkdLinkDef matchgroup=mkdDelimiter   start="^ \{,3}\zs\[" end="]:" oneline nextgroup=mkdLinkDefTarget skipwhite
71 syn region mkdLinkDefTarget start="<\?\zs\S" excludenl end="\ze[>[:space:]\n]"   contained nextgroup=mkdLinkTitle,mkdLinkDef skipwhite skipnl oneline
72 syn region mkdLinkTitle matchgroup=mkdDelimiter start=+"+     end=+"+  contained
73 syn region mkdLinkTitle matchgroup=mkdDelimiter start=+'+     end=+'+  contained
74 syn region mkdLinkTitle matchgroup=mkdDelimiter start=+(+     end=+)+  contained
75
76 "HTML headings
77 syn region htmlH1       start="^\s*#"                   end="$" contains=@Spell
78 syn region htmlH2       start="^\s*##"                  end="$" contains=@Spell
79 syn region htmlH3       start="^\s*###"                 end="$" contains=@Spell
80 syn region htmlH4       start="^\s*####"                end="$" contains=@Spell
81 syn region htmlH5       start="^\s*#####"               end="$" contains=@Spell
82 syn region htmlH6       start="^\s*######"              end="$" contains=@Spell
83 syn match  htmlH1       /^.\+\n=\+$/ contains=@Spell
84 syn match  htmlH2       /^.\+\n-\+$/ contains=@Spell
85
86 "define Markdown groups
87 syn match  mkdLineContinue ".$" contained
88 syn match  mkdLineBreak    /  \+$/
89 syn region mkdBlockquote   start=/^\s*>/                   end=/$/ contains=mkdLineBreak,mkdLineContinue,@Spell
90 syn region mkdCode         start=/\(\([^\\]\|^\)\\\)\@<!`/ end=/\(\([^\\]\|^\)\\\)\@<!`/
91 syn region mkdCode         start=/\s*``[^`]*/              end=/[^`]*``\s*/
92 syn region mkdCode         start=/^\s*\z(`\{3,}\)\s*[0-9A-Za-z_+-]*\s*$/          end=/^\s*\z1`*\s*$/
93 syn region mkdCode         start=/\s*\~\~[^\~]*/              end=/[^\~]*\~\~\s*/
94 syn region mkdCode         start=/^\s*\z(\~\{3,}\)\s*[0-9A-Za-z_+-]*\s*$/         end=/^\s*\z1\~*\s*$/
95 syn region mkdCode         start="<pre[^>]*>"              end="</pre>"
96 syn region mkdCode         start="<code[^>]*>"             end="</code>"
97 syn region mkdFootnote     start="\[^"                     end="\]"
98 syn match  mkdCode         /^\s*\n\(\(\s\{8,}[^ ]\|\t\t\+[^\t]\).*\n\)\+/
99 syn match  mkdCode         /\%^\(\(\s\{4,}[^ ]\|\t\+[^\t]\).*\n\)\+/
100 syn match  mkdCode         /^\s*\n\(\(\s\{4,}[^ ]\|\t\+[^\t]\).*\n\)\+/ contained
101 syn region mkdListItemLine matchgroup=mkdListItem start="^\s*\%([-*+]\|\d\+\.\)\s\+" end="$" contains=@mkdNonListItem,@Spell
102 syn region mkdNonListItemBlock start="\(\%^\(\s*\([-*+]\|\d\+\.\)\s\+\)\@!\|\n\(\_^\_$\|\s\{4,}[^ ]\|\t+[^\t]\)\@!\)" end="^\(\s*\([-*+]\|\d\+\.\)\s\+\)\@=" contains=@mkdNonListItem,@Spell
103 syn match  mkdRule         /^\s*\*\s\{0,1}\*\s\{0,1}\*$/
104 syn match  mkdRule         /^\s*-\s\{0,1}-\s\{0,1}-$/
105 syn match  mkdRule         /^\s*_\s\{0,1}_\s\{0,1}_$/
106 syn match  mkdRule         /^\s*-\{3,}$/
107 syn match  mkdRule         /^\s*\*\{3,5}$/
108
109 " YAML frontmatter
110 if get(g:, 'vim_markdown_frontmatter', 0)
111   syn include @yamlTop syntax/yaml.vim
112   syn region Comment matchgroup=mkdDelimiter start="\%^---$" end="^---$" contains=@yamlTop
113 endif
114
115 if get(g:, 'vim_markdown_math', 0)
116   syn include @tex syntax/tex.vim
117   syn region mkdMath matchgroup=mkdDelimiter start="\\\@<!\$" end="\$" contains=@tex
118   syn region mkdMath matchgroup=mkdDelimiter start="\\\@<!\$\$" end="\$\$" contains=@tex
119 endif
120
121 syn cluster mkdNonListItem contains=@htmlTop,htmlItalic,htmlBold,htmlBoldItalic,mkdFootnotes,mkdInlineURL,mkdLink,mkdLinkDef,mkdLineBreak,mkdBlockquote,mkdCode,mkdListItem,mkdRule,htmlH1,htmlH2,htmlH3,htmlH4,htmlH5,htmlH6,mkdMath
122
123 "highlighting for Markdown groups
124 HtmlHiLink mkdString        String
125 HtmlHiLink mkdCode          String
126 HtmlHiLink mkdCodeStart     String
127 HtmlHiLink mkdCodeEnd       String
128 HtmlHiLink mkdFootnote      Comment
129 HtmlHiLink mkdBlockquote    Comment
130 HtmlHiLink mkdLineContinue  Comment
131 HtmlHiLink mkdListItem      Identifier
132 HtmlHiLink mkdRule          Identifier
133 HtmlHiLink mkdLineBreak     Todo
134 HtmlHiLink mkdFootnotes     htmlLink
135 HtmlHiLink mkdLink          htmlLink
136 HtmlHiLink mkdURL           htmlString
137 HtmlHiLink mkdInlineURL     htmlLink
138 HtmlHiLink mkdID            Identifier
139 HtmlHiLink mkdLinkDef       mkdID
140 HtmlHiLink mkdLinkDefTarget mkdURL
141 HtmlHiLink mkdLinkTitle     htmlString
142 HtmlHiLink mkdDelimiter     Delimiter
143
144 let b:current_syntax = "mkd"
145
146 delcommand HtmlHiLink
147 " vim: ts=8