.vim/bundle/ale/ale_linters/terraform/terraform_ls.vim

   1 " Author: Horacio Sanson <hsanson@gmail.com>
   2 " Description: terraform-ls integration for ALE (cf. https://github.com/hashicorp/terraform-ls)
   3
   4 call ale#Set('terraform_terraform_executable', 'terraform')
   5 call ale#Set('terraform_ls_executable', 'terraform-ls')
   6 call ale#Set('terraform_ls_options', '')
   7
   8 function! ale_linters#terraform#terraform_ls#GetTerraformExecutable(buffer) abort
   9     let l:terraform_executable = ale#Var(a:buffer, 'terraform_terraform_executable')
  10
  11     if(ale#path#IsAbsolute(l:terraform_executable))
  12         return '-tf-exec ' . l:terraform_executable
  13     endif
  14
  15     return ''
  16 endfunction
  17
  18 function! ale_linters#terraform#terraform_ls#GetCommand(buffer) abort
  19     return '%e'
  20     \ . ale#Pad('serve')
  21     \ . ale#Pad(ale_linters#terraform#terraform_ls#GetTerraformExecutable(a:buffer))
  22     \ . ale#Pad(ale#Var(a:buffer, 'terraform_ls_options'))
  23 endfunction
  24
  25 function! ale_linters#terraform#terraform_ls#GetProjectRoot(buffer) abort
  26     let l:tf_dir = ale#path#FindNearestDirectory(a:buffer, '.terraform')
  27
  28     return !empty(l:tf_dir) ? fnamemodify(l:tf_dir, ':h:h') : ''
  29 endfunction
  30
  31 call ale#linter#Define('terraform', {
  32 \   'name': 'terraform_ls',
  33 \   'aliases': ['terraformls'],
  34 \   'lsp': 'stdio',
  35 \   'executable': {b -> ale#Var(b, 'terraform_ls_executable')},
  36 \   'command': function('ale_linters#terraform#terraform_ls#GetCommand'),
  37 \   'project_root': function('ale_linters#terraform#terraform_ls#GetProjectRoot'),
  38 \   'language': 'terraform',
  39 \})