.vim/bundle/ale/ale_linters/apiblueprint/drafter.vim

   1 " Author: nametake https://nametake.github.io
   2 " Description: apiblueprint parser
   3
   4 function! ale_linters#apiblueprint#drafter#HandleErrors(buffer, lines) abort
   5     " Matches patterns line the following:
   6     "
   7     " warning: (3)  unable to parse response signature, expected 'response [<HTTP status code>] [(<media type>)]'; line 4, column 3k - line 4, column 22
   8     " warning: (10)  message-body asset is expected to be a pre-formatted code block, separate it by a newline and indent every of its line by 12 spaces or 3 tabs; line 30, column 5 - line 30, column 9; line 31, column 9 - line 31, column 14; line 32, column 9 - line 32, column 14
   9     let l:pattern = '\(^.*\): (\d\+)  \(.\{-\}\); line \(\d\+\), column \(\d\+\) - line \d\+, column \d\+\(.*; line \d\+, column \d\+ - line \(\d\+\), column \(\d\+\)\)\{-\}$'
  10     let l:output = []
  11
  12     for l:match in ale#util#GetMatches(a:lines[2:], l:pattern)
  13         let l:item = {
  14         \   'type': l:match[1] is# 'warning' ? 'W' : 'E',
  15         \   'text': l:match[2],
  16         \   'lnum': l:match[3] + 0,
  17         \   'col': l:match[4] + 0,
  18         \}
  19
  20         if l:match[5] isnot# ''
  21             let l:item.end_lnum = l:match[6] + 0
  22             let l:item.end_col = l:match[7] + 0
  23         endif
  24
  25         call add(l:output, l:item)
  26     endfor
  27
  28     return l:output
  29 endfunction
  30
  31
  32 call ale#linter#Define('apiblueprint', {
  33 \   'name': 'drafter',
  34 \   'output_stream': 'stderr',
  35 \   'executable': 'drafter',
  36 \   'command': 'drafter --use-line-num --validate',
  37 \   'callback': 'ale_linters#apiblueprint#drafter#HandleErrors',
  38 \})