syntax/mkd.vim

   1 " Vim syntax file
   2 " Language:     Markdown
   3 " Maintainer:   Ben Williams <benw@plasticboy.com>
   4 " URL:          http://plasticboy.com/markdown-vim-mode/
   5 " Remark:       Uses HTML syntax file
   6 " Remark:       I don't do anything with angle brackets (<>) because that would too easily
   7 "               easily conflict with HTML syntax
   8 " TODO:         Handle stuff contained within stuff (e.g. headings within blockquotes)
   9
  10
  11 " Read the HTML syntax to start with
  12 if version < 600
  13   so <sfile>:p:h/html.vim
  14 else
  15   runtime! syntax/html.vim
  16
  17   if exists('b:current_syntax')
  18     unlet b:current_syntax
  19   endif
  20 endif
  21
  22 if version < 600
  23   syntax clear
  24 elseif exists("b:current_syntax")
  25   finish
  26 endif
  27
  28 " don't use standard HiLink, it will not work with included syntax files
  29 if version < 508
  30   command! -nargs=+ HtmlHiLink hi link <args>
  31 else
  32   command! -nargs=+ HtmlHiLink hi def link <args>
  33 endif
  34
  35 syn spell toplevel
  36 syn case ignore
  37 syn sync linebreaks=1
  38
  39 "additions to HTML groups
  40 syn region htmlItalic start="\\\@<!\*\S\@=" end="\S\@<=\\\@<!\*" keepend oneline
  41 syn region htmlItalic start="\(^\|\s\)\@<=_\|\\\@<!_\([^_]\+\s\)\@=" end="\S\@<=_\|_\S\@=" keepend oneline
  42 syn region htmlBold start="\S\@<=\*\*\|\*\*\S\@=" end="\S\@<=\*\*\|\*\*\S\@=" keepend oneline
  43 syn region htmlBold start="\S\@<=__\|__\S\@=" end="\S\@<=__\|__\S\@=" keepend oneline
  44 syn region htmlBoldItalic start="\S\@<=\*\*\*\|\*\*\*\S\@=" end="\S\@<=\*\*\*\|\*\*\*\S\@=" keepend oneline
  45 syn region htmlBoldItalic start="\S\@<=___\|___\S\@=" end="\S\@<=___\|___\S\@=" keepend oneline
  46
  47 " [link](URL) | [link][id] | [link][]
  48 syn region mkdFootnotes matchgroup=mkdDelimiter start="\[^"    end="\]"
  49 syn region mkdID matchgroup=mkdDelimiter        start="\["    end="\]" contained oneline
  50 syn region mkdURL matchgroup=mkdDelimiter       start="("     end=")"  contained oneline
  51 syn region mkdLink matchgroup=mkdDelimiter      start="\\\@<!\[" end="\]\ze\s*[[(]" contains=@Spell nextgroup=mkdURL,mkdID skipwhite oneline
  52 " mkd  inline links:           protocol   optional  user:pass@       sub/domain                 .com, .co.uk, etc      optional port   path/querystring/hash fragment
  53 "                            ------------ _____________________ --------------------------- ________________________ ----------------- __
  54 syntax match   mkdInlineURL /https\?:\/\/\(\w\+\(:\w\+\)\?@\)\?\([A-Za-z][-_0-9A-Za-z]*\.\)\{1,}\(\w\{2,}\.\?\)\{1,}\(:[0-9]\{1,5}\)\?\S*/
  55
  56 " Link definitions: [id]: URL (Optional Title)
  57 " TODO handle automatic links without colliding with htmlTag (<URL>)
  58 syn region mkdLinkDef matchgroup=mkdDelimiter   start="^ \{,3}\zs\[" end="]:" oneline nextgroup=mkdLinkDefTarget skipwhite
  59 syn region mkdLinkDefTarget start="<\?\zs\S" excludenl end="\ze[>[:space:]\n]"   contained nextgroup=mkdLinkTitle,mkdLinkDef skipwhite skipnl oneline
  60 syn region mkdLinkTitle matchgroup=mkdDelimiter start=+"+     end=+"+  contained
  61 syn region mkdLinkTitle matchgroup=mkdDelimiter start=+'+     end=+'+  contained
  62 syn region mkdLinkTitle matchgroup=mkdDelimiter start=+(+     end=+)+  contained
  63
  64 "define Markdown groups
  65 syn match  mkdLineContinue ".$" contained
  66 syn match  mkdLineBreak    /  \+$/
  67 syn region mkdBlockquote   start=/^\s*>/                   end=/$/ contains=mkdLineBreak,mkdLineContinue,@Spell
  68 syn region mkdCode         start=/\(\([^\\]\|^\)\\\)\@<!`/ end=/\(\([^\\]\|^\)\\\)\@<!`/
  69 syn region mkdCode         start=/\s*``[^`]*/              end=/[^`]*``\s*/
  70 syn region mkdCode         start=/^\s*```\s*[0-9A-Za-z_-]*\s*$/          end=/^\s*```\s*$/
  71 syn region mkdCode         start="<pre[^>]*>"              end="</pre>"
  72 syn region mkdCode         start="<code[^>]*>"             end="</code>"
  73 syn region mkdFootnote     start="\[^"                     end="\]"
  74 syn match  mkdCode         /^\s*\n\(\(\s\{8,}[^ ]\|\t\t\+[^\t]\).*\n\)\+/
  75 syn match  mkdIndentCode   /^\s*\n\(\(\s\{4,}[^ ]\|\t\+[^\t]\).*\n\)\+/ contained
  76 syn match  mkdListItem     "^\s*[-*+]\s\+"
  77 syn match  mkdListItem     "^\s*\d\+\.\s\+"
  78 syn region mkdNonListItemBlock start="\n\(\_^\_$\|\s\{4,}[^ ]\|\t+[^\t]\)\@!" end="^\(\s*\([-*+]\|\d\+\.\)\s\+\)\@=" contains=@mkdNonListItem,@Spell
  79 syn match  mkdRule         /^\s*\*\s\{0,1}\*\s\{0,1}\*$/
  80 syn match  mkdRule         /^\s*-\s\{0,1}-\s\{0,1}-$/
  81 syn match  mkdRule         /^\s*_\s\{0,1}_\s\{0,1}_$/
  82 syn match  mkdRule         /^\s*-\{3,}$/
  83 syn match  mkdRule         /^\s*\*\{3,5}$/
  84
  85 "HTML headings
  86 syn region htmlH1       start="^\s*#"                   end="\($\|#\+\)" contains=@Spell
  87 syn region htmlH2       start="^\s*##"                  end="\($\|#\+\)" contains=@Spell
  88 syn region htmlH3       start="^\s*###"                 end="\($\|#\+\)" contains=@Spell
  89 syn region htmlH4       start="^\s*####"                end="\($\|#\+\)" contains=@Spell
  90 syn region htmlH5       start="^\s*#####"               end="\($\|#\+\)" contains=@Spell
  91 syn region htmlH6       start="^\s*######"              end="\($\|#\+\)" contains=@Spell
  92 syn match  htmlH1       /^.\+\n=\+$/ contains=@Spell
  93 syn match  htmlH2       /^.\+\n-\+$/ contains=@Spell
  94
  95 if get(g:, 'vim_markdown_math', 0)
  96   syn region mkdMath matchgroup=mkdDelimiter start="\\\@<!\$" end="\$"
  97   syn region mkdMath matchgroup=mkdDelimiter start="\\\@<!\$\$" end="\$\$"
  98 endif
  99
 100 syn cluster mkdNonListItem contains=htmlItalic,htmlBold,htmlBoldItalic,mkdFootnotes,mkdID,mkdURL,mkdLink,mkdLinkDef,mkdLineBreak,mkdBlockquote,mkdCode,mkdMath,mkdIndentCode,mkdListItem,mkdRule,htmlH1,htmlH2,htmlH3,htmlH4,htmlH5,htmlH6
 101
 102 " YAML frontmatter
 103 if get(g:, 'vim_markdown_frontmatter', 0)
 104   syn include @yamlTop syntax/yaml.vim
 105   syn region Comment matchgroup=mkdDelimiter start="\%^---$" end="^---$" contains=@yamlTop
 106 endif
 107
 108 "highlighting for Markdown groups
 109 HtmlHiLink mkdString        String
 110 HtmlHiLink mkdCode          String
 111 HtmlHiLink mkdIndentCode    String
 112 HtmlHiLink mkdFootnote    Comment
 113 HtmlHiLink mkdBlockquote    Comment
 114 HtmlHiLink mkdLineContinue  Comment
 115 HtmlHiLink mkdListItem      Identifier
 116 HtmlHiLink mkdRule          Identifier
 117 HtmlHiLink mkdLineBreak     Todo
 118 HtmlHiLink mkdFootnotes     htmlLink
 119 HtmlHiLink mkdLink          htmlLink
 120 HtmlHiLink mkdURL           htmlString
 121 HtmlHiLink mkdInlineURL     htmlLink
 122 HtmlHiLink mkdID            Identifier
 123 HtmlHiLink mkdLinkDef       mkdID
 124 HtmlHiLink mkdLinkDefTarget mkdURL
 125 HtmlHiLink mkdLinkTitle     htmlString
 126 HtmlHiLink mkdMath          Statement
 127 HtmlHiLink mkdDelimiter     Delimiter
 128
 129 " Automatically insert bullets
 130 setlocal formatoptions+=r
 131 " Do not automatically insert bullets when auto-wrapping with text-width
 132 setlocal formatoptions-=c
 133 " Accept various markers as bullets
 134 setlocal comments=b:*,b:+,b:-
 135
 136 " Automatically continue blockquote on line break
 137 setlocal comments+=b:>
 138
 139 let b:current_syntax = "mkd"
 140
 141 delcommand HtmlHiLink
 142 " vim: ts=8