.vim/bundle/ale/ale_linters/java/javalsp.vim

   1 " Author: Horacio Sanson <https://github.com/hsanson>
   2 " Description: Support for the Java language server https://github.com/georgewfraser/vscode-javac
   3
   4 call ale#Set('java_javalsp_executable', '')
   5 call ale#Set('java_javalsp_config', {})
   6
   7 function! ale_linters#java#javalsp#Executable(buffer) abort
   8     return ale#Var(a:buffer, 'java_javalsp_executable')
   9 endfunction
  10
  11 function! ale_linters#java#javalsp#Config(buffer) abort
  12     let l:defaults = { 'java': { 'classPath': [], 'externalDependencies': [] } }
  13     let l:config = ale#Var(a:buffer, 'java_javalsp_config')
  14
  15     " Ensure the config dictionary contains both classPath and
  16     " externalDependencies keys to avoid a NPE crash on Java Language Server.
  17     call extend(l:config, l:defaults, 'keep')
  18     call extend(l:config['java'], l:defaults['java'], 'keep')
  19
  20     return l:config
  21 endfunction
  22
  23 function! ale_linters#java#javalsp#Command(buffer) abort
  24     let l:executable = ale_linters#java#javalsp#Executable(a:buffer)
  25
  26     if fnamemodify(l:executable, ':t') is# 'java'
  27         " For backward compatibility.
  28         let l:cmd = [
  29         \ ale#Escape(l:executable),
  30         \ '--add-exports jdk.compiler/com.sun.tools.javac.api=javacs',
  31         \ '--add-exports jdk.compiler/com.sun.tools.javac.code=javacs',
  32         \ '--add-exports jdk.compiler/com.sun.tools.javac.comp=javacs',
  33         \ '--add-exports jdk.compiler/com.sun.tools.javac.main=javacs',
  34         \ '--add-exports jdk.compiler/com.sun.tools.javac.tree=javacs',
  35         \ '--add-exports jdk.compiler/com.sun.tools.javac.model=javacs',
  36         \ '--add-exports jdk.compiler/com.sun.tools.javac.util=javacs',
  37         \ '--add-opens jdk.compiler/com.sun.tools.javac.api=javacs',
  38         \ '-m javacs/org.javacs.Main',
  39         \]
  40
  41         return join(l:cmd, ' ')
  42     else
  43         return ale#Escape(l:executable)
  44     endif
  45 endfunction
  46
  47 call ale#linter#Define('java', {
  48 \   'name': 'javalsp',
  49 \   'aliases': ['java_language_server'],
  50 \   'lsp': 'stdio',
  51 \   'executable': function('ale_linters#java#javalsp#Executable'),
  52 \   'command': function('ale_linters#java#javalsp#Command'),
  53 \   'language': 'java',
  54 \   'project_root': function('ale#java#FindProjectRoot'),
  55 \   'lsp_config': function('ale_linters#java#javalsp#Config')
  56 \})