.vim/ftplugin/mail.vim

   1 nmap <buffer> <C-P><F1> :w<CR>:%!~/.bin/mail/mailplate --keep-unknown official<CR>
   2 nmap <buffer> <C-P><F2> :w<CR>:%!~/.bin/mail/mailplate --keep-unknown private<CR>
   3 nmap <buffer> <C-P><F3> :w<CR>:%!~/.bin/mail/mailplate --keep-unknown debian<CR>
   4 nmap <buffer> <C-P><F4> :w<CR>:%!~/.bin/mail/mailplate --keep-unknown phd<CR>
   5 nmap <buffer> <C-P><F5> :w<CR>:%!~/.bin/mail/mailplate --keep-unknown ul<CR>
   6 nmap <buffer> <C-P><F6> :w<CR>:%!~/.bin/mail/mailplate --keep-unknown uzh<CR>
   7 nmap <buffer> <C-P><F9> :w<CR>:%!~/.bin/mail/mailplate --keep-unknown sudetia<CR>
   8 nmap <buffer> <F1> :w<CR>:%!~/.bin/mail/mailplate --auto --keep-unknown 2>/dev/null<CR>
   9
  10 " Checking attachments in edited emails for use in Mutt: warns user when
  11 " exiting
  12 " by Hugo Haas <hugo@larve.net> - 20 June 2004
  13 " based on an idea by The Doctor What explained at
  14 " <mid:caq406$rq4$1@FreeBSD.csie.NCTU.edu.tw>
  15 " http://www.vim.org/scripts/download_script.php?src_id=3165
  16 autocmd BufUnload mutt-* call CheckAttachments()
  17 function! CheckAttachments()
  18   let l:english = 'attach\(ing\|ed\|ment\)\?\|included with this mail'
  19   let l:french = 'attach\(e\|er\|ée\?s\?\|ement\|ant\)'
  20   let l:german = 'an\(gehängt\|hängsel\|bei\)\|bei\(gefügt\|lage\)\|\(im\|siehe\)\_s\(anhang\|beilage\)'
  21   let l:ic = &ignorecase
  22   if (l:ic == 0)
  23     set ignorecase
  24   endif
  25   if (search('^\([^>|].*\)\?\<\(re-\?\)\?\('.l:english.'\|'.l:german.'\)\>', "w") != 0)
  26     let l:temp = inputdialog("Do you want to attach a file? [Hit return] ")
  27   endif
  28   if (l:ic == 0)
  29     set noignorecase
  30   endif
  31   echo
  32 endfunction
  33
  34 " change subject line
  35 " Before: Subject: old
  36 " After : Subject: New (was: old)
  37 " http://strcat.de/wiki/dotfiles#vim
  38 " map ,sw 1G/^Subject: <CR>:s/Re:/was:/<CR>Wi (<C-O>$)<ESC>0Whi
  39 map <Leader>ns 1G/^Subject: /<CR>:s,\(Subject: \)\(Re: \)*\(.*\)$,\1 (was: \3),<CR>:set nohls<CR>f li
  40
  41 " Delete 'was' in the Subject.
  42 " Before: Subject: New (was: old)
  43 " After : Subject: New
  44 " http://strcat.de/wiki/dotfiles#vim
  45 map <Leader>dw 1G/^Subject: /<CR>:s, *(was: .*)$<CR>:set nohls<CR>f l
  46
  47 " http://dollyfish.net.nz/blog/2008-04-01/mutt-and-vim-custom-autocompletion
  48 fun! LBDBCompleteFn(findstart, base)
  49   let line = getline('.')
  50   if a:findstart
  51     " locate the start of the word
  52     let start = col('.') - 1
  53     while start > 0 && line[start - 1] =~ '[^:,]'
  54       let start -= 1
  55     endwhile
  56     while start < col('.') && line[start] =~ '[:, ]'
  57       let start += 1
  58     endwhile
  59     return start
  60   else
  61     let res = []
  62     let query = substitute(a:base, '"', '', 'g')
  63     let query = substitute(query, '\s*<.*>\s*', '', 'g')
  64     for m in LbdbQuery(query)
  65       call complete_add(printf('"%s" <%s>', escape(m[0], '"'), m[1]))
  66       if complete_check()
  67         break
  68       endif
  69     endfor
  70     return res
  71   endif
  72 endfun
  73 set completefunc=LBDBCompleteFn
  74
  75 " And this magic by James Vega, which ensures that we only complete with lbdb
  76 " on the recipient lines of the mail header.
  77 ino <expr> <C-n> DelegateCompletion(1)
  78 ino <expr> <C-p> DelegateCompletion(0)
  79
  80 fun! DelegateCompletion(next)
  81   if getline('.') =~? '^\%(To\|B\=Cc\):'
  82     return "\x18\x15"
  83   elseif a:next
  84     return "\x0e"
  85   else
  86     return "\x10"
  87   endif
  88 endfun