syntax/markdown.vim

   1 " Vim syntax file
   2 " Language:     Markdown
   3 " Maintainer:   Ben Williams <benw@plasticboy.com>
   4 " URL:          http://plasticboy.com/markdown-vim-mode/
   5 " Remark:       Uses HTML syntax file
   6 " TODO:         Handle stuff contained within stuff (e.g. headings within blockquotes)
   7
   8
   9 " Read the HTML syntax to start with
  10 if version < 600
  11   so <sfile>:p:h/html.vim
  12 else
  13   runtime! syntax/html.vim
  14
  15   if exists('b:current_syntax')
  16     unlet b:current_syntax
  17   endif
  18 endif
  19
  20 if version < 600
  21   syntax clear
  22 elseif exists("b:current_syntax")
  23   finish
  24 endif
  25
  26 " don't use standard HiLink, it will not work with included syntax files
  27 if version < 508
  28   command! -nargs=+ HtmlHiLink hi link <args>
  29 else
  30   command! -nargs=+ HtmlHiLink hi def link <args>
  31 endif
  32
  33 syn spell toplevel
  34 syn case ignore
  35 syn sync linebreaks=1
  36
  37 "additions to HTML groups
  38 syn region htmlItalic start="\\\@<!\*\S\@=" end="\S\@<=\\\@<!\*" keepend oneline
  39 syn region htmlItalic start="\(^\|\s\)\@<=_\|\\\@<!_\([^_]\+\s\)\@=" end="\S\@<=_\|_\S\@=" keepend oneline
  40 syn region htmlBold start="\S\@<=\*\*\|\*\*\S\@=" end="\S\@<=\*\*\|\*\*\S\@=" keepend oneline
  41 syn region htmlBold start="\S\@<=__\|__\S\@=" end="\S\@<=__\|__\S\@=" keepend oneline
  42 syn region htmlBoldItalic start="\S\@<=\*\*\*\|\*\*\*\S\@=" end="\S\@<=\*\*\*\|\*\*\*\S\@=" keepend oneline
  43 syn region htmlBoldItalic start="\S\@<=___\|___\S\@=" end="\S\@<=___\|___\S\@=" keepend oneline
  44
  45 " [link](URL) | [link][id] | [link][]
  46 syn region mkdFootnotes matchgroup=mkdDelimiter start="\[^"    end="\]"
  47 syn region mkdID matchgroup=mkdDelimiter        start="\["    end="\]" contained oneline
  48 syn region mkdURL matchgroup=mkdDelimiter       start="("     end=")"  contained oneline
  49 syn region mkdLink matchgroup=mkdDelimiter      start="\\\@<!\[" end="\]\ze\s*[[(]" contains=@Spell nextgroup=mkdURL,mkdID skipwhite oneline
  50
  51 " Autolink without angle brackets.
  52 " mkd  inline links:           protocol   optional  user:pass@       sub/domain                 .com, .co.uk, etc      optional port   path/querystring/hash fragment
  53 "                            ------------ _____________________ --------------------------- ________________________ ----------------- __
  54 syntax match   mkdInlineURL /https\?:\/\/\(\w\+\(:\w\+\)\?@\)\?\([A-Za-z][-_0-9A-Za-z]*\.\)\{1,}\(\w\{2,}\.\?\)\{1,}\(:[0-9]\{1,5}\)\?\S*/
  55
  56 " Autolink with angle brackets.
  57 syn region mkdInlineURL matchgroup=mkdDelimiter start="\\\@<!<\(\(coap\|doi\|javascript\|aaa\|aaas\|about\|acap\|cap\|cid\|crid\|data\|dav\|dict\|dns\|file\|ftp\|geo\|go\|gopher\|h323\|http\|https\|iax\|icap\|im\|imap\|info\|ipp\|iris\|iris.beep\|iris.xpc\|iris.xpcs\|iris.lwz\|ldap\|mailto\|mid\|msrp\|msrps\|mtqp\|mupdate\|news\|nfs\|ni\|nih\|nntp\|opaquelocktoken\|pop\|pres\|rtsp\|service\|session\|shttp\|sieve\|sip\|sips\|sms\|snmp,soap.beep\|soap.beeps\|tag\|tel\|telnet\|tftp\|thismessage\|tn3270\|tip\|tv\|urn\|vemmi\|ws\|wss\|xcon\|xcon-userid\|xmlrpc.beep\|xmlrpc.beeps\|xmpp\|z39.50r\|z39.50s\|adiumxtra\|afp\|afs\|aim\|apt,attachment\|aw\|beshare\|bitcoin\|bolo\|callto\|chrome,chrome-extension\|com-eventbrite-attendee\|content\|cvs,dlna-playsingle\|dlna-playcontainer\|dtn\|dvb\|ed2k\|facetime\|feed\|finger\|fish\|gg\|git\|gizmoproject\|gtalk\|hcp\|icon\|ipn\|irc\|irc6\|ircs\|itms\|jar\|jms\|keyparc\|lastfm\|ldaps\|magnet\|maps\|market,message\|mms\|ms-help\|msnim\|mumble\|mvn\|notes\|oid\|palm\|paparazzi\|platform\|proxy\|psyc\|query\|res\|resource\|rmi\|rsync\|rtmp\|secondlife\|sftp\|sgn\|skype\|smb\|soldat\|spotify\|ssh\|steam\|svn\|teamspeak\|things\|udp\|unreal\|ut2004\|ventrilo\|view-source\|webcal\|wtai\|wyciwyg\|xfire\|xri\|ymsgr\):\/\/[^> ]*>\)\@=" end=">"
  58
  59 " Link definitions: [id]: URL (Optional Title)
  60 syn region mkdLinkDef matchgroup=mkdDelimiter   start="^ \{,3}\zs\[" end="]:" oneline nextgroup=mkdLinkDefTarget skipwhite
  61 syn region mkdLinkDefTarget start="<\?\zs\S" excludenl end="\ze[>[:space:]\n]"   contained nextgroup=mkdLinkTitle,mkdLinkDef skipwhite skipnl oneline
  62 syn region mkdLinkTitle matchgroup=mkdDelimiter start=+"+     end=+"+  contained
  63 syn region mkdLinkTitle matchgroup=mkdDelimiter start=+'+     end=+'+  contained
  64 syn region mkdLinkTitle matchgroup=mkdDelimiter start=+(+     end=+)+  contained
  65
  66 "define Markdown groups
  67 syn match  mkdLineContinue ".$" contained
  68 syn match  mkdLineBreak    /  \+$/
  69 syn region mkdBlockquote   start=/^\s*>/                   end=/$/ contains=mkdLineBreak,mkdLineContinue,@Spell
  70 syn region mkdCode         start=/\(\([^\\]\|^\)\\\)\@<!`/ end=/\(\([^\\]\|^\)\\\)\@<!`/
  71 syn region mkdCode         start=/\s*``[^`]*/              end=/[^`]*``\s*/
  72 syn region mkdCode         start=/^\s*```\s*[0-9A-Za-z_-]*\s*$/          end=/^\s*```\s*$/
  73 syn region mkdCode         start=/\s*\~\~[^\~]*/              end=/[^\~]*\~\~\s*/
  74 syn region mkdCode         start=/^\s*\~\~\~\s*[0-9A-Za-z_-]*\s*$/          end=/^\s*\~\~\~\s*$/
  75 syn region mkdCode         start="<pre[^>]*>"              end="</pre>"
  76 syn region mkdCode         start="<code[^>]*>"             end="</code>"
  77 syn region mkdFootnote     start="\[^"                     end="\]"
  78 syn match  mkdCode         /^\s*\n\(\(\s\{8,}[^ ]\|\t\t\+[^\t]\).*\n\)\+/
  79 syn match  mkdIndentCode   /^\s*\n\(\(\s\{4,}[^ ]\|\t\+[^\t]\).*\n\)\+/ contained
  80 syn match  mkdListItem     "^\s*[-*+]\s\+"
  81 syn match  mkdListItem     "^\s*\d\+\.\s\+"
  82 syn region mkdNonListItemBlock start="\n\(\_^\_$\|\s\{4,}[^ ]\|\t+[^\t]\)\@!" end="^\(\s*\([-*+]\|\d\+\.\)\s\+\)\@=" contains=@mkdNonListItem,@Spell
  83 syn match  mkdRule         /^\s*\*\s\{0,1}\*\s\{0,1}\*$/
  84 syn match  mkdRule         /^\s*-\s\{0,1}-\s\{0,1}-$/
  85 syn match  mkdRule         /^\s*_\s\{0,1}_\s\{0,1}_$/
  86 syn match  mkdRule         /^\s*-\{3,}$/
  87 syn match  mkdRule         /^\s*\*\{3,5}$/
  88
  89 "HTML headings
  90 syn region htmlH1       start="^\s*#"                   end="\($\|#\+\)" contains=@Spell
  91 syn region htmlH2       start="^\s*##"                  end="\($\|#\+\)" contains=@Spell
  92 syn region htmlH3       start="^\s*###"                 end="\($\|#\+\)" contains=@Spell
  93 syn region htmlH4       start="^\s*####"                end="\($\|#\+\)" contains=@Spell
  94 syn region htmlH5       start="^\s*#####"               end="\($\|#\+\)" contains=@Spell
  95 syn region htmlH6       start="^\s*######"              end="\($\|#\+\)" contains=@Spell
  96 syn match  htmlH1       /^.\+\n=\+$/ contains=@Spell
  97 syn match  htmlH2       /^.\+\n-\+$/ contains=@Spell
  98
  99 if get(g:, 'vim_markdown_math', 0)
 100   syn region mkdMath matchgroup=mkdDelimiter start="\\\@<!\$" end="\$"
 101   syn region mkdMath matchgroup=mkdDelimiter start="\\\@<!\$\$" end="\$\$"
 102 endif
 103
 104 " YAML frontmatter
 105 if get(g:, 'vim_markdown_frontmatter', 0)
 106   syn include @yamlTop syntax/yaml.vim
 107   syn region Comment matchgroup=mkdDelimiter start="\%^---$" end="^---$" contains=@yamlTop
 108 endif
 109
 110 syn cluster mkdNonListItem contains=htmlItalic,htmlBold,htmlBoldItalic,mkdFootnotes,mkdInlineURL,mkdLink,mkdLinkDef,mkdLineBreak,mkdBlockquote,mkdCode,mkdIndentCode,mkdListItem,mkdRule,htmlH1,htmlH2,htmlH3,htmlH4,htmlH5,htmlH6,mkdMath
 111
 112 "highlighting for Markdown groups
 113 HtmlHiLink mkdString        String
 114 HtmlHiLink mkdCode          String
 115 HtmlHiLink mkdIndentCode    String
 116 HtmlHiLink mkdFootnote    Comment
 117 HtmlHiLink mkdBlockquote    Comment
 118 HtmlHiLink mkdLineContinue  Comment
 119 HtmlHiLink mkdListItem      Identifier
 120 HtmlHiLink mkdRule          Identifier
 121 HtmlHiLink mkdLineBreak     Todo
 122 HtmlHiLink mkdFootnotes     htmlLink
 123 HtmlHiLink mkdLink          htmlLink
 124 HtmlHiLink mkdURL           htmlString
 125 HtmlHiLink mkdInlineURL     htmlLink
 126 HtmlHiLink mkdID            Identifier
 127 HtmlHiLink mkdLinkDef       mkdID
 128 HtmlHiLink mkdLinkDefTarget mkdURL
 129 HtmlHiLink mkdLinkTitle     htmlString
 130 HtmlHiLink mkdMath          Statement
 131 HtmlHiLink mkdDelimiter     Delimiter
 132
 133 let b:current_syntax = "mkd"
 134
 135 delcommand HtmlHiLink
 136 " vim: ts=8