indent/markdown.vim

   1 if exists("b:did_indent") | finish | endif
   2 let b:did_indent = 1
   3
   4 setlocal indentexpr=GetMarkdownIndent()
   5 setlocal nolisp
   6 setlocal autoindent
   7
   8 " Automatically insert bullets
   9 setlocal formatoptions+=r
  10 " Do not automatically insert bullets when auto-wrapping with text-width
  11 setlocal formatoptions-=c
  12 " Accept various markers as bullets
  13 setlocal comments=b:*,b:+,b:-
  14
  15 " Automatically continue blockquote on line break
  16 setlocal comments+=b:>
  17
  18 " Only define the function once
  19 if exists("*GetMarkdownIndent") | finish | endif
  20
  21 function! s:is_li_start(line)
  22     return a:line !~ '^ *\([*-]\)\%( *\1\)\{2}\%( \|\1\)*$' &&
  23       \    a:line =~ '^\s*[*+-] \+'
  24 endfunction
  25
  26 function! s:is_blank_line(line)
  27     return a:line =~ '^$'
  28 endfunction
  29
  30 function! s:prevnonblank(lnum)
  31     let i = a:lnum
  32     while i > 1 && s:is_blank_line(getline(i))
  33         let i -= 1
  34     endwhile
  35     return i
  36 endfunction
  37
  38 function GetMarkdownIndent()
  39     let list_ind = 4
  40     " Find a non-blank line above the current line.
  41     let lnum = prevnonblank(v:lnum - 1)
  42     " At the start of the file use zero indent.
  43     if lnum == 0 | return 0 | endif
  44     let ind = indent(lnum)
  45     let line = getline(lnum)    " Last line
  46     let cline = getline(v:lnum) " Current line
  47     if s:is_li_start(cline)
  48         " Current line is the first line of a list item, do not change indent
  49         return indent(v:lnum)
  50     elseif s:is_li_start(line)
  51         " Last line is the first line of a list item, increase indent
  52         return ind + list_ind
  53     else
  54         return ind
  55     endif
  56 endfunction